gnuplot：在多图模式下绘制单个调色板

Question

我想就以下主题寻求一些帮助：

以下代码在同一页上生成 3 个图（3 行，1 列）：

set terminal postscript color
set output "test.ps"
file="test.dat"

set palette rgb 33,13,10  
set cblabel "[km]"
set cbtics 2.5, 5, 20 format "%.0f"

set lmargin at screen 0.08
set rmargin at screen 0.88
# BUILD FROM BOTTOM TO TOP #
TOP=0.92  #
DY = 0.27 # DIMENSION OF Y

set multiplot
set grid
set offset 0, 0, graph 0.05, graph 0.05 

#unset colorbox
# BOTTOM GRAPH #
set xlabel "Second of the Week [s]"
set ylabel "Up [m]" offset 1.5
set ytics -0.7, 0.2, 0.4
set yrange[-0.75:0.35]
set tmargin at screen TOP-2*DY
set bmargin at screen TOP-3*DY
plot file u 1:12:3 notitle palette 
# MIDDLE GRAPH #
set xtics format ''
unset xlabel 
set ytics -0.3, 0.2, 0.8
set yrange[-0.35:0.75]
set ylabel "North [m]"
set tmargin at screen TOP-DY
set bmargin at screen TOP-2*DY
plot file u 1:11:3 notitle palette
# TOP GRAPH #
set title "test"
set ylabel "East [m]"
set ytics -0.7, 0.2, 0.4
set yrange[-0.9:0.25]
set tmargin at screen TOP
set bmargin at screen TOP-DY
plot file u 1:10:3 notitle palette

unset multiplot

上面的代码产生以下图：

在图中，数据根据距原点的距离显示。距离采用颜色编码，所使用的调色板绘制在每个图表的右侧。

我的问题是： - 如何获得相同的图表，但在 3 个图的右侧有一个垂直调色板？我希望从第一个图表的顶部（东）到第三个图表的底部（上）显示一个调色板。这也将使我能够扩大调色板，并产生更清晰的绘图。

任何帮助是极大的赞赏。

Answer 1

对于第一次使用

set colorbox user origin screen 0, screen 0.05 size screen XX, screen YY

您需要设置 XX 和 YY 以适合三个图所需的颜色框宽度和高度。

然后对于第二个图，只需设置

unset colorbox