如何列出jenkins管道作业中的所有`env`属性？

Question

鉴于jenkins 2.1构建管道,jenkins将一个env变量注入到node{}.例如,BRANCH_NAME可以使用

node {
    echo ${env.BRANCH_NAME}
    ...

我想回显jenkins管道中的所有 env属性.

我正在寻找像这样的代码

node {
    for(e in env){
        echo e + " is " + ${e}
    }
    ...

这会像回应一样

 BRANCH_NAME is myBranch2
 CHANGE_ID is 44
 ...

Answer 1

另一种更简洁的方式:

node {
    echo sh(returnStdout: true, script: 'env')
    // ...
}

比照 https://jenkins.io/doc/pipeline/steps/workflow-durable-task-step/#code-sh-code-shell-script

Answer 2

根据Jenkins的声明性管道文档:

sh 'printenv'

对于Jenkins 脚本管道:

echo sh(script: 'env|sort', returnStdout: true)

为方便起见,上面还对您的env vars进行了排序.

Answer 3

以下作品:

@NonCPS
def printParams() {
  env.getEnvironment().each { name, value -> println "Name: $name -> Value $value" }
}
printParams()

请注意,它很可能在第一次执行时失败,并且需要您批准各种groovy方法才能在jenkins沙箱中运行.这是在"管理jenkins /进程内脚本批准"中完成的

我得到的清单包括:

• BUILD_DISPLAY_NAME
• BUILD_ID
• BUILD_NUMBER
• BUILD_TAG
• BUILD_URL
• CLASSPATH
• HUDSON_HOME
• HUDSON_SERVER_COOKIE
• HUDSON_URL
• JENKINS_HOME
• JENKINS_SERVER_COOKIE
• JENKINS_URL
• JOB_BASE_NAME
• JOB_NAME
• JOB_URL

Answer 4

您可以使用sh/ bat步骤完成结果readFile:

node {
    sh 'env > env.txt'
    readFile('env.txt').split("\r?\n").each {
        println it
    }
}

不幸的是,env.getEnvironment()返回非常有限的环境变量图.

Answer 5

为什么这么复杂？

sh 'env'

做你需要的（在* nix下）

Answer 6

这是一个快速脚本,您可以添加为管道作业以列出所有环境变量:

node {
    echo(env.getEnvironment().collect({environmentVariable ->  "${environmentVariable.key} = ${environmentVariable.value}"}).join("\n"))
    echo(System.getenv().collect({environmentVariable ->  "${environmentVariable.key} = ${environmentVariable.value}"}).join("\n"))
}

这将列出系统和Jenkins变量.

Answer 7

读取全局变量的纯 Groovy解决方案env不会打印所有环境变量（例如，它们缺少environment块中的变量、withEnv上下文中的变量以及操作系统中大多数特定于机器的变量）。使用 shell 步骤可以获得更完整的集合，但这需要node上下文，这并不总是需要的。

这是一个解决方案，它使用该getContext步骤来检索和打印当前上下文的完整环境变量集，包括管道参数。

警告：在 Groovy 沙箱中不起作用。不过，您可以从受信任的共享库中使用它。

def envAll = getContext( hudson.EnvVars )
echo envAll.collect{ k, v -> "$k = $v" }.join('\n')

Answer 8

我使用Blue Ocean插件并不喜欢每个环境条目都有自己的块.我想要一个包含所有线条的块.

打印效果不佳:

sh 'echo `env`'

打印效果不佳:

sh 'env > env.txt'
for (String i : readFile('env.txt').split("\r?\n")) {
    println i
}

打印好:

sh 'env > env.txt'
sh 'cat env.txt'

打印得很好:(如@mjfroehlich所述)

echo sh(script: 'env', returnStdout: true)

Answer 9

显示所有变量在Windows系统和Unix系统中是不同的，你可以定义一个函数来每次调用它。

def showSystemVariables(){    
   if(isUnix()){
     sh 'env'
   } else {
     bat 'set'
   }
}

我将首先调用此函数来显示所有 pipline 脚本中的所有变量

stage('1. Show all variables'){
     steps {
         script{            
              showSystemVariables()
         }
     }
} 

Answer 10

最简单快捷的方法是使用以下 url 打印所有环境变量

http://localhost:8080/env-vars.html/

Answer 11

列出所有环境变量的跨平台方式：

if (isUnix()) {
    sh env
}
else {
    bat set
}