使用注解处理生成单元测试

Question

使用注解处理生成单元测试

Víc*_*tos 5 java junit annotation-processing android-studio

我一直在寻找有关此事的信息，但找不到任何有用的资源。

我需要使用注释处理生成单元测试。我生成一个可以作为单元测试的类没有问题。我不知道该怎么做是将这些生成的文件放在正确的文件夹中。

默认情况下，输出将位于build/generated/source/apt/debug文件夹中，但我需要将这些文件放在build/generated/source/apt/test. 我猜。我的意思是我在注释处理之前使用过，但我从未用于生成单元测试，所以我不知道在何处或如何定位它们的正确方法是什么。

顺便说一下，我使用的是 Android Studio 2.0。

Answer 1

Xav*_*ler 5

您的另一个选择是编写一个简单的 Gradle 插件，根据您的需要配置项目。通过编写自己的插件，您可以配置所需的一切，例如为注解处理器添加依赖项，然后修改 javaCompile 任务以将生成的依赖项移动到您想要的文件夹。

现在我意识到这可能看起来有些过分，但是 Gradle 插件非常强大并且很容易制作。如果您能够克服编写 Groovy 代码的初始学习曲线（我假设您除了在 build.gradle 文件中之外没有使用 Groovy），那么它可以是一个非常快速和简单的选择来做您想做的事情

在我开始解释如何将 Gradle 插件与库结合使用之前，让我解释一下我在做什么：

我曾经写过一个名为ProguardAnnotations的库，它需要做的比单独使用注释处理器所能做的更多。在我的情况下，我需要配置项目的 proguard 设置以使用由我的注释处理器生成的 proguard 规则文件。实现插件并没有太多工作，除了配置 proguard 设置之外，我还可以使用它来将我的注释处理器的依赖项添加到项目中。然后我将插件发布到 Gradle Plugin Repository 所以现在使用我的插件来添加所有必需的依赖项并适当地配置项目所有用户必须做的就是在他们的 build.gradle 文件的顶部：

plugins {
    id "com.github.wrdlbrnft.proguard-annotations" version "0.2.0.51"
}

Run Code Online (Sandbox Code Playgroud)

所以你可以看到这如何使使用你的库变得非常简单。只需添加这个 Gradle 就可以发挥它的魔力并处理所有插件配置。

现在让我们来看看插件本身。作为参考，此链接将带您到我为我的库编写的 Gradle 插件。您的插件最终应该看起来非常相似。

让我们先看看项目结构，为了简单起见，我将向您展示我为我的库编写的 Gradle 插件的屏幕截图。这应该是 Gradle 插件所需的最简单设置：

[ Gradle 插件项目设置][1]

这里有三个重要的部分。Gradle 使用 Groovy 作为其首选的脚本语言。因此，您需要做的第一件事是在此处获取 Groovy SDK：http : //groovy-lang.org/download.html

我建议你使用 IntelliJ 来编写 Gradle 插件，但理论上 Android Studio 应该与一些附加配置一样工作。

由于我们正在编写 groovy 代码，因此您需要将代码放在src/main/groovy文件夹中而不是src/main/java. 您的源文件本身需要有一个.groovy扩展名而不是.java. IntellIj 在这里非常棘手，因为即使您在src/main/groovy文件夹中工作，它仍然总是主要提示您创建 java 文件，只需注意文件名旁边的图标形状即可。如果它是方形而不是圆形，那么您正在处理一个常规文件。除了编写 Groovy 代码之外，Groovy 代码非常简单——每个有效的 Java 代码在 Groovy 中也有效——因此您可以像在 Java 中习惯的那样开始编写代码，然后它就会编译。对于初学者，我不建议使用所有额外的 Groovy 功能，因为它可能会非常混乱。

另一个非常重要的部分是资源文件夹。在屏幕截图中，您可以看到文件夹中的属性文件src/main/resources/META-INF/gradle-plugins。这个属性文件决定了你的 Gradle 插件的 id——本质上是名称。它本质上非常简单：属性文件的名称就是您的 Gradle 插件的名称！屏幕截图中的属性文件被调用，com.github.wrdlbrnft.proguard-annotations.properties所以我的 Gradle 插件的名称是com.github.wrdlbrnft.proguard-annotations. 如果你想在你的 build.gradle 文件中应用它，你可以在你的 apply 语句中使用该名称：apply project: 'com.github.wrdlbrnft.proguard-annotations'或者如上id一plugins节中所示！

最后一部分是 build.gradle 本身。您需要将其配置为能够编译 groovy 代码，并且您需要 Gradle 插件所需的所有依赖项。幸运的是，您只需要五行代码：

apply plugin: 'groovy'

dependencies {
    compile gradleApi()
    compile localGroovy()
}

Run Code Online (Sandbox Code Playgroud)

有了 build.gradle 中的这个基本设置，也许对你的 IDE 设置稍微调整一下，你应该准备好编写自己的 Gradle 插件了。

现在让我们创建插件类本身。选择 Java 中的包名并创建适当的 groovy 文件，例如 YourLibraryPlugin.groovy。Gradle 插件的基本样板如下所示：

package com.github.example.yourlibrary

import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.ProjectConfigurationException

/**
 * Created by Xaver Kapeller on 11/06/16.
 */
class YourLibraryPlugin implements Plugin<Project> {

    @Override
    void apply(Project project) {

    }
}

Run Code Online (Sandbox Code Playgroud)

现在，与 Java 相比，您的 Groovy 代码中有两点不同：

您不需要指定类的可见性。在 Java 代码中不指定任何包本地可见性通常是最好的选择。但是，您可以根据需要指定公开可见性，没有任何变化。
如果您查看导入，您会发现每行末尾没有分号。在 Groovy 中，分号完全是可选的。你在任何地方都不需要它们。但是有也没关系。他们只是不需要。

该类本身是您的主要 Plugin 类。它是您的插件开始发挥其魔力的地方。apply(Project)一旦您的插件应用于项目，就会调用该方法。如果想详细了解apply plugin: 'com.android.application'build.gradle 文件中的语句是做什么的 - 现在您有了答案。他们创建插件类的一个实例，并使用 Gradle 项目作为参数调用 apply 方法。

通常，您在 apply 方法中要做的第一件事是：

@Override
void apply(Project project) {
    project.afterEvaluate {

    }
}

Run Code Online (Sandbox Code Playgroud)

现在project.afterEvaluate意味着afterEvaluate在整个 build.gradle 被评估后调用括号内的代码。这是一件好事，因为您的插件可能依赖于应用到项目的其他插件，但开发人员可能将这些apply project: ...语句放在apply project: ...引用您插件的语句之后。因此，在其他方面，通过致电afterEvaluate您确保至少在您做任何事情之前已经完成了基本的项目配置，这可以避免错误并减少使用您插件的开发人员的摩擦。但你不应该过度。您可以立即配置有关项目的所有内容都应该立即生效。但是，在您的情况下，现在无事可做，因此我们继续afterEvaluate声明。

例如，您现在可以做的第一件事是为您的注释处理器添加依赖项。所以这意味着您的用户只需要应用插件，而不必担心自己添加任何依赖项。

@Override
void apply(Project project) {
    project.afterEvaluate {
        project.afterEvaluate {

            project.dependencies {
                compile 'com.github.wrdlbrnft:proguard-annotations-api:0.2.0.44'
                apt 'com.github.wrdlbrnft:proguard-annotations-processor:0.2.0.44'
            }
        }
    }
}

Run Code Online (Sandbox Code Playgroud)

将依赖项添加到项目就像在 build.gradle 文件中一样。你可以看到我在这里使用了 apt 分类器作为注释处理器。您的用户需要将 apt 插件也应用于项目才能使其工作。但是，我留给您的练习是，您还可以检测 apt 插件是否已经应用于项目，以及是否没有自动应用它！您的 Gradle 插件可以为您的用户处理的另一件事。

现在让我们开始实际操作您希望 Gradle 插件执行的操作。在最基本的层面上，您需要做一些事情来响应您的注释处理器已经完成了单元测试的创建。

所以我们需要做的第一件事就是弄清楚我们正在使用什么样的项目。它是一个android库项目还是一个android应用程序项目？这对于一种复杂的原因很重要，我不会在这个答案中解释这个原因，因为它会使这个已经很长的答案变得更长。我只是要向您展示代码并解释它的基本作用：

@Override
void apply(Project project) {
    project.afterEvaluate {
        project.afterEvaluate {

            project.dependencies {
                compile 'com.github.wrdlbrnft:proguard-annotations-api:0.2.0.44'
                apt 'com.github.wrdlbrnft:proguard-annotations-processor:0.2.0.44'
            }

            def variants = determineVariants(project)

            project.android[variants].all { variant ->
                configureVariant(project, variant)
            }
        }
    }
}

private static String determineVariants(Project project) {
    if (project.plugins.findPlugin('com.android.application')) {
        return 'applicationVariants';
    } else if (project.plugins.findPlugin('com.android.library')) {
        return 'libraryVariants';
    } else {
        throw new ProjectConfigurationException('The com.android.application or com.android.library plugin must be applied to the project', null)
    }
}

Run Code Online (Sandbox Code Playgroud)

它的作用是检查com.android.library插件或com.android.application插件是否已被应用，然后在这种情况下遍历项目的所有变体。这意味着基本上你在 build.gradle 中指定的所有项目风格和构建类型都是独立配置的——因为它们本质上也是不同的构建过程，需要自己的配置。在def类似于var在C＃关键字，并且可以使用，而没有显式指定的类型声明变量。

project.android[variants].all { variant ->
    configureVariant(project, variant)
}

Run Code Online (Sandbox Code Playgroud)

这部分是一个循环，它遍历所有不同的变体，然后调用 configureVariant 方法。在这种方法中，所有的魔法都发生了，这对您的项目来说是真正重要的部分。我们来看看基本的实现：

private static void configureVariant(Project project, def variant) {
    def javaCompile = variant.hasProperty('javaCompiler') ? variant.javaCompiler : variant.javaCompile
    javaCompile.doLast {

    }
}

Run Code Online (Sandbox Code Playgroud)

现在该方法的第一行是一个有用的片段，它基本上做了一件事：它返回 java 编译任务。我们需要这个，因为注解处理是 java 编译过程的一部分，一旦编译任务完成，你的注解处理器也完成了。该javaCompile.doLast {}部分类似于afterEvaluate. 它允许我们在任务结束时添加自己的代码！所以在java编译任务之后，因此注释处理完成后括号内的部分doLast被执行了！在那里，您现在终于可以为您的项目做您需要做的事情了。由于我不完全知道你需要做什么或你需要如何做，我只是给你举个例子：

private static void configureVariant(Project project, def variant) {
    def javaCompile = variant.hasProperty('javaCompiler') ? variant.javaCompiler : variant.javaCompile
    javaCompile.doLast {
        def generatedSourcesFolder = new File(project.buildDir, 'generated/apt')
        def targetDirectory = new File(project.buildDir, 'some/other/folder');
        if(generatedSourcesFolder.renameTo(targetDirectory)) {
            // Success!!1 Files moved.
        }
    }
}

Run Code Online (Sandbox Code Playgroud)

就是这样！虽然这是一个很长的答案，但它只触及了整个主题的表面，所以如果我忘记了一些重要的事情或者您有任何进一步的问题，请随时提出。

然而，还有一些最后的事情：

如果您需要将生成的文件移动到不同的文件夹，您需要注意 apt 文件夹中可能有许多来自其他库的其他生成文件，通常将它们移开并不是一件好事。所以你需要找出一个系统来过滤文件夹中的文件 - 例如一些常见的前缀或后缀。这应该不是问题。

我需要提及的另一件事是：一旦掌握javaCompile了configureVariants()方法中的任务，您就可以实际为注释处理器指定命令行参数，如提到的@emory。然而，这可能非常棘手。事实上，这正是android-apt插件所做的。它build/generated/apt通过在javaCompile任务上指定文件夹来指定文件夹作为所有注释处理器的输出文件夹。同样，您不想惹恼它。我不知道有什么方法可以为一个注释处理器（即您的）指定输出文件夹，但可能有一种方法。如果你有时间，你可能想研究一下。你可以看看android-apt 这里的相关源代码。处理器输出路径的指定发生在configureVariants方法的下方。

在 build.gradle 中设置 Gradle 插件项目与任何其他 Gradle 项目非常相似，实际上非常简单。但是作为参考，这里是我用于编写的 Gradle 插件的完整 build.gradle。如果您需要帮助弄清楚如何将您的插件发布到 jcenter 或 Gradle Plugin Pepository 或任何一般配置，您可能会从查看中受益：

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        jcenter()
    }
    dependencies {
        classpath "com.gradle.publish:plugin-publish-plugin:0.9.4"
        classpath 'com.novoda:bintray-release:0.3.4'
    }
}

apply plugin: "com.gradle.plugin-publish"
apply plugin: 'com.jfrog.bintray'
apply plugin: 'maven-publish'
apply plugin: 'maven'
apply plugin: 'groovy'

dependencies {
    compile gradleApi()
    compile localGroovy()
}

final bintrayUser = hasProperty('bintray_user') ? property('bintray_user') : ''
final bintrayApiKey = hasProperty('bintray_api_key') ? property('bintray_api_key') : ''
final versionName = hasProperty('version_name') ? property('version_name') : ''

version = versionName

pluginBundle {
    vcsUrl = 'https://github.com/Wrdlbrnft/ProguardAnnotations'
    website = 'https://github.com/Wrdlbrnft/ProguardAnnotations'
    description = 'Makes dealing with Proguard simple and easy!'
    plugins {

        ProguardAnnotationsPlugin {
            id = 'com.github.wrdlbrnft.proguard-annotations'
            displayName = 'ProguardAnnotations'
            tags = ['android', 'proguard', 'plugin']
        }
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

publishing {
    publications {
        Bintray(MavenPublication) {
            from components.java
            groupId 'com.github.wrdlbrnft'
            artifactId 'proguard-annotations'
            artifact sourcesJar
            version versionName
        }
    }
}

bintray {
    user = bintrayUser
    key = bintrayApiKey
    publications = ['Bintray']
    pkg {
        repo = 'maven'
        name = 'ProguardAnnotationsPlugin'
        userOrg = bintrayUser
        licenses = ['Apache-2.0']
        vcsUrl = 'https://github.com/Wrdlbrnft/ProguardAnnotations'
        publicDownloadNumbers = true
        version {
            name = versionName
            released = new Date()
        }
    }
}

Run Code Online (Sandbox Code Playgroud)

如果您对 build.gradle 文件中没有定义的所有三个或四个变量感到困惑 - 当我运行构建时，它们是由我的构建服务器注入的。它们在开发时会自动回退到某些默认值。

我希望我能帮助你让你的图书馆变得很棒:)

归档时间：	9 年，8 月前
查看次数：	1173 次
最近记录：	9 年，7 月前