自动增量发布版本Jenkins

Question

我有一个在Jenkins中构建的应用程序,我想部署到Octopus.当我这样做时,我必须创建一个发送到Octopus的发布版本.对于此次发布的版本我必须给一个号码(例如:"C:\Octopus\Octo.exe" create-release --project APP --version 4.8 --packageversion=4.8)

如何使版本号自动递增？(例如:我已经构建了应用程序并在Octopus中创建了版本号4.8,下次我构建应用程序时我想创建版本号4.9)

谢谢

Answer 1

如果您正在从 git 存储库进行部署，您可能已经为每个版本创建了标签（或者您至少应该这样做，以便您可以更轻松地跟踪部署的内容）。如果是这种情况，您可以从这些标签中导出下一个发布版本，而无需将版本存储在其他任何地方（只需确保 Jenkins 在高级克隆行为中获取标签）。

然后，您可以使用以下内容计算下一个版本：

def nextVersionFromGit(scope) {
    def latestVersion = sh(returnStdout: true, script: 'git describe --tags --abbrev=0 --match *.*.* 2> /dev/null || echo 0.0.0').trim()
    def (major, minor, patch) = latestVersion.tokenize('.').collect { it.toInteger() }
    def nextVersion
    switch (scope) {
        case 'major':
            nextVersion = "${major + 1}.0.0"
            break
        case 'minor':
            nextVersion = "${major}.${minor + 1}.0"
            break
        case 'patch':
            nextVersion = "${major}.${minor}.${patch + 1}"
            break
    }
    nextVersion
}

此方法使用语义版本控制格式，但如果您想要只有 2 个数字的版本，则可以轻松调整。

Answer 2

您可以使用作业属性来存储版本,然后使用以下脚本在每次运行时更新它(由"执行系统groovy脚本"构建步骤执行):

import jenkins.model.Jenkins
import hudson.model.*

def jenkins = Jenkins.getInstance()
def jobName = "yourJobName"
String versionType = "minor"
def job = jenkins.getItem(jobName)

//get the current version parameter and update its default value
paramsDef = job.getProperty(ParametersDefinitionProperty.class)
if (paramsDef) {
   paramsDef.parameterDefinitions.each{
       if("version".equals(it.name)){
           println "Current version is ${it.defaultValue}"
           it.defaultValue = getUpdatedVersion(versionType, it.defaultValue)
           println "Next version is ${it.defaultValue}"
       }
   }
}

//determine the next version by the required type 
//and incrementing the current version

def getUpdatedVersion(String versionType, String currentVersion){

    def split = currentVersion.split('\\.')
    switch (versionType){
        case "minor.minor":
            split[2]=++Integer.parseInt(split[2])
            break
        case "minor":
            split[1]=++Integer.parseInt(split[1])
            break;
        case "major":
           split[0]=++Integer.parseInt(split[0])
           break;
    }
    return split.join('.')
}

Answer 3

Jenkins提供了一些可用于每个构建命令的环境变量。其中之一是内部版本号，数量不断增加。

如果您可以在版本号中留空，请更改版本以包含内部版本号，例如4.8-142，其中142是jenkins的内部版本号。这使您可以从语义上增加版本号，并且仍然可以通过更多功能来控制实际版本。

如果您对版本中的内部版本号不满意，则应该拥有一个后构建脚本，用于更新版本号并将其存储在某个文件中。然后，您可以使用EnvInject插件或使用参数化的构建来注入该文件内容。