如何将flowtype与spacemacs集成

Question

我是spacemacs的粉丝.我想使用Facebook Flow,但我不知道如何将它与spacemacs集成.我正在使用流程,nuclide但我需要重新学习所有内容才能提高效率.有这个脚本在flow仓库与emacs的使用它.我需要一个如何在spacemacs中使用它的指南.

谢谢.

Answer 1

我在这里使用了Bodil的flow flycheck配置:https://github.com/bodil/emacs.d/blob/d28264cf072bb8a62459a48813d0cb30804b4f5b/bodil/bodil-js.el#L121-L154

react-mode通过将以下内容添加到我的dotspacemacs/user-config(https://github.com/saltycrane/.spacemacs.d/blob/9d985ace9251529c2b8d7857e2ec9835b103084c/init.el#L383-L414),我使用了spacemacs 和默认的eslint flychecker :

;; Flow (JS) flycheck config (http://flowtype.org)
;; from https://github.com/bodil/emacs.d/blob/master/bodil/bodil-js.el
(require 'f)
(require 'json)
(require 'flycheck)

(defun flycheck-parse-flow (output checker buffer)
  (let ((json-array-type 'list))
    (let ((o (json-read-from-string output)))
      (mapcar #'(lambda (errp)
                  (let ((err (cadr (assoc 'message errp))))
                    (flycheck-error-new
                     :line (cdr (assoc 'line err))
                     :column (cdr (assoc 'start err))
                     :level 'error
                     :message (cdr (assoc 'descr err))
                     :filename (f-relative
                                (cdr (assoc 'path err))
                                (f-dirname (file-truename
                                            (buffer-file-name))))
                     :buffer buffer
                     :checker checker)))
              (cdr (assoc 'errors o))))))

(flycheck-define-checker javascript-flow
  "Javascript type checking using Flow."
  :command ("flow" "--json" source-original)
  :error-parser flycheck-parse-flow
  :modes react-mode
  :next-checkers ((error . javascript-eslint))
  )
(add-to-list 'flycheck-checkers 'javascript-flow)

还要确保已安装Flow命令行工具.像这样安装:

npm install -g flow-bin

我认为Bodil打算让消息简短,但我想让flycheck显示更详细的消息.如果有人知道如何做到这一点,我会很感激.

编辑2016-08-12:我发布的原始版本Symbol's function definition is void: flycheck-define-checker在初始加载时出错.我更新了上面的代码,添加了一个require 'flycheck去除该错误.