在Delphi中唤起实时模板时如何创建GUID？

Question

我在Delphi中使用了很多Live Templates,但他们试图想出一个将GUIDS添加到模板的解决方案.有谁知道如何做到这一点？

在模板下面我现在使用GUID作为单词我需要手动替换.

<?xml version="1.0" encoding="utf-8" ?>
<codetemplate   xmlns="http://schemas.borland.com/Delphi/2005/codetemplates"
            version="1.0.0">
<template name="iacc" surround="false" invoke="manual">
    <point name="name">
        <text>
            IntfAccessors
        </text>
        <hint>
            Accessors name
        </hint>
    </point>
    <description>
        accessor declaration
    </description>
    <author>
        PMH
    </author>
    <code language="Delphi" context="methoddecl" delimiter="|">    <![CDATA[I|name|Accessors = interface(IInterface)
GUID <-- here I want a GUID
end;


I|name| = interface(I|name|Accessors)
GUID <-- here I want a GUID
end;
    ]]>
        </code>
    </template>
</codetemplate>

Answer 1

您可以通过编写自定义脚本引擎来扩展IDE来执行此操作.(这是Nick Hodges写的一篇文章,其中有一个插入当前日期的类似例子.)

我假设你的示例模板中的两个不同的接口需要两个不同的IID,所以我编写了脚本引擎来加载"脚本"中的点名称(它只是名称=值对的列表,其中名称是点名称和value必须是NewGuid,否则会被忽略)因此您可以创建具有多个点的模板,每个点都接收一个单独的新IID.

示例模板intf.xml:

<?xml version="1.0" encoding="utf-8" ?>
<codetemplate   xmlns="http://schemas.borland.com/Delphi/2005/codetemplates" version="1.0.0">
<template name="iacc" surround="false" invoke="manual">
    <point name="name">
        <text>
            Accessor
        </text>
        <hint>
            Accessors name
        </hint>
    </point>
    <point name="guid1"/>
    <point name="guid2"/>
    <description>
        accessor declaration
    </description>
    <author>
        PMH
    </author>
    <script language="NewGuidScript" onvalidate="true">
        guid1=NewGuid
        guid2=NewGuid
    </script>
    <code language="Delphi" context="any" delimiter="|">    <![CDATA[I|name|Accessors = interface(IInterface)
|*||guid1|
end;

I|name| = interface(I|name|Accessors)
|*||guid2|
end;]]>
    </code>
    </template>
</codetemplate>

NewGuidScriptEngine.pas:

unit NewGuidScriptEngine;

interface

uses
  Classes, SysUtils,
  ToolsApi, CodeTemplateApi, DesignEditors;

type
  TNewGuidScriptEngine = class(TNotifierObject, IOTACodeTemplateScriptEngine)
  public
    procedure Execute(const ATemplate: IOTACodeTemplate; const APoint: IOTACodeTemplatePoint; const ASyncPoints: IOTASyncEditPoints; const AScript: IOTACodeTemplateScript; var Cancel: Boolean);
    function GetIDString: WideString;
    function GetLanguage: WideString;
  end;

procedure Register;

implementation

uses
  ActiveX,
  ComObj;

procedure Register;
begin
  (BorlandIDEServices as IOTACodeTemplateServices).RegisterScriptEngine(TNewGuidScriptEngine.Create);
end;

procedure TNewGuidScriptEngine.Execute(const ATemplate: IOTACodeTemplate; const APoint: IOTACodeTemplatePoint;
  const ASyncPoints: IOTASyncEditPoints; const AScript: IOTACodeTemplateScript; var Cancel: Boolean);
var
  I: Integer;
  Guid: TGUID;
  P: IOTACodeTemplatePoint;
  Points: TStringList;
begin
  Cancel := False;
  if not Assigned(ATemplate) then
    Exit;

  Points := TStringList.Create;
  try
    Points.Text := AScript.Script;
    for I := 0 to Points.Count - 1 do
      Points.Strings[I] := Trim(Points[I]);

    for I := 0 to Points.Count - 1 do
      if Points.ValueFromIndex[I] = 'NewGuid' then
      begin
        P := ATemplate.FindPoint(Points.Names[I]);
        if Assigned(P) then
        begin
          OleCheck(CoCreateGuid(Guid));
          P.Editable := False;
          P.Value := '[''' + GUIDToString(Guid) + ''']';
        end;
      end;
  finally
    Points.Free;
  end;
end;

function TNewGuidScriptEngine.GetIDString: WideString;
begin
  Result := 'OndrejKelle.NewGuidScriptEngine';
end;

function TNewGuidScriptEngine.GetLanguage: WideString;
begin
  Result := 'NewGuidScript';
end;

end.

将上述单元放入仅限designtime的包中,将designide.dcp的引用添加到其requires子句中,并在IDE中安装该包.

另一个有用的类似模板可能如下所示:

<?xml version="1.0" encoding="utf-8" ?>
<codetemplate   xmlns="http://schemas.borland.com/Delphi/2005/codetemplates" version="1.0.0">
<template name="iacc" surround="false" invoke="manual">
    <point name="name">
        <text>
        </text>
        <hint>
            Accessors name
        </hint>
    </point>
    <point name="guid1"/>
    <point name="guid2"/>
    <description>
        accessor declaration
    </description>
    <author>
        PMH
    </author>
    <script language="NewGuidScript" onvalidate="true">
        guid1=NewGuid
        guid2=NewGuid
    </script>
    <code language="Delphi" context="any" delimiter="|">    <![CDATA[const
  SIID_I|name|Accessors = |guid1|;
  IID_I|name|Accessors: TGUID = SIID_I|name|Accessors;
  SIID_I|name| = |guid2|;
  IID_I|name|: TGUID = SIID_I|name|;

type
  I|name|Accessors = interface
    [SIID_I|name|Accessors]
  end;

  I|name| = interface(I|name|Accessors)
    [SIID_I|name|]
  end;]]>
    </code>
    </template>
</codetemplate>

这将声明字符串以及TGUID常量,并在接口声明中重用它们.在这种情况下,插入的GUID值不应括在方括号中.您有几个选项可以调整脚本引擎来执行此操作:

1. 修改代码只是不使用方括号
2. 引入一个单独的新函数NewGuidNoBrackets并在模板中使用它
3. 介绍一些简单的语法,如NewGuid(false),你的引擎可以解析它,并使用参数值来确定是否应该使用方括号.