has_many,通过Ecto的协会

Question

我还在尝试如何处理has_many, through:在Ecto中创建/更新关联的问题.我重新阅读了José关于协会和文档的帖子,但我仍在努力.

我有的是这个:

网络/模型/ dish.ex

defmodule Mp.Dish do
  use Mp.Web, :model

  schema "dishes" do
    # ...
    has_many :dish_dietary_prefs, Mp.DishDietaryPref, on_delete: :delete_all,
      on_replace: :delete
    has_many :dietary_prefs, through: [:dish_dietary_prefs, :dietary_pref]
  end

  # ...
end

网络/模型/ dietary_pref.ex

defmodule Mp.DietaryPref do
  use Mp.Web, :model

  schema "dietary_prefs" do
    # ...
    has_many :dish_dietary_prefs, Mp.DishDietaryPref, on_delete: :delete_all,
      on_replace: :delete
    has_many :dishes, through: [:dish_dietary_prefs, :dish]
  end

  # ...
end

网络/模型/ dish_dietary_pref.ex

defmodule Mp.DishDietaryPref do
  use Ecto.Schema

  schema "dish_dietary_prefs" do
    belongs_to :dish, Mp.Dish
    belongs_to :dietary_pref, Mp.DietaryPref
  end
end

我有一个接收a的参数的JSON端点Dish,在其中我有一个名为dietary_prefscall 的键作为逗号分隔的字符串传递,因此,例如:

[info] POST /api/vendors/4/dishes
[debug] Processing by Mp.Api.DishController.create/2
  Parameters: %{"dish" => %{"dietary_prefs" => "2,1"}, "vendor_id" => "4"}

("dish"为此SO帖子删除了其他参数.)

---

我如何在我的控制器中处理这个？具体来说,我想要这种行为:

1. 对于POST请求(创建操作),创建必要的记录dish_dietary_prefs以将此新关联Dish与给定的DietaryPrefs 相关联.逗号分隔的字符串是记录的ids DietaryPref.
2. 对于PUT/PATCH请求(更新),创建/销毁必要的记录dish_dietary_prefs以更新关联(用户可以将菜肴重新分配给不同的饮食首选项).
3. 对于DELETE请求,销毁dish_dietary_prefs.我认为这种情况已经on_delete通过模型中的配置来处理.

我已经在我的控制器中有逻辑来为给定的供应商创建/更新菜肴(这只是一个简单的has_many/belongs_to关系),但我仍然无法弄清楚如何创建/更新/销毁给定菜肴的这些关联.

任何帮助将不胜感激.

---

如果我将"需要接收的识别码与手工打造为中间协会每个" DietaryPref我关联的Dish,我能得到的我会怎么做,要在我的控制器上面的规格的例子吗？

---

更新:刚看到Ecto 2.0.0-beta.1已经发布,这就是支持many_to_many,看起来它可以解决我的问题.任何人都有一个在行动中使用它的例子,就像我上面所描述的那样？

Answer 1

感谢无耻的Jedi-MasterJoséValim本人,我已经弄明白了(在Ecto中2.0.0-beta.1):

这是我的最终控制者:

def create(conn, %{"dish" => dish_params }, vendor) do
  dietary_prefs = get_dietary_pref_changeset(dish_params["dietary_prefs"])

  changeset = vendor
  |> build_assoc(:dishes)
  |> Repo.preload(:dietary_prefs)
  |> Dish.changeset(dish_params)
  |> Ecto.Changeset.put_assoc(:dietary_prefs, dietary_prefs)

  case Repo.insert(changeset) do
    {:ok, dish} ->
      conn
      |> put_status(:created)
      |> render("show.json", dish: dish)
    {:error, changeset} ->
      conn
      |> put_status(:unprocessable_entity)
      |> render(ChangesetView, "error.json", changeset: changeset)
  end
end

def update(conn, %{"id" => id, "dish" => dish_params}, vendor) do
  dish = Repo.get!(vendor_dishes(vendor), id)
  dietary_prefs = get_dietary_pref_changeset(dish_params["dietary_prefs"])

  changeset = dish
  |> Repo.preload(:dietary_prefs)
  |> Dish.changeset(dish_params)
  |> Ecto.Changeset.put_assoc(:dietary_prefs, dietary_prefs)

  case Repo.update(changeset) do
    { :ok, dish } ->
      render(conn, "show.json", dish: dish)
    { :error, changeset } ->
      conn
      |> put_status(:unprocessable_entity)
      |> render(ChangesetView, "error.json", changeset: changeset)
  end
end

defp vendor_dishes(vendor) do
  assoc(vendor, :dishes)
end

defp parse_dietary_pref_ids(ids) do
  ids
  |> String.split(",")
  |> Enum.map(fn(x) -> Integer.parse(x) |> Kernel.elem(0) end)
end

defp get_dietary_prefs_with_ids(ids) do
  from(dp in DietaryPref, where: dp.id in ^ids) |> Repo.all
end

defp get_dietary_pref_changeset(param) do
  param
  |> parse_dietary_pref_ids
  |> get_dietary_prefs_with_ids
  |> Enum.map(&Ecto.Changeset.change/1)
end

https://groups.google.com/forum/#!topic/elixir-ecto/3cAi6nrsawk