Spring4D中的TForm管理

Question

我有以下代码:

Project.dpr

program Project2;

uses
  madExcept,
  madLinkDisAsm,
  madListHardware,
  madListProcesses,
  madListModules,
  Spring.Container,
  Vcl.Forms,
  uRegistrations in '..\Memory leak II\uRegistrations.pas',
  Unit3 in 'Unit3.pas' {MainForm},
  Unit4 in 'Unit4.pas' {SecondaryForm},
  Unit5 in 'Unit5.pas';

{$R *.res}

begin
  RegisterTypes(GlobalContainer);
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
//  MainForm:=TMainForm.Create(nil);
  Application.CreateForm(TMainForm, MainForm);
  MainForm.SecondaryForm := Globalcontainer.Resolve<ISecondaryForm>;
  Application.Run;
end.

注册接口的uRegistrations.pas

unit uRegistrations;

interface

uses
  Spring.Container;

procedure RegisterTypes(Container: TContainer);

implementation

uses
  Unit5,
  Unit4;

procedure RegisterTypes(Container: TContainer);
begin
  container.RegisterType<ISecondaryForm, TSecondaryForm>.DelegateTo(
    function: TSecondaryForm
    begin
      result := TSecondaryForm.Create(nil);
    end);
  Container.Build;

end;

end.

Unit3.pas持有主表格

unit Unit3;

interface

uses
  Winapi.Windows,
  Winapi.Messages,
  System.SysUtils,
  System.Variants,
  System.Classes,
  Vcl.Graphics,
  Unit5,
  Vcl.Controls,
  Vcl.Forms,
  Vcl.Dialogs;

type
  TMainForm = class(TForm)
  private
    { Private declarations }
    FSecondaryForm: ISecondaryForm;
  public
    { Public declarations }
    property SecondaryForm: ISecondaryForm read FSecondaryForm write FSecondaryForm;
  end;

var
  MainForm: TMainForm;

implementation

{$R *.dfm}

end.

Unit4.pas与次要表格

unit Unit4;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  unit5,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TSecondaryForm = class(TForm, ISecondaryForm)
  private
    { Private declarations }
  public
    { Public declarations }
  end;

//var
//  SecondaryForm: TSecondaryForm;

implementation

{$R *.dfm}

end.

最后是Unit5.pas和Interface声明

{$M+}
unit Unit5;

interface

type
ISecondaryForm=interface
  ['{62D63E9A-A3AD-435B-8938-9528E70D78B1}']
end;

implementation

end.

它会定期编译和运行,但是当我关闭应用程序时,我有三次内存泄漏.

分配号码:8482程序运行时间:721 ms类型:刷柄处理:$ 461027f5样式:BS_SOLID颜色:$ f0f0f0

分配号码:8318程序运行时间:697 ms类型:TSecondaryForm地址:$ d51ac64大小:924访问权限:读/写

分配编号:8267程序运行时间:693 ms类型:字体手柄:$ 1d0a28f1面:Tahoma高度:-11

为什么会发生这种情况,我该如何解决？

编辑

在答案之后,我实施了以下解决方案(评论突出了我得到的错误:

procedure RegisterTypes(Container: TContainer);
begin
  container.RegisterType<ISecondaryForm, TSecondaryForm>.DelegateTo(
    function: TSecondaryForm
    begin
      result := TSecondaryForm.Create(nil);

      result.Owner:=Application.MainForm;//cannot assign to a read-only property
      result.Parent:=Application; //incompatible types
      result.Parent:=application.MainForm;//memory leak

    end);
  Container.Build;

end;

我还试图通过以下方式修改TSecondaryForm的OnClose方法:

procedure TSecondaryForm.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action:=caFree; //memory leak
end;

但我得到了内存泄漏.

上面的所有技术我做错了什么？

最后我只是按照注释中的建议制作了两个方法_AddRef和_Release来管理引用计数,我没有更多的内存泄漏.

  TSecondaryForm = class(TForm, ISecondaryForm)
  private
    { Private declarations }
  protected
    FRefCount: Integer;
    function _AddRef: Integer; stdcall;
    function _Release: Integer; stdcall;
  public
    { Public declarations }
  end;

function TSecondaryForm._AddRef: Integer;
begin
  Result := InterlockedIncrement(FRefCount);
end;

function TSecondaryForm._Release: Integer;
begin
  Result := InterlockedDecrement(FRefCount);
  if Result=0 then
    self.Free;
end

Answer 1

如果您希望通过接口引用计数来处理表单(或从TComponent继承的任何类),那么您需要自己实现它(System.TInterfacedObject作为如何执行它的示例).

您基本上需要重新实现IInterface要启用引用计数的类:

type
  TInterfacedForm = class(TForm, IInterface)
    // look at System.TInterfacedObject
  end;

如果您这样做,请记住它不应由所有者机制处理.如果您将它注册到容器并使用其默认创建机制,它将从Spring4D 1.2开始将nil传递给所有者 - 请参阅参考资料Spring.Container.Resolvers.TComponentOwnerResolver.在任何版本之前,您需要使用nil显式创建它DelegateTo.

如果您正在处理通过其父属性放置到其他控件(如框架)上的接口的任何控件,请记住,在这种情况下,另一个内存管理机制会起作用,如果其父组件被破坏,可能会破坏此类组件 - 如果你只是处理不是问题的接口表单,但我想我在这里提到完整性.