那些遇到过的问题

XSLT 输出 JSON 而不是 XML

use*_*326 2 xml xslt json

我有一个 XSLT，它在输出 XML 时按照我想要的方式工作，但是我想将 XSLT 更改为输出 JSON。问题出现在我最内层的 for-each 循环中，但我不确定。如果有办法使这更有效，我也对您的建议感兴趣。

示例输入 XML

<?xml version="1.0" encoding="UTF-8"?>
<root xmlns:xs="http://www.w3.org/2001/XMLSchema">
   <Metric measType="1526727075"
           measResult="0"
           endTime="2016-08-25T04:30:00-07:00"
           measObjLdn="LTHBC0126858/GTPU:Board Type=MPT, Cabinet No.=0, Subrack No.=1, Slot No.=7"
           Element_Type="ENODEB"
           Key1="LTHBC0126858"
           TableName="HH_ENODEB"
           ColumnName="H1526727075"
           H1526727075="0"/>
   <Metric measType="1526727076"
           measResult="0"
           endTime="2016-08-25T04:30:00-07:00"
           measObjLdn="LTHBC0126858/GTPU:Board Type=MPT, Cabinet No.=0, Subrack No.=1, Slot No.=7"
           Element_Type="ENODEB"
           Key1="LTHBC0126858"
           TableName="HH_ENODEB"
           ColumnName="H1526727076"
           H1526727076="0"/>
   <Metric measType="1526727077"
           measResult="0"
           endTime="2016-08-25T04:30:00-07:00"
           measObjLdn="LTHBC0126858/GTPU:Board Type=MPT, Cabinet No.=0, Subrack No.=1, Slot No.=7"
           Element_Type="ENODEB"
           Key1="LTHBC0126858"
           TableName="HH_ENODEB"
           ColumnName="H1526727077"
           H1526727077="0"/>
</root>
Run Code Online (Sandbox Code Playgroud)

这是输出 XML 并按我期望的方式工作的 XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="root">
        <root>
            <xsl:for-each-group select="Metric" group-by="@measObjLdn">
                <xsl:sort select="current-grouping-key()"/>
                <xsl:variable name="curr_key" select="current-grouping-key()"/>
                <xsl:for-each-group select="current-group()" group-by="@TableName">
                    <xsl:sort select="current-grouping-key()"/>
                    <xsl:if test="current-grouping-key() != ''">
                        <Table TableName="{current-grouping-key()}">
                            <xsl:for-each select="current-group()">
                                <xsl:attribute name="Stamp">
                                    <xsl:value-of select="@endTime"/>
                                </xsl:attribute>
                                <xsl:attribute name="measObjLdn">
                                    <xsl:value-of select="$curr_key"/>
                                </xsl:attribute>
                                <xsl:attribute name="Element_Type">
                                    <xsl:value-of select="@Element_Type"/>
                                </xsl:attribute>
                                <xsl:attribute name="Key1">
                                    <xsl:value-of select="@Key1"/>
                                </xsl:attribute>
                                <xsl:for-each select="@*">
                                    <xsl:if test="starts-with(name(), 'H')">
                                        <xsl:attribute name="{name()}">
                                            <xsl:value-of select="number(.)"/>
                                        </xsl:attribute>
                                    </xsl:if>
                                </xsl:for-each>
                            </xsl:for-each>
                        </Table>
                    </xsl:if>
                </xsl:for-each-group>
            </xsl:for-each-group>
        </root>
    </xsl:template>
</xsl:stylesheet>
Run Code Online (Sandbox Code Playgroud)

这是我的 JSON 输出代码，但没有按预期工作。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">
    <xsl:output method="text" encoding="utf-8"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="root">
        <xsl:text>{"root":{</xsl:text>
        <xsl:for-each-group select="Metric" group-by="@TableName">
            <xsl:sort select="current-grouping-key()"/>
            <xsl:if test="current-grouping-key() != ''">
                <xsl:text>"Table":[</xsl:text>
                <xsl:text>{"TableName":"</xsl:text>
                <xsl:value-of select="current-grouping-key()"/>
                <!--<Table TableName="{current-grouping-key()}">-->
                <xsl:text>",</xsl:text>
                <xsl:for-each-group select="current-group()" group-by="@measObjLdn">
                    <xsl:sort select="current-grouping-key()"/>
                    <xsl:for-each select="current-group()">
                        <xsl:text>"Stamp":"</xsl:text>
                        <xsl:value-of select="@endTime"/>
                        <xsl:text>",</xsl:text>
                        <xsl:text>"measObjLdn":"</xsl:text>
                        <xsl:value-of select="current-grouping-key()"/>
                        <xsl:text>",</xsl:text>
                        <xsl:text>"Element_Type":"</xsl:text>
                        <xsl:value-of select="@Element_Type"/>
                        <xsl:text>",</xsl:text>
                        <xsl:text>"Key1":"</xsl:text>
                        <xsl:value-of select="@Key1"/>
                        <xsl:text>",</xsl:text>
                        <xsl:for-each select="@attribute()">
                            <xsl:if test="starts-with(name(), 'H')">
                                <xsl:text>"</xsl:text>
                                <xsl:value-of select="name()"/>
                                <xsl:text>":"</xsl:text>
                                <xsl:value-of select="number(.)"/>
                                <xsl:text>"</xsl:text>
                                <xsl:if test="position() != last()">
                                    <xsl:text>,</xsl:text>
                                </xsl:if>
                            </xsl:if>
                        </xsl:for-each>
                    </xsl:for-each>
                </xsl:for-each-group>
                <!--</Table>-->
                <xsl:text>}</xsl:text>
                <xsl:if test="position() != last()">
                    <xsl:text>,</xsl:text>
                </xsl:if>
            </xsl:if>
        </xsl:for-each-group>
        <xsl:text>}</xsl:text>
    </xsl:template>
</xsl:stylesheet>
Run Code Online (Sandbox Code Playgroud)

好点子，所以 XML 版本将同一个表的所有属性组合在一起；鉴于上面的示例，XML 输出如下

<root xmlns:xs="http://www.w3.org/2001/XMLSchema">
<Table TableName="HH_ENODEB" Stamp="2016-08-25T04:30:00-07:00" measObjLdn="LTHBC0126858/GTPU:Board Type=MPT, Cabinet No.=0, Subrack No.=1, Slot No.=7" Element_Type="ENODEB" Key1="LTHBC0126858" H1526727075="0" H1526727076="0" H1526727077="0"/>
Run Code Online (Sandbox Code Playgroud)

JSON 示例输出不是我预期的 XML 版本的 JSON 版本。

{"root":{"Table":[{"TableName":"HH_ENODEB","Stamp":"2016-08-25T04:30:00-07:00","measObjLdn":"LTHBC0126858/GTPU:Board Type=MPT, Cabinet No.=0, Subrack No.=1, Slot No.=7","Element_Type":"ENODEB","Key1":"LTHBC0126858","H1526727075":"0""Stamp":"2016-08-25T04:30:00-07:00","measObjLdn":"LTHBC0126858/GTPU:Board Type=MPT, Cabinet No.=0, Subrack No.=1, Slot No.=7","Element_Type":"ENODEB","Key1":"LTHBC0126858","H1526727076":"0""Stamp":"2016-08-25T04:30:00-07:00","measObjLdn":"LTHBC0126858/GTPU:Board Type=MPT, Cabinet No.=0, Subrack No.=1, Slot No.=7","Element_Type":"ENODEB","Key1":"LTHBC0126858","H1526727077":"0"}}
Run Code Online (Sandbox Code Playgroud)

Tim*_*m C 5

您实际上并没有说您期望的 JSON 应该是什么样子，但是根据您的 XML，我假设它应该是这样的

{
  "root":
  {
    "Table":
    [
      {
        "TableName":"HH_ENODEB",
        "Stamp":"2016-08-25T04:30:00-07:00",
        "measObjLdn":"HH_ENODEB",
        "Element_Type":"ENODEB",
        "Key1":"LTHBC0126858",
        "H1526727075":"0",
        "H1526727076":"0",
        "H1526727077":"0"
      }
    ]
  }
}
Run Code Online (Sandbox Code Playgroud)

问题在于，在生成 XML 输出的 XSLT 中，您在 statement 中创建了 xsl:attributes <xsl:for-each select="current-group()">，但这意味着您要为单个Table元素重复输出相同的属性名称。在这种情况下，XSLT 只会用最新创建的属性替换任何现有属性，因此您不会注意到发生了什么。

当输出 JSON 时（或者更确切地说，当输出文本时，恰好是 JSON 格式），你最终会得到重复的属性，因为它只是文本。

解决方案是将主要属性的创建移到内部循环之外。

试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="root">
        <xsl:text>{&#10;  "root":&#10;  {&#10;</xsl:text>
            <xsl:for-each-group select="Metric" group-by="@measObjLdn">
                <xsl:sort select="current-grouping-key()"/>
                <xsl:variable name="curr_key" select="current-grouping-key()"/>
                <xsl:text>    "Table":&#10;    [&#10;</xsl:text>
                <xsl:for-each-group select="current-group()" group-by="@TableName">
                    <xsl:sort select="current-grouping-key()"/>
                    <xsl:if test="current-grouping-key() != ''">
                        <xsl:text>      {&#10;        "TableName":"</xsl:text>
                        <xsl:value-of select="current-grouping-key()"/>
                        <xsl:text>",&#10;</xsl:text>
                        <xsl:text>        "Stamp":"</xsl:text>
                        <xsl:value-of select="@endTime"/>
                        <xsl:text>",&#10;</xsl:text>
                        <xsl:text>        "measObjLdn":"</xsl:text>
                        <xsl:value-of select="$curr_key"/>
                        <xsl:text>",&#10;</xsl:text>
                        <xsl:text>        "Element_Type":"</xsl:text>
                        <xsl:value-of select="@Element_Type"/>
                        <xsl:text>",&#10;</xsl:text>
                        <xsl:text>        "Key1":"</xsl:text>
                        <xsl:value-of select="@Key1"/>
                        <xsl:text>"</xsl:text>
                        <xsl:for-each select="current-group()">
                            <xsl:for-each select="@*[starts-with(name(), 'H')]">
                                <xsl:text>,&#10;</xsl:text>
                                <xsl:text>        "</xsl:text>
                                <xsl:value-of select="name()"/>
                                <xsl:text>":"</xsl:text>
                                <xsl:value-of select="number(.)"/>
                                <xsl:text>"</xsl:text>
                            </xsl:for-each>
                        </xsl:for-each>
                        <xsl:text>&#10;      }&#10;</xsl:text>
                    </xsl:if>
                </xsl:for-each-group>
                <xsl:text>    ]&#10;</xsl:text>
            </xsl:for-each-group>
        <xsl:text>  }&#10;}</xsl:text>
    </xsl:template>
</xsl:stylesheet>
Run Code Online (Sandbox Code Playgroud)

  • 非常感谢您解释为什么会有不同的行为，对我来说，这比工作代码更重要。 (2认同)

归档时间：

查看次数：

8752 次

最近记录：

9 年，4 月 前
相关归档
在textarea输入中整理json数据 42
jed_decode在godaddy托管上失败 16
JSON模式 - 如果对象*不包含特定属性,则有效 13
该行动无法完成.(可可错误:3840.) 8
使用blob创建json文件 8
Json.Net序列化对象丢失其Id值 7
如何使用Python 3 json.dumps修复JSON密钥顺序？ 7
如何在xml解析中解析属性中的值 5
如何读取 .7z 扩展名文件的内容 5
带有修改的XSLT副本 2
难疑归档
迭代字典的最佳方法是什么？ 2455
如何从YouTube API获取YouTube视频缩略图？ 2291
**(双星/星号)和*(星号/星号)对参数有什么作用？ 2149
我如何递归grep？ 1619
你如何合并两个Git存储库？ 1517
每个'循环的Java'如何工作？ 1446
我在哪里可以找到有关在JavaScript中格式化日期的文档？ 1381
在Python中反转一个字符串 1288
你如何存放未跟踪的文件？ 1287
如何在Java中创建通用数组？ 1045