模拟器使用 int21h/ah=09h 显示“在 2000 个字节之后找不到错误字节 24h”

Question

我必须使用EMU8086在汇编中做一个简单的计算器，但每次我尝试启动它时，EMU8086都会出现此错误：

INT 21h, AH=09h - 
address: 170B5
byte 24h not found after 2000 bytes.
; correct example of INT 21h/9h:
mov dx, offset msg
mov ah, 9
int 21h
ret
msg db "Hello$"

我检查了其他东西，但没有错误：

data segment
    choice db ?
    snum1 db 4 dup(?)
    snum2 db 4 dup(?)
    sres db 4 dup(?)
    num1 db ?
    num2 db ?
    res db ?
    ;;menu1 db "Chose a function to procced", 10, 13, "Add [+]", 10, 13, "Sub [-]", 10, 13
    ;;menu2 db "Mul [*]", 10, 13, "Div [/]", 10, 13, "Mod [%]", 10, 13, "Pow [^]", 10, 13, "Exit [x]$"
    messStr db "Enter Your Choice:",10,13,"",10,13,"Add --> +",10,13,"Sub --> -",10,13,"Mul --> *",10,13,"Div --> /",10,13,"Mod --> %",10,13,"Pow --> ^",10,13,"Exit --> X",10,13,"$"
    msg1 db "Enter first number$"
    msg2 db "Enter second number$"
    msg3 db "Press any key to procced$"
    msg4 db "The result is $"

ends

stack segment
    dw   128  dup(0)
ends

code segment
assume cs:code, ds:data, ss:stack 

newline proc ;; new line
    push ax
    push dx
    mov ah, 2
    mov DL, 10
    int 21h
    mov ah, 2
    mov DL, 13
    int 21h
    pop dx
    pop ax
    ret
endp

printstr proc ;; print string
    push BP
    mov BP, SP
    push dx
    push ax
    mov dx, [BP+4]
    mov ah, 9
    int 21h
    pop ax
    pop dx
    pop BP
    ret 2
endp

inputstr proc ;; collect input
    push BP
    mov BP, SP
    push bx
    push ax
    mov bx, [BP+4]
k1: 
    mov ah, 1
    int 21h
    cmp al, 13
    je sofk
    mov [bx], al
    inc bx
    jmp k1
sofk:
    mov byte ptr [bx], '$'
    pop ax
    pop bx
    pop BP
    ret 2
endp

getNums proc ;; get the numbers
    call newline
    push offset msg1
    call printstr
    call newline    
    push offset snum1
    call inputstr 

    call newline
    push offset msg2
    call printstr
    call newline
    push offset snum2
    call inputstr
    ret
endp

start:
    mov ax, data
    mov ds, ax
    mov ax, stack
    mov ss, ax

    ;; print the main menu
    call newline
    push offset msg4
    call printstr 
    ;; collect the input
    call newline
    mov bx, offset choice
    mov ah, 1
    int 21h
    mov [bx], al
    ;; check it
    mov al, choice
    cmp al, '+'
    jne cexit
    call getNums

    jmp cont
cexit:    
    cmp al, 'x'
    je cend

cont:
   ;; pause before going to the main menu
   call newline
   push offset msg3
   call printstr

   mov bx, offset choice
   mov ah, 1
   int 21h 

   call newline
   call newline
   call newline

   jmp start

cend:   

mov ax, 4c00h
int 21h  

ends

end start

我删掉了大部分代码段，因为这里并不重要。

在对代码进行试验后，我发现问题与数据段中消息的长度有关。menu1&menu2太长了，它们之后的任何消息都无法打印（msg1&msg2被打印，但之后什么都没有）。我检查了是否应该合并menu1& menu2，但它没有帮助。请帮我找出它有什么问题。

Answer 1

错误消息意味着您在不以(ASCII 24h)结尾的字符串上使用int 21h/ 。系统调用处理程序检查了 2000 个字节，但没有找到。AH=09h$

通常，这意味着您的代码或数据有问题，例如，在固定字符串中，您最后忘记了 a $，或者如果将字节复制到缓冲区中，那么您可能会覆盖或从未存储 a '$'。

但在这种情况下，似乎 EMU8086 有一个错误组装push offset msg4。（以某种方式将00B5h16 位地址截断为 8 位，然后符号扩展回 16，从而创建一个错误的指针，指向$数据中任何字符所在的位置。）

根据下面的错误消息，我知道您正在使用EMU8086作为您的开发环境。

INT 21h, AH=09h - 地址：170B5 字节 2000 字节后未找到 24h。; INT 21h/9h 的正确示例：mov dx, offset msg mov ah, 9 int 21h ret msg db "Hello$"

无论如何，我都不是EMU8086的专家。我知道为什么你的偏移不起作用。我无法告诉您是否有解决此问题的正确方法，或者它是否是EMU8086错误。对这个模拟器有更好背景的人会知道。

您已经创建了一个data包含一些变量的段。对我来说似乎没问题（但我可能会遗漏一些东西）。我决定加载EMU8086来实际尝试这段代码。它组装没有错误。使用调试器，我单步到push offset msg1程序开头附近的那一行。我立即从指令编码中知道发生了什么。这是我看到的解码指令：

它显示指令被编码为push 0b5h其中 0b5h 是偏移量。问题是它被编码为push imm8. 左侧窗格中突出显示的两个字节显示它是用这些字节编码的：

6A B5 

如果您查看指令集参考，您会发现PUSH指令编码的编码6A如下：

Opcode*   Instruction Op/En   64-Bit Mode Compat/Leg Mode Description
6A ib     PUSH imm8   I       Valid       Valid           Push imm8.

您可能会说B5适合一个字节 (imm8) 那么有什么问题呢？push在 16 位模式下可以压入堆栈的最小值是 16 位字。由于一个字节比一个字小，处理器取该字节并对其进行符号扩展以生成一个 16 位值。指令集参考实际上是这样说的：

如果源操作数是大小小于操作数大小的立即数，则将符号扩展值压入堆栈

B5是二进制 10110101 。符号位是最左边的位。因为它是 1，所以放在堆栈上的高 8 位将是 11111111b (FF)。如果符号位为 0，则 00000000b 被放置在高 8 位中。模拟器没有放置00B5到堆栈中，而是放置了FFB5. 那是不正确的！如果我逐步执行push 0b5h指令并查看堆栈，则可以确认这一点。这是我看到的：

观察到放置在堆栈上的值是FFB5。我找不到合适的语法（甚至使用word修饰符）来强制 EMU8086 将其编码为push imm16. Apush imm16将能够对整个单词进行编码，push 00b5这将起作用。

你可以做两件事。您可以在data段中放置 256 字节的虚拟数据，如下所示：

data segment
db 256 dup(?)
choice db ?
... rest of data

为什么这样做？在虚拟数据之后定义的每个变量都将是一个无法用单个字节表示的偏移量。因此，EMU8086 被迫编码push offset msg1为字推送。

更清洁的解决方案是使用LEA指令。这是load effective address指令。它需要一个内存操作数并计算地址（在这种情况下是相对于数据段的偏移量）。您可以使用以下内容替换所有使用的代码offset：

lea ax, [msg1]
push ax

AX可以是任何通用 16 位寄存器。进入寄存器后，将 16 位寄存器压入堆栈。

有人可能对此有更好的解决方案，或者知道解决此问题的方法。如果是这样，请随时发表评论。

鉴于以上信息，您可能会问为什么在移动数据时它似乎起作用了？原因是您重新组织所有字符串的方式（将长字符串放在最后）导致所有变量以小于 < 128 的偏移量开始。因此，8 位立即偏移符号的PUSH扩展了一个 0 in放在堆栈上时的最高位。偏移量是正确的。一旦偏移量 >= 128（并且 < 256），符号位为 1，并且放置在堆栈符号上的值的高 8 位将为 1 而不是 0。

您的程序中还有其他错误，我专注于与您收到的错误直接相关的问题。