F#：导数函数

Question

我想弄清楚如何让这个功能工作。我对 F# 非常无能，所以感谢解释，

let deriv (f:(float->float), dx: float) = 
    fun f:(float -> float) * dx:float -> x:float -> float
let (f, dx, x) = ((f(x + dx) - f(x))/dx)

我用f:(float->float)错了吗？

Answer 1

与其试图解决您的问题，不如从头开始解释。

符号导数是一个函数，它接受一个函数并返回一个新函数。但是，您正在尝试计算在给定函数、值和增量的情况下返回值的数值导数。

首先，我们将为函数命名：deriv 它需要三个参数：
1. 一个函数，它接受一个浮点数并返回一个浮点数：(f : float -> float)
2. 要计算导数的位置的值：(x0 : float)
3. 一个增量：(dx : float)

您的示例中有三个参数中的两个，但缺少x0.

它也应该返回一个浮点数。

所以签名是

deriv (f : (float -> float)) (x0 : float) (dx : float) : float

现在计算数值导数。我不会解释这个，只是参考导数

对于这个例子，我们将使用一个具有导数的简单函数，x^2。

这是 F# 中的代码

// val deriv : f:(float -> float) -> x0:float -> dx:float -> float
let deriv (f : (float -> float)) (x0 : float) (dx : float) : float =
    let (x1 : float) = x0 - dx
    let (x2 : float) = x0 + dx
    let (y1 : float) = f x1
    let (y2 : float) = f x2
    let (result : float) = (y2 - y1) / (x2 - x1)
    result

// val f : x:float -> float
let f x = x**2.0

快速测试表明它可以正常工作。

// val it : float = 2.0
deriv f 1.0 0.000005

对一系列值进行更彻底的测试。

使用Visual Studio和NuGet安装FSharp.Charting

在 F# 交互中

#I "..\packages"
#load "FSharp.Charting.0.90.13\FSharp.Charting.fsx"
open FSharp.Charting

let xs1 = [ for x in (double)(-3.10) .. 0.05 .. 3.10 do yield x]
let ys1 = xs1 |> List.map f
let values1 = List.zip xs1 ys1
Chart.Line(values1)
    .WithXAxis(Min=(-4.0), Max=4.0, MajorTickMark = ChartTypes.TickMark(Interval=2.0, IntervalOffset = 1.0, LineWidth = 2))
    .WithYAxis(Min=(0.0), Max=10.0, MajorTickMark = ChartTypes.TickMark(Interval=2.0, IntervalOffset = 1.0, LineWidth = 2))

这也可以使用 Wolfram Alpha 确认：x^2

一个更简单的例子：

// val d : x:float -> float
let d x = deriv f x 0.00000005

let xs2 = [ for x in (double)(-3.10) .. 0.05 .. 3.10 do yield x]
let ys2 = xs2 |> List.map d
let values2 = List.zip xs2 ys2
Chart.Line(values2)
    .WithXAxis(Min=(-4.0), Max=4.0, MajorTickMark = ChartTypes.TickMark(Interval=2.0, IntervalOffset = 1.0, LineWidth = 2))
    .WithYAxis(Min=(-6.0), Max=6.0, MajorTickMark = ChartTypes.TickMark(Interval=2.0, IntervalOffset = 1.0, LineWidth = 2))

这也可以使用 Wolfram Alpha 确认：d/dx x^2