360观察者统一,纹理在顶部和底部出现翘曲

Question

我正在制作一个360度的统一观察者,观看一张360度的照片,我曾经将一个立方体贴图连接到天空盒,而且效果很好.但是立方体贴图的重量迫使我切换到纹理.

所有360观察器教程都说要在其上放置一个带着色器的球体,然后将相机放入其中.当我这样做时,它不能很好地工作,因为当我看到顶部或底部时,我看到图像像这样弯曲:(椅子被假定看起来正常)

当我使用天空盒时,它没有发生.

有人知道为什么会这样吗？

非常感谢你!

Answer 1

您选择的着色器不能很好地处理矩形失真.在球体的两极(顶部和底部),很多图像信息必须映射到非常小的空间,这会导致您看到的伪像.

您可以编写专门的着色​​器来改进从您的equirectangular图像到球体的坐标映射.在Unity论坛上发布了一个专门的着色​​器.

Shader "Custom/Equirectangular" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,1)
        _MainTex ("Diffuse (RGB) Alpha (A)", 2D) = "gray" {}
    }

    SubShader{
        Pass {
            Tags {"LightMode" = "Always"}

            CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag
                #pragma fragmentoption ARB_precision_hint_fastest
                #pragma glsl
                #pragma target 3.0

                #include "UnityCG.cginc"

                struct appdata {
                   float4 vertex : POSITION;
                   float3 normal : NORMAL;
                };

                struct v2f
                {
                    float4    pos : SV_POSITION;
                    float3    normal : TEXCOORD0;
                };

                v2f vert (appdata v)
                {
                    v2f o;
                    o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                    o.normal = v.normal;
                    return o;
                }

                sampler2D _MainTex;

                #define PI 3.141592653589793

                inline float2 RadialCoords(float3 a_coords)
                {
                    float3 a_coords_n = normalize(a_coords);
                    float lon = atan2(a_coords_n.z, a_coords_n.x);
                    float lat = acos(a_coords_n.y);
                    float2 sphereCoords = float2(lon, lat) * (1.0 / PI);
                    return float2(sphereCoords.x * 0.5 + 0.5, 1 - sphereCoords.y);
                }

                float4 frag(v2f IN) : COLOR
                {
                    float2 equiUV = RadialCoords(IN.normal);
                    return tex2D(_MainTex, equiUV);
                }
            ENDCG
        }
    }
    FallBack "VertexLit"
}

同样,它不是我自己的代码,但我在Android设备上测试它,并作为一个独立的PC版本.它产生非常光滑的极点.

请注意:此着色器不会翻转球体的法线.所以,如果你想你的相机坐在里面的球你有一个3D程序或着色器反转其法线.尝试Cull Front在上面的第9行之后添加,着色器将其纹理应用到模型的"错误"侧.