如何将列表列表作为参数提供给Robot Framework测试模板

Question

我有"do any combination"测试的模板关键字,其中$ {labels}是一个列表,$ {versions}是一个列表列表:

TT Process Instance Version Search
    [Arguments]     ${labels}    ${versions}
    Login
    Process Instance Version Search     ${labels}    ${versions}

然后我创建一个测试套件文件并放置以下内容:

*** Settings ***
Test Template   TT Process Instance Version Search


*** Variables ***
@{ProcessVersions} =   ${Process0}     ${Process1}     ${Process2}
@{SingleVersion} =  ${Process2}
@{Process0} =   1   2
@{Process1} =   3   test_version
@{Process2} =   1

@{SingleProcessLabel} =  Label1
@{ProcessLabels} =  Label1     Label2   Label3

    *** Test Cases ***                                     
Single Instance Version for a Single Process     ${SingleProcessLabel}   ${SingleVersion}
Distinct Instance Versions for Multiple Processes    ${ProcessLabels}  ${ProcessVersions}

我得到的错误信息是"列表变量'@ {versions}'在索引0中没有项目."

我玩了很多,包括使用嵌入式参数,以及我管理修复它的唯一方法是直接提供$ version作为全局变量.我的代码适用于全局变量,但我必须手动更改数据.我真正需要的是实现数据驱动设计.

非常感谢任何建议和帮助!

Answer 1

从评论到你写的问题:

问题是:如何将列表列表作为参数提供给测试模板？

答案就是在机器人框架用户指南的" 列表变量 "一节中记录的.调用关键字时,如果$在变量前面使用a ,则该变量将被视为列表对象.如果使用@,变量将被拆分为多个参数.

在编写接受参数的关键字时,情况也是如此.如果需要单个参数,请使用a $作为参数变量.如果要将所有参数收集为列表,请使用@.

这是一个测试,显示了几个例子:

*** Variables ***
@{numbers}    1    2    3
@{letters}    a    b    c    d
@{listoflists}    ${numbers}    ${letters}

*** Keywords ***
Accept list of lists as single arg
    [Arguments]         ${arguments}
    length should be    ${arguments}       2
    length should be    ${arguments[0]}    3
    length should be    ${arguments[1]}    4

Accept multiple args
    [Arguments]         @{arguments}
    length should be    ${arguments}       2
    length should be    ${arguments[0]}    3
    length should be    ${arguments[1]}    4


*** Test cases ***
Pass list of lists as single argument
    Accept list of lists as single arg       ${listoflists}

Pass list of lists as multiple arguments
    Accept multiple args    @{listoflists}
    Accept multiple args    ${numbers}    ${letters}