使用Oracle PL/SQL For循环迭代逗号分隔的字符串

Question

我正在编写一段代码,需要迭代字符串的内容,每个值用a分隔,.

我有我的 elements

v_list_pak_like varchar2(4000) := 'PEBO,PTGC,PTTL,PTOP,PTA';

如何将它放入Array/Cursor中以在循环中迭代它？

for x in (elements)
loop
   -- do my stuff
end loop;

我正在寻找非常简单的方法,如果可能的话,避免声明关联数组.

是否有可能创建一个函数来返回可用作for循环输入的东西(与可以像/sf/answers/1342894241/中使用的while相反)？

提前谢谢了.

Answer 1

您可以在纯SQL中轻松完成.有多种方法可以实现,请参阅将逗号分隔的字符串拆分为Oracle中的行

但是,如果你真的想在PL/SQL中这样做,那么你可以这样做:

SQL> set serveroutput on
SQL> DECLARE
  2    str VARCHAR2(100) := 'PEBO,PTGC,PTTL,PTOP,PTA';
  3  BEGIN
  4    FOR i IN
  5    (SELECT trim(regexp_substr(str, '[^,]+', 1, LEVEL)) l
  6    FROM dual
  7      CONNECT BY LEVEL <= regexp_count(str, ',')+1
  8    )
  9    LOOP
 10      dbms_output.put_line(i.l);
 11    END LOOP;
 12  END;
 13  /
PEBO
PTGC
PTTL
PTOP
PTA

PL/SQL procedure successfully completed.

SQL>

Answer 2

感谢 Lalit 的出色指示，我能够创建一个可以从循环中调用的函数for：

创建类型和函数

CREATE OR REPLACE TYPE t_my_list AS TABLE OF VARCHAR2(100);
CREATE OR REPLACE
       FUNCTION comma_to_table(p_list IN VARCHAR2)
         RETURN t_my_list
       AS
         l_string VARCHAR2(32767) := p_list || ',';
         l_comma_index PLS_INTEGER;
         l_index PLS_INTEGER := 1;
         l_tab t_my_list     := t_my_list();
       BEGIN
         LOOP
           l_comma_index := INSTR(l_string, ',', l_index);
           EXIT
         WHEN l_comma_index = 0;
           l_tab.EXTEND;
           l_tab(l_tab.COUNT) := TRIM(SUBSTR(l_string,l_index,l_comma_index - l_index));
           l_index            := l_comma_index + 1;
         END LOOP;
         RETURN l_tab;
       END comma_to_table;
/

然后如何在我的for循环中调用它：

declare
  v_list_pak_like varchar2(4000) := 'PEBO,PTGC,PTTL,PTOP,PTA';
begin
    FOR x IN (select * from (table(comma_to_table(v_list_pak_like)) ) )
    loop
        dbms_output.put_line(x.COLUMN_VALUE);
    end loop;
end;
/

请注意 Oracle 给出的默认名称COLUMN_VALUE，这是我想要使用结果所必需的。

结果符合预期：

PEBO
PTGC
PTTL
PTOP
PTA