出错时退出子程序并将错误返回给调用错误子程序的子程序

Question

一些背景：

前奏：我已经查看了其他错误处理问题，但我无法完全将答案应用于我的情况。我感到Err.Raise这就是我将如何完成我将在下面描述的事情。但是，我不确定如何以我需要的方式实现它。如果我要使用，Err.Raise如何在主子中引发错误代码之前先退出 Sub1-15？

话虽如此，

我有一个大型 Excel VBA 项目，它执行大量不同的例程。我选择从一个主例程中调用所有例程，以便以后维护各个例程。我有一个On Error处理程序，如果从该主例程调用的任何例程中抛出错误，我希望触发该处理程序。

有没有办法：

1. 记录
   • 发生的错误类型
   • 错误信息
   • 引发错误的子项
2. 出现错误时退出该子程序以返回主子程序，然后
   • 引发另一个子中刚刚发生的错误，以便调用NotifyandRepair错误处理程序？

我有以下情况

Sub MainSub()
    On Error GoTo NotifyandCorrect
    Call Sub1
    Call Sub2
    ...
    Call Sub15
    Exit Sub
NotifyandCorrect:
    'Send copy of faulty file, the error code and Sub that caused it
    'Then stop macro execution completely
End Sub

Sub Sub1()
    On Error Exit Sub1 and raise current Error in MainSub(?)
    'Perform data checks
End Sub

Sub Sub2()
    On Error Exit Sub2 and raise current Error in MainSub(?
    'Modify data groups
End Sub

Sub Sub15()
    On Error Exit Sub15 and raise current Error in MainSub(?
    'Clean up work
End Sub

无论如何，我是否可以避免对 Sub1-Sub15 中的每一个执行如下操作？

Sub MainSub()
        On Error GoTo NotifyandCorrect
        Call Sub1
        Call Sub2
        ...
        Call Sub15
        Exit Sub
    NotifyandCorrect:
        'Send copy of faulty file, the error code and Sub that caused it
        'Then stop macro execution completely
    End Sub
    ...
    ...
Sub Sub15()
    On Error Goto HaltExecution
    'Clean up work
    Exit Sub
HaltExecution:
    'Note Error message & type
    'Note that Sub15 is where error occurred
    End Sub

结束语

1. 这是可能吗？
2. 如果这是不可能的，我应该如何处理这个问题以完成我所描述的事情？你有什么建议（如果可以的话请提供一个例子）

Answer 1

您需要处理“子”方法中的错误，并让它们“重新抛出”错误（Err.Raise在错误处理程序子例程中使用），以便调用者可以看到它 - 重新抛出时，将方法的名称指定为“来源”。以下代码产生此输出：

5            Invalid procedure call or argument        DoSomething1
9            Subscript out of range      DoSomething2

Public Sub MainSub()
    On Error GoTo ErrHandler

    DoSomething1
    DoSomething2

    Exit Sub
ErrHandler:
    Debug.Print Err.Number, Err.Description, Err.Source
    Resume Next
End Sub

Private Sub DoSomething1()
    On Error GoTo ErrHandler

    Err.Raise 5

    Exit Sub
ErrHandler:
    Err.Raise Err.Number, "DoSomething1", Err.Description
End Sub

Private Sub DoSomething2()
    On Error GoTo ErrHandler

    Err.Raise 9

    Exit Sub
ErrHandler:
    Err.Raise Err.Number, "DoSomething2", Err.Description
End Sub

无论如何，我是否可以避免对 Sub1-Sub15 中的每一个执行如下操作？

不可以。每个过程都必须处理运行时错误，没有办法解决它。

在硬编码字符串中指定方法名称很烦人。通过将每个过程封装到其自己的对象中（例如，某些ICommand实现），您可以利用以下TypeName函数实现相同的结果：

模块1

Option Explicit

Public Sub MainSub()
    On Error GoTo ErrHandler

    RunCommand New DoSomething1
    RunCommand New DoSomething2

    Exit Sub
ErrHandler:
    Debug.Print Err.Number, Err.Description, Err.Source
    Resume Next
End Sub

Private Sub RunCommand(ByVal command As ICommand)
    command.Execute
End Sub

ICommand（类模块）

Public Sub Execute()
End Sub

DoSomething1（类模块）

Option Explicit
Implements ICommand

Private Sub ICommand_Execute()
    On Error GoTo ErrHandler

    Err.Raise 5

ErrHandler:
    Err.Raise Err.Number, TypeName(Me), Err.Description
End Sub

DoSomething2（类模块）

Option Explicit
Implements ICommand

Private Sub ICommand_Execute()
    On Error GoTo ErrHandler

    Err.Raise 9

ErrHandler:
    Err.Raise Err.Number, TypeName(Me), Err.Description
End Sub

该ICommand接口并不是真正需要的，但它正式化了每个DoSomething命令的调用方式。这个想法是有一个对象来实现每个过程 - 这样您就可以将TypeName(Me)其作为错误源，并且永远不需要对字符串进行硬编码。您将在 15 个专用类模块中拥有 15 个方法，而不是在单个标准模块中拥有 15 个过程。