从哈希值生成组合

Question

在perl如果我有一个哈希

my %ranges = (                                                                                      
'--tic' => [ 0, 1, 2 ],                                                                             
'--threads' => [ 8, 16 ],                                                                           
'--level' => [ 10, 20 ]                                                                               
);                                                                     

如何生成所有组合的数组,例如

--level 10 --threads 8 --tic 0                                                                        
--level 10 --threads 8 --tic 1                                                                        
--level 10 --threads 8 --tic 2                                                                        
--level 10 --threads 16 --tic 0                                                                       
--level 10 --threads 16 --tic 1                                                                       
--level 10 --threads 16 --tic 2                                                                       
--level 20 --threads 8 --tic 0                                                                        
--level 20 --threads 8 --tic 1                                                                        
--level 20 --threads 8 --tic 2                                                                        
--level 20 --threads 16 --tic 0                                                                       
--level 20 --threads 16 --tic 1                                                                       
--level 20 --threads 16 --tic 2       

可以有任意数量的哈希条目,每个条目的值数组中可以包含任意数量的元素.输出数组的顺序无关紧要,每个组合只需要1个元素,在这种情况下3*2*2 = 12,但可以是任意数字.

我认为拼接,地图和foreach的某些组合应该可以工作,但我正在以一种糟糕的方式找到它.

Answer 1

如前所述,您正在寻找笛卡尔积,

use strict;
use warnings;

sub getCartesian {
#
  my @input = @_;
  my @ret = map [$_], @{ shift @input };

  for my $a2 (@input) {
    @ret = map {
      my $v = $_;
      map [@$v, $_], @$a2;
    }
    @ret;
  }
  return @ret;
}

my %ranges = (
    '--tic' => [ 0, 1, 2 ],
    '--threads' => [ 8, 16 ],
    '--level' => [ 10, 20 ]
);

my @arr =  map {
  my $k = $_;
  [ map "$k $_", @{$ranges{$k}} ];
}
keys %ranges;

print "@$_\n" for getCartesian(@arr);

产量

--level 10 --tic 0 --threads 8
--level 10 --tic 0 --threads 16
--level 10 --tic 1 --threads 8
--level 10 --tic 1 --threads 16
--level 10 --tic 2 --threads 8
--level 10 --tic 2 --threads 16
--level 20 --tic 0 --threads 8
--level 20 --tic 0 --threads 16
--level 20 --tic 1 --threads 8
--level 20 --tic 1 --threads 16
--level 20 --tic 2 --threads 8
--level 20 --tic 2 --threads 16