Base64编码"字符串" - 命令行Windows？

Question

我已经找到了很多方法在Windows上使用命令行对整个文件进行base64编码,但我似乎找不到使用命令行实用程序批量编码"字符串"的简单方法.

例如,如何在批处理文件中使用它？

Answer 1

这是一个PowerShell单行程序,您可以从cmd控制台运行,它将对Base64进行编码.

powershell "[convert]::ToBase64String([Text.Encoding]::UTF8.GetBytes(\"Hello world!\"))"

它可能没有npocmaka解决方案那么快,但你可以用它设置一个控制台宏.

doskey btoa=powershell "[convert]::ToBase64String([Text.Encoding]::UTF8.GetBytes(\"$*\"))"
doskey atob=powershell "[Text.Encoding]::UTF8.GetString([convert]::FromBase64String(\"$*\"))"

btoa Hello world!
btoa This is fun.
btoa wheeeeee!
atob SGVsbG8gd29ybGQh

请注意,doskey在批处理脚本中不起作用 - 仅限控制台.如果要在批处理脚本中使用它,请创建一个函数.

@echo off
setlocal

call :btoa b64[0] "Hello world!"
call :btoa b64[1] "This is fun."
call :btoa b64[2] "wheeeeee!"
call :atob b64[3] SGVsbG8gd29ybGQh

set b64
goto :EOF

:btoa <var_to_set> <str>
for /f "delims=" %%I in (
    'powershell "[convert]::ToBase64String([Text.Encoding]::UTF8.GetBytes(\"%~2\"))"'
) do set "%~1=%%I"
goto :EOF

:atob <var_to_set> <str>
for /f "delims=" %%I in (
    'powershell "[Text.Encoding]::UTF8.GetString([convert]::FromBase64String(\"%~2\"))"'
) do set "%~1=%%I"
goto :EOF

或者,如果您更喜欢批处理+ JScript混合:

@if (@CodeSection==@Batch) @then
@echo off & setlocal

call :btoa b64[0] "Hello world!"
call :btoa b64[1] "This is fun."
call :btoa b64[2] "wheeeeee!"
call :atob b64[3] SGVsbG8gd29ybGQh

set b64
goto :EOF

:btoa <var_to_set> <str>
:atob <var_to_set> <str>
for /f "delims=" %%I in ('cscript /nologo /e:JScript "%~f0" %0 "%~2"') do set "%~1=%%I"
goto :EOF

@end // end batch / begin JScript hybrid code
var htmlfile = WSH.CreateObject('htmlfile');
htmlfile.write('<meta http-equiv="x-ua-compatible" content="IE=10" />');
WSH.Echo(htmlfile.parentWindow[WSH.Arguments(0).substr(1)](WSH.Arguments(1)));

编辑:@Hackoo的批处理+ VBScript混合:

<!-- : batch portion
@echo off & setlocal

call :btoa b64[0] "Hello world!"
call :btoa b64[1] "This is fun."
call :btoa b64[2] "wheeeeee!"
call :atob b64[3] SGVsbG8gd29ybGQh

set b64
goto :EOF

:btoa <var_to_set> <str>
:atob <var_to_set> <str>
for /f "delims=" %%I in ('cscript /nologo "%~f0?.wsf" %0 "%~2"') do set "%~1=%%I"
goto :EOF

: VBScript -->
<job>
    <script language="VBScript">
        Set htmlfile = WSH.CreateObject("htmlfile")
        htmlfile.write("<meta http-equiv='x-ua-compatible' content='IE=10' />")
        if WSH.Arguments(0) = ":btoa" then
            WScript.Echo htmlfile.parentWindow.btoa(WSH.Arguments(1))
        else
            WScript.Echo htmlfile.parentWindow.atob(WSH.Arguments(1))
        end if
    </script>
</job>

Answer 2

根据对该问题的评论,您可以使用certutil.例如,

certutil -encode raw.txt encoded.txt

要么

certutil -f -encode raw.txt encoded.txt

的-f意思是"力量覆盖".否则,如果输出文件(上面的encoded.txt)已经存在,您将收到错误.

但是,这会将输出格式化为encoded.txt文件,就像它是证书PEM文件一样,包含BEGIN和END行,以及最大字符处的分割线.因此,您需要在批处理场景中进行进一步处理,如果字符串很长则需要一些额外的工作.

Answer 3

这个脚本可以解码/编码来自XP及以上的每台机器上的base64字符串,而无需安装.net或Internet Explorer 10/11.它甚至可以处理特殊的javascript转义符号:

// result is IkhlbGxvIg==
base64.bat -encode "\u0022Hello\u0022" -eval yes

// result is SGVsbG8=
base64.bat -encode "Hello"

这个接受一个参数 - 你要编码为base 64的字符串并打印结果(但至少需要安装Internet Explorer 10):

@echo off

setlocal

set "string=%~1"

::echo %string%^|mshta.exe "%~f0"
for /f "delims=" %%# in ('echo %string%^|mshta.exe "%~f0"') do (
    set b64=%%#
)

set b64

endlocal&exit /b %errorlevel%

<HTA:Application
   ShowInTaskbar = no
   WindowsState=Minimize
   SysMenu=No
   ShowInTaskbar=No
   Caption=No
   Border=Thin
>
<meta http-equiv="x-ua-compatible" content="ie=10" />
<script language="javascript" type="text/javascript">
    window.visible=false;
    window.resizeTo(1,1);

   var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);
   var fso2= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(0);
   var string=fso2.ReadLine();

    var encodedString = btoa(string);

   fso.Write(encodedString);
   window.close();
</script>

Answer 4

如果您安装了 Windows 版 OpenSSL，您可以使用它来编码字符串“Hello”：

echo | set /p="Hello" | openssl base64

这| set /p=是为了抑制 echo 通常输出的换行符。

这将在 bash 中产生与以下相同的结果：

echo -n 'Hello' | openssl base64

输出：

SGVsbG8=