CMakeExternalProject_add 与子文件夹上的 CMakeLists

Question

我正在尝试使用ExternalProject_Add 命令从cmake 下载并构建DevIL，但由于某种原因，git 存储库在项目的子文件夹中包含CMakeLists.txt 文件。

我似乎无法找到一种方法使ExternalProject_add 在正确的文件夹上调用cmake。我尝试使用 prefix 和 source_dir，但仍然失败。

然后，我在网上看到一个答案，其中涉及创建一个临时的 CMakeLists.txt，它将调用正确的 cmake 路径。但由于我不知道如何提供 cmake 调用的路径，这意味着我必须将其放入下载的 git 存储库中，后来证明这很痛苦......这是我正在使用的当前命令：包括（“外部项目”）

######### Search for required third-party libraries. If not found, attempt to download and build them ########

set ( DEVIL_ROOT "${THIRD_PARTY_OUTPUT_PATH}/DevIL" )
option ( BUILD_DEVIL "Download and build DevIL" FALSE )

find_package ( Devil )
if ( NOT DEVIL_FOUND )
    message ( STATUS "DevIL not found. Forcing to build own copy...")
    set ( BUILD_DEVIL TRUE )
endif()

if ( BUILD_DEVIL )
set ( DEVIL_BUILD_PATH "${THIRD_PARTY_BUILD_PATH}/DevIL/" )
set ( DEVIL_OUTPUT_PATH "${THIRD_PARTY_OUTPUT_PATH}/DevIL" )

message ( STATUS "Downloading DevIL and building...")
file( WRITE ${DEVIL_BUILD_PATH}/DevilCMakeLists.txt "cmake_minimum_required( VERSION 3.0 ) \n  add_subdirectory ( DevIL )" )
ExternalProject_Add ( ThirdParty_DevIL
    PREFIX "${DEVIL_BUILD_PATH}"
    GIT_REPOSITORY "https://github.com/DentonW/DevIL"
    PATCH_COMMAND cmake -E copy "${DEVIL_BUILD_PATH}/DevilCMakeLists.txt" "${DEVIL_BUILD_PATH}/src/ThirdParty_DevIL/DevIL/"
    INSTALL_DIR ${DEVIL_OUTPUT_PATH}
    CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR> )

list ( APPEND THIRD_PARTY_DEPENDENCIES ThirdParty_DevIL )
set ( DEVIL_INCLUDE_DIR "${DEVIL_OUTPUT_PATH}/include" )
set ( DEVIL_LIBRARY devil )
add_definitions ( -DDEVIL )
endif()

list ( APPEND THIRD_PARTY_INCLUDE_DIRS "${DEVIL_INCLUDE_DIR}" )
list ( APPEND THIRD_PARTY_LIBRARIES ${DEVIL_LIBRARY} )

我尝试对这样的路径进行硬编码（“/src/ThirdParty_DevIL/”部分），但它很难看，如果 cmake 决定将来更改它，它就会崩溃。另外，由于这实际上是在 git 树中复制文件，cmake 后来抱怨

Failed to unstash changes in:
'<yadda yadda>/ThirdParty/build//DevIL//src/ThirdParty_DevIL/'.


You will have to resolve the conflicts manually

有没有办法使这个解决方案（创建临时 CMakeListst.txt ）起作用？或者甚至更好，是否还有另一种解决方案，只需正确配置ExternalProject_add？

我对参数、路径等没有任何要求，所以请随意提出任何建议。我怎样才能解决这个问题？谢谢

Answer 1

您可以提供CONFIGURE_COMMAND选项，而不是修补源树，该选项使用正确的目录作为源：

ExternalProject_Add ( ThirdParty_DevIL
    PREFIX "${DEVIL_BUILD_PATH}"
    GIT_REPOSITORY "https://github.com/DentonW/DevIL"
    INSTALL_DIR ${DEVIL_OUTPUT_PATH}
    CONFIGURE_COMMAND ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
        <SOURCE_DIR>/DevIL # Tell CMake to use subdirectory as source.
)

在这种情况下，您应该手动向此命令添加一些内容，这些内容通常由CMAKE_ARGS、CMAKE_CACHE_ARGS等选项给出。但这不应该是一个真正的问题。

或者，您可以分为ExternalProject_Add两个调用：一个仅下载包，第二个执行其他所有操作。在这些调用中，您可以使用不同的SOURCE_DIR选项：

ExternalProject_Add ( ThirdParty_DevIL_download
    PREFIX "${DEVIL_BUILD_PATH}"
    SOURCE_DIR "${DEVIL_BUILD_PATH}/src/ThirdParty_DevIL" # Explicitely set
    GIT_REPOSITORY "https://github.com/DentonW/DevIL"
    CONFIGURE_COMMAND "" # Disable all other steps
    BUILD_COMMAND ""
    INSTALL_COMMAND ""
)

ExternalProject_Add ( ThirdParty_DevIL
    PREFIX "${DEVIL_BUILD_PATH}"
    DOWNLOAD_COMMAND "" # Disable download step
    SOURCE_DIR "${DEVIL_BUILD_PATH}/src/ThirdParty_DevIL/DevIL" # Source dir for configuration
    INSTALL_DIR ${DEVIL_OUTPUT_PATH}
    CMAKE_CACHE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
)

# Add dependency between to calls
add_dependencies(ThirdParty_DevIL ThirdParty_DevIL_download)

由于基于PREFIX的SOURCE_DIR计算取决于外部项目的名称，并且两次调用的名称不同，因此显式设置此选项。

这种方法的缺点是构建日志显示有关许多“未执行”步骤的行（第一次ExternalProject_Add()调用的配置、构建和安装以及第二次调用的下载、路径和更新）。