Common LISP (SBCL)：从循环内返回值

Question

前言：我目前正在学习一门显然是用 LISP 教授的浓缩课程，而且我一生中从未使用过 LISP，所以我不得不在一个周末学习语言。我提前为糟糕的代码道歉。我只是对 LISP 的语法足够熟悉，可以使代码正常工作，仅此而已。

我目前正在开发一个解决地图着色问题的程序。此代码采用一个序列，其中每个子序列的第一个元素是状态，第二个元素表示颜色。例如：'((AR) (BG) (CG) (DY) (EB) (FB)) 然后检查以确保没有状态与它所约束的状态（由约束列表定义）具有相同的颜色。我知道可能有很多更简洁更简单的方法来做到这一点，但我目前正在努力的是让我的 dolist 循环在满足 if 语句时立即返回值 T。到目前为止，我一直无法让函数简单地返回一个值，并且不得不求助于这种将变量设置为 true 并等待循环完成以使代码工作的非常丑陋/错误的方法。一世'

(setq constraint '((A (B C E)) (B (A E F)) (C (A E F)) (D (F)) (E (A B C F)) (F (B C D E))))

(defun check_constraint (f s)
    (setf ans nil)
    (dolist (state constraint)
        (if (eq (first state) f)
            (if (search (list s) (second state))
                (setf ans T) ;;where I want it to just return T
            )
        )
    )
    ans
)

;;ex: ((A R) (B R)  (C B)  (D R)  (E B)  (F G))
(defun check_conflict (lst)
    (setf anb nil)
    (dolist (state lst)
        (dolist (neighbor (remove state lst))
            (if (check_constraint (first state) (first neighbor))
                (if (eq (second state) (second neighbor))
                    (setf anb T)) ;;where I want it to just return T
            )
        )
    )
    anb
)

编辑：我最终只是用递归来解决这个问题。代码现在更干净了，但我仍然很想知道我的问题是什么。这是递归代码。

(setq constraint '((A (B C E)) (B (A E F)) (C (A E F)) (D (F)) (E (A B C F)) (F (B C D E))))

(defun check_constraint (lst f s)
    (COND
        ((null lst) nil)
        ((search (list (car (car lst))) f)
            (if (search s (second (car lst))) T))
        (t (check_constraint (cdr lst) f s))
    )
)

(defun check_neighbor (check lst)
    (COND
        ((null lst) nil)
        ((check_constraint constraint (list (car check)) (list (first (first lst))))
            (if (eq (second check) (second (car lst))) T))
        (t (check_neighbor check (cdr lst)))
    )
)

;;(check_state '((A R) (B R) (C B) (D R) (E B) (F G)))
(defun check_state (lst)
    (COND
        ((null lst) nil)
        ((check_neighbor (car lst) (cdr lst)) T)
        (t (check_state (cdr lst)))
    )
)

Answer 1

首先是一些风格问题。您应该使用DEFVAR或DEFPARAMETER来声明全局变量。这些名称还应该有星号，以表明它们是全局的（或实际上是特殊的）。

(defparameter *constraint*
  '((A (B C E))
    (B (A E F))
    (C (A E F))
    (D (F))
    (E (A B C F))
    (F (B C D E))))

命名事物的 lisp 约定是在单词之间使用破折号（CHECK-CONSTRAINT而不是CHECK_CONSTRAINT）。您还应该更喜欢变量名称的完整单词而不是缩写（LIST而不是LST）。右括号不应该单独写一行。

然后是实际问题。您可以使用RETURN从名为 的块返回值NIL。循环建立这样一个块，因此您可以编写第一个函数，例如

(defun check-constraint (first second)
  (dolist (state *constraint*)
    (when (and (eq first (first state))
               (member second (second state)))
      (return t))))

最好使用WHEN而不是IF只有 then 分支时。我还IF使用将两个s合二为一AND。由于您包含S在一个列表中以供使用SEARCH，我想您可能想MEMBER改用（尽管我不确定，因为我不完全知道代码应该做什么）。如果错了，你可以改回来。

您可能也可以将其简化为

(defun check-constraint (first second)
  (member second (second (find first *constraint* :key #'first))))

在第二个函数中，您有两个循环。如果您使用RETURN从内部循环返回，您最终只会继续外部循环并忽略返回值。所以你必须使用RETURN-FROM从函数而不是内部循环返回。

(defun check-conflict (list)
  (dolist (state list)
    (dolist (neighbor (remove state list))
      (when (and (check-constraint (first state) (first neighbor))
                 (eq (second state) (second neighbor)))
        (return-from check-conflict t)))))