批处理中解析简单的JSON字符串

Question

如何在Batch中解析一个简单的JSON字符串？

例如,如果我有以下JSON字符串:

{"...":"...","年":2016年,"时间":"05:01","......":"......",}

这个JSON字符串有许多元素,其中两个是"年"和"时间".从这个字符串,我想在两个变量中提取"年"和"时间"的值而不使用任何外部库(即,我不想为此安装下载任何外部工具,新安装的Windows应该全部这样做的必要工具).

Answer 1

这是一个混合的Batch + PowerShell解决方案.PowerShell对JSON文本进行客体化(反序列化)并以key = value格式输出以进行捕获,并通过批处理for /f循环设置为批处理变量.用.bat扩展名保存它并给它一个镜头.

<# : batch portion (contained within a PowerShell multi-line comment)
@echo off & setlocal

set "JSON={ "year": 2016, "time": "05:01" }"

rem # re-eval self with PowerShell and capture results
for /f "delims=" %%I in ('powershell "iex (${%~f0} | out-string)"') do set "%%~I"

rem # output captured results
set JSON[

rem # end main runtime
goto :EOF

: end batch / begin PowerShell hybrid code #>

add-type -AssemblyName System.Web.Extensions
$JSON = new-object Web.Script.Serialization.JavaScriptSerializer
$obj = $JSON.DeserializeObject($env:JSON)

# output object in key=value format to be captured by Batch "for /f" loop
foreach ($key in $obj.keys) { "JSON[{0}]={1}" -f $key, $obj[$key] }

然后,如果您只想要年份和时间值,只需使用%JSON[year]%或%JSON[time]%.

如果您从.json文件中读取JSON,则可以让PowerShell部分读取该文件,替换($env:JSON)为((gc jsonfile.json)).那么你根本不会依赖于你的JSON是多线的还是美化的还是缩小的.无论哪种方式,它都会被反序列化.

如果需要考虑执行速度,您可能更喜欢Batch + JScript混合解决方案.它将JSON反序列化为与PowerShell解决方案相同的对象,但从Batch上下文调用JScript比从Batch调用PowerShell命令或脚本更快.

@if (@CodeSection == @Batch) @then
@echo off & setlocal

set "JSON={ "year": 2016, "time": "05:01" }"

rem // re-eval self with JScript interpreter and capture results
for /f "delims=" %%I in ('cscript /nologo /e:JScript "%~f0"') do set "%%~I"

rem // output captured results
set JSON[

rem // end main runtime
goto :EOF

@end // end Batch / begin JScript hybrid code

var htmlfile = WSH.CreateObject('htmlfile'),
    txt = WSH.CreateObject('Wscript.Shell').Environment('process').Item('JSON');

htmlfile.write('<meta http-equiv="x-ua-compatible" content="IE=9" />');
var obj = htmlfile.parentWindow.JSON.parse(txt);
htmlfile.close();

for (var i in obj) WSH.Echo('JSON[' + i + ']=' + obj[i]);

与第一个PowerShell混合解决方案的情况一样,如果您愿意,可以通过从JScript部分中读取.json文件来解析多行JSON(通过创建Scripting.FileSystemObject对象并调用它.OpenTextFile()和.ReadAll()方法).

这是另一个纯批处理解决方案,但是将key = value对设置为关联数组,以避免%time%像Aacini的解决方案那样踩踏.我认为最好将JSON解析为辅助语言中的对象而不是纯批处理中的平面文本,但我也意识到最好的答案并不总是最受欢迎.

@echo off
setlocal

set "JSON={ "other": 1234, "year": 2016, "value": "str", "time": "05:01" }"

set "JSON=%JSON:~1,-1%"
set "JSON=%JSON:":=",%"

set mod=0
for %%I in (%JSON%) do (
    set /a mod = !mod
    setlocal enabledelayedexpansion
    if !mod! equ 0 (
        for %%# in ("!var!") do endlocal & set "JSON[%%~#]=%%~I"
    ) else (
        endlocal & set "var=%%~I"
    )
)

set JSON[

Answer 2

@echo off
setlocal

set string={ "other": 1234, "year": 2016, "value": "str", "time": "05:01" }

rem Remove quotes
set string=%string:"=%
rem Remove braces
set "string=%string:~2,-2%"
rem Change colon+space by equal-sign
set "string=%string:: ==%"
rem Separate parts at comma into individual assignments
set "%string:, =" & set "%"

echo other="%other%"
echo year="%year%"
echo value="%value%"
echo time="%time%"

输出:

other="1234"
year="2016"
value="str"
time="05:01"

这种方法的一个小不方便是"时间"批量动态变量将被新的JSON替换,但是如果你使用setlocal命令,这一点不会引起任何问题.

Answer 3

有不同的方式,这是一个.

@echo off
set string={ "year": 2016, "time": "05:01" }
set string=%string:"=%

for /f "tokens=3,5" %%a in ('echo %string%') do set d=%%a&set t=%%b
echo -%d%- -%t%-
pause & goto :EOF

这是第二个:

@echo off
set string={ "year": 2016, "time": "05:01" }

for /f "tokens=3,5" %%a in ('echo %string%') do set d=%%~a&set t=%%~b
echo -%d%- -%t%-
pause & goto :EOF