Fortran reshape - N 维转置

Question

我正在尝试在 Fortran 中编写一些代码，这需要重新排序 n 维数组。我认为重塑内在与order参数应该允许这样做，但是我遇到了困难。

考虑以下最小示例

program test
    implicit none
    real, dimension(:,:,:,:,:), allocatable :: matA, matB
    integer, parameter :: n1=3, n2=5, n3=7, n4=11, n5=13
    integer :: i1, i2, i3, i4, i5

    allocate(matA(n1,n2,n3,n4,n5)) !Source array
    allocate(matB(n3,n2,n4,n1,n5)) !Reshaped array

    !Populate matA
    do i5=1, n5
       do i4=1, n4
          do i3=1, n3
             do i2=1, n2
                do i1=1, n1
                   matA(i1,i2,i3,i4,i5) = i1+i2*10+i3*100+i4*10000+i5*1000000
                enddo
             enddo
          enddo
       enddo
    enddo

    print*,"Ad1 : ",matA(:,1,1,1,1),shape(matA)
    matB = reshape(matA, shape(matB), order = [3,2,4,1,5])
    print*,"Bd4 : ",matB(1,1,1,:,1),shape(matB) !Leading dimension of A is the fourth dimension of B
end program test

我希望这会导致

Ad1 : 1010111.00       1010112.00       1010113.00               3           5           7          11          13

Bd4 : 1010111.00       1010112.00       1010113.00               7           5          11           3          13

但相反，我发现：

Ad1 : 1010111.00       1010112.00       1010113.00               3           5           7          11          13

Bd4 : 1010111.00       1010442.00       1020123.00               7           5          11           3          13

我已经用gfortran(4.8.3 和 4.9) 和ifort(11.0)尝试过这个并找到了相同的结果，所以很可能我只是误解了关于重塑如何工作的一些东西。

任何人都可以阐明我哪里出错了以及我如何实现我的目标？

Answer 1

因为我也觉得多维数组的行为order非常不直观，所以我在下面做了一些代码比较，以使情况更加清晰（除了已经完整的@francescalus'答案）。首先，在一个简单的情况下，reshape()with 和 withoutorder给出以下内容：

mat = reshape( [1,2,3,4,5,6,7,8], [2,4] )

=> [ 1  3  5  7  ;
     2  4  6  8  ]

mat = reshape( [1,2,3,4,5,6,7,8], [2,4], order=[2,1] )

=> [ 1  2  3  4  ;
     5  6  7  8  ]

此示例显示，如果没有，order元素将以通常的列优先方式填充，而如果使用order=[2,1]第二维，则运行速度更快，因此元素会按行填充。这里的关键点是order指定 LHS（而不是源数组）的哪个维度运行得更快（如上面答案中所强调的）。

现在我们将相同的机制应用于更高维度的情况。首先，reshape()5维数组没有order

matB = reshape( matA, [n3,n2,n4,n1,n5] )

对应于显式循环

k = 0
do i5 = 1, n5   !! (5)-th dimension of LHS
do i1 = 1, n1   !! (4)
do i4 = 1, n4   !! (3)
do i2 = 1, n2   !! (2)
do i3 = 1, n3   !! (1)-st dimension of LHS
    k = k + 1
    matB( i3, i2, i4, i1, i5 ) = matA_seq( k )
enddo;enddo;enddo;enddo;enddo

其中matA_seq是 的顺序视图matA

real, pointer :: matA_seq(:)
matA_seq( 1 : n1*n2*n3*n4*n5 ) => matA(:,:,:,:,:)

现在附加order=[3,2,4,1,5]到reshape()，

matB = reshape( matA, [n3,n2,n4,n1,n5], order = [3,2,4,1,5] )

然后改变 DO 循环的顺序，使得

k = 0
do i5 = 1, n5   !! (5)-th dim of LHS
do i3 = 1, n3   !! (1)
do i1 = 1, n1   !! (4)
do i2 = 1, n2   !! (2)
do i4 = 1, n4   !! (3)-rd dim of LHS
    k = k + 1
    matB( i3, i2, i4, i1, i5 ) = matA_seq( k )
enddo;enddo;enddo;enddo;enddo

这意味着matB(因此i4) 的第三个维度运行最快（对应于上面答案中的第二行）。但OP想要的是

k = 0
do i5 = 1, n5   !! (5)-th dim of LHS
do i4 = 1, n4   !! (3)
do i3 = 1, n3   !! (1)
do i2 = 1, n2   !! (2)
do i1 = 1, n1   !! (4)-th dim of LHS
    k = k + 1
    matB( i3, i2, i4, i1, i5 ) = matA_seq( k )
enddo;enddo;enddo;enddo;enddo

这对应于

matB = reshape( matA, [n3,n2,n4,n1,n5], order = [4,2,1,3,5] )

即，francescalus 答案的最后一行。

希望这次比较能进一步澄清情况......

Answer 2

当order=被指定时reshape，以置换下标顺序获取的结果的元素对应于源数组的元素。这可能还不完全清楚。Fortran 2008 标准将其表述为（忽略有关 的部分pad=）

结果的元素采用排列下标顺序 ORDER (1), ..., ORDER (n)，是 SOURCE 的正常数组元素顺序 ..

这意味着从您的示例中order=[3,2,4,1,5]可以映射到

matA(1,1,1,1,1), matA(2,1,1,1,1), matA(3,1,1,1,1), matA(1,2,1,1,1), ...

的

matB(1,1,1,1,1), matB(1,1,2,1,1), matB(1,1,3,1,1), matB(1,1,4,1,1), ...

偏移量在 的第三个索引中变化最快，matB对应于 的第一个索引中变化最快matA。下一个变化最快的matB是 2 维，然后是 4 维，依此类推。

matB(1,1,1:3,1,1)所以，它是对应于 的元素matA(:,1,1,1,1)。

我已经明确说明了该切片的范围，matB因为您对 的形状有疑问matB：您希望 的形状matB是说明order=符给出的排列的逆。

你可以把你的例子写成

  implicit none
  integer, parameter :: n1=3, n2=5, n3=7, n4=11, n5=13
  integer matA(n1,n2,n3,n4,n5)
  integer matB(n4,n2,n1,n3,n5)  ! Inverse of permutation (3 2 4 1 5)
  integer i1, i2, i3, i4, i5

  forall (i1=1:n1, i2=1:n2, i3=1:n3, i4=1:n4, i5=1:n5) &
          matA(i1,i2,i3,i4,i5)=i1+i2*10+i3*100+i4*10000+i5*1000000

  print*,"Ad1 : ",matA(:,1,1,1,1),shape(matA)
  matB = reshape(matA, shape(matB), order = [3,2,4,1,5])
  print*,"Bd3 : ",matB(1,1,:,1,1),shape(matB)

end

或者，如果它是您想要的形状matB，那么它就是需要反转的顺序排列：

  matB = reshape(matA, shape(matB), order = [4,2,1,3,5])

乍一看，可能很自然地会看到与源尺寸相关的顺序。然而，以下内容可能会澄清：无论源的形状如何，重塑的结果都是相同的（使用的是按自然顺序排列的数组元素）；该order=值的大小等于该shape=值的大小。对于第一个，如果源是[1,2,3,4,5,6]（回想一下我们如何构造 2 级数组），那么如果在源上使用它，则order=永远不会产生任何效果（它必须是）。[1]