如何进行64位十六进制/十进制算术并在HEX中输出一个完整的数字作为Perl中的字符串？

Question

我需要用下面的大十六进制数做一些算术,但是当我尝试输出时,我得到溢出错误消息"十六进制数> 0xffffffff非可移植",有关不可移植的消息,或最大32位十六进制值FFFFFFFF.

所有这些都意味着标准语言和输出例程只能处理32位值.我需要64位值,并做了很多研究,但我没有发现BOTH启用算术AND以十六进制输出大数字.

my $result = 0x00000200A0000000 +
             ( ( $id & 0xFFFFF ) * 2 ) + ( ( $id / 0x100000 ) * 0x40000000 );

因此,对于具有以下值的$ id,我应该得到$result:

$id = 0, $result = 0x00000200A0000000
$id = 1, $result = 0x00000200A0000002
$id = 2, $result = 0x00000200A0000004

我怎样才能做到这一点？

以下是我不确定的研究结果,原因如下:

• 如何在Perl中进行64位运算？

• 如何在Perl中求和大十六进制值？模糊,回答不是确切的精确,没有例子.

• 整数溢出 无定论

• 整数溢出 无定论

• bigint 没有关于赋值,算术或输出的信息

• bignum 例子不接近我的问题.

• 我怎样才能在Perl中使用大字符？ 给出的示例对我来说不够信息:不处理十六进制赋值或算术.

• Re:密码生成器 使用Fleximal的一些例子,提到to_str输出变量的值但1)我没看到变量是如何分配的,2)我得到错误"无法调用方法"to_str"没有包或对象参考"当我使用它运行我的代码时.

• 字符串到十六进制 使用Math :: BigInt的示例对我不起作用 - 仍然会出现溢出错误.

• 是否有64位十六进制()？ 几乎在那里 - 但不处理以十六进制输出大数字,它只涉及十进制.

• CPAN Math:Fleximal 执行算术运算,但似乎没有任何方法可以实际输出仍为十六进制的值

• sprintf 似乎无法处理大于32位的数字,得到饱和的FFFFFFFF消息.

---

编辑:更新 - 新要求和提供的解决方案 - 请随时提供评论

查斯.欧文斯的答案仍然被接受和优秀(第2部分对我有效,没有尝试过新的Perl的第1部分版本,尽管我会邀请其他人确认).

但是,另一个要求是能够从结果转换回原始id.

所以我写了代码来做这个,这是完整的解决方案,包括@Chas.欧文斯原始解决方案,然后实施这一新要求:

#!/usr/bin/perl

use strict;
use warnings;
use bigint;

use Carp;

sub bighex {
    my $hex = shift;

    my $part = qr/[0-9a-fA-F]{8}/;
    croak "$hex is not a 64-bit hex number"
        unless my ($high, $low) = $hex =~ /^0x($part)($part)$/;

    return hex("0x$low") + (hex("0x$high") << 32);
}

sub to_bighex {
    my $decimal = shift;
    croak "$decimal is not an unsigned integer"
            unless $decimal =~ /^[0-9]+$/;

    my $high = $decimal >> 32;
    my $low  = $decimal & 0xFFFFFFFF;

    return sprintf("%08x%08x", $high, $low);
}

for my $id (0 ,1, 2, 0xFFFFF, 0x100000, 0x100001, 0x1FFFFF, 0x200000, 0x7FDFFFFF ) {
    my $result = bighex("0x00000200A0000000");
    $result += ( ( $id & 0xFFFFF ) * 2 ) + ( ( $id / 0x100000 ) * 0x40000000 );

    my $clusterid = to_bighex($result);

# the convert back code here:
my $clusterid_asHex = bighex("0x".$clusterid);
my $offset = $clusterid_asHex - bighex("0x00000200A0000000");
my $index_small_units = ( $offset / 2 ) & 0xFFFFF;
my $index_0x100000_units = ( $offset / 0x40000000 ) * 0x100000;
my $index = $index_0x100000_units + $index_small_units;


    print "\$id = ".to_bighex( $id ).
          " clusterid = ".$clusterid.
          " back to \$id = ".to_bighex( $index ).
          " \n";
}

请在http://ideone.com/IMsp6上试用此代码.

Answer 1

#!/usr/bin/perl

use strict;
use warnings;

use bigint qw/hex/;

for my $id (0 ,1, 2) {
    my $result = hex("0x00000200A0000000") + 
        ( ( $id & 0xFFFFF ) * 2 ) + ( ( $id / 0x100000 ) * 0x40000000 );
    printf "%d: %#016x\n", $id, $result;
}

该bigintpragma hex用一个可以处理大数字的版本替换该函数.它还透明地使数学运算符处理大的int而不是目标平台上的int.

注意,这仅适用于Perl 5.10及更高版本.如果您运行的是早期版本的Perl 5,可以尝试这样做:

#!/usr/bin/perl

use strict;
use warnings;
use bigint;

use Carp;

sub bighex {
    my $hex = shift;

    my $part = qr/[0-9a-fA-F]{8}/;
    croak "$hex is not a 64-bit hex number"
        unless my ($high, $low) = $hex =~ /^0x($part)($part)$/;

    return hex("0x$low") + (hex("0x$high") << 32);
}

sub to_bighex {
    my $decimal = shift;
    croak "$decimal is not an unsigned integer"
            unless $decimal =~ /^[0-9]+$/;

    my $high = $decimal >> 32;
    my $low  = $decimal & 0xFFFFFFFF;

    return sprintf("%08x%08x", $high, $low);
}

for my $id (0 ,1, 2) {
    my $result = bighex("0x00000200A0000000");
    $result += ( ( $id & 0xFFFFF ) * 2 ) + ( ( $id / 0x100000 ) * 0x40000000 );
    print "$id ", to_bighex($result), "\n";
}