如何在视频停止播放后使用闪光灯自动录制视频响应

Question

使用Mediaelementjs,我已经成功实现了一个视频播放器,并触发了一个end event立即弹出adobe的闪光录音机.在"网站隐私设置"面板中列出该网站,可通过浏览器直接访问麦克风和摄像头.

问题:
在用户允许访问麦克风和摄像头之后是否有办法触发某些功能,比如开始录制视频？

在用户允许使用闪光灯访问麦克风和相机后,我们能否以某种方式立即录制视频.

Answer 1

我的回答质量很低，因为很多年前我就对 Flash 失去了兴趣。最礼貌的说法是：我的 Flash 技术已经生锈了。（生锈是指 Flash-8 ActionScript 2.0 / Flash CS4 ActionScript 2.0 级别的生锈）。真正的问题是什么 - 我当前的计算机上没有 Flash 测试环境。因此，这将是一个盲目的建议。谨防错误。

但是，好的一面是，我确实有集成 Flash 和 Javascript 的经验。从我看来，其中一些内容仍然具有相关性。

我所知道的技术简短列表：

JavaScript 到 Flash：

1. Flash 提供的ExternalInterface 对象允许Javascript 在Flash 内部执行方法——这可以启动动画或返回数据。缺点：ExternalInterface 可能会被安全设置或插件的错误实现所禁止。

2. document.getElementById('exampleMovie').SetVariable("someVariableName", "一些文本"); - 使用它作为消息系统 - 添加将监听的 Flash 计时器 - 进行了变量更改

Flash 到 JavaScript：

1. Flash 提供的ExternalInterface 对象允许Flash 从Javascript 执行函数。缺点：ExternalInterface 可能会被安全设置或插件的错误实现所禁止。

2. getUrl( 'javascript:someJavascriptFunction( "a", "b", true );' ); 我不确定它是否出于安全原因被禁止，但它可以工作。主要缺点是它是一种单向交互。

我认为使用外部接口是实现交互的最合乎逻辑的方式。

是的，你可以使用单向交互 2. 和 2. 来构建通信协议 - 我什至可以想象那个系统......但这有点太反常了 ^ ^。+ 我找不到任何有关浏览器支持“SetVariable”的数据。+ Stackoverflow 报告了 SetVariable 在 Firefox 中的奇怪行为SetVariable 在 Firefox 中不起作用

以下是外部接口的官方文档： http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/external/ExternalInterface.html

该页面有一个浏览器兼容性表。也许文档需要更新 - 没有 Google Chrome 的痕迹，在我看来这感觉很奇怪......

从概念上讲，您可以像这样使用外部接口：

// HTML
// id must be equal to name here
// and shouldn't contain symbols . - + * / \
<object id="exampleFlash" name="exampleFlash" ... >
    ...
</object>

// Javascript:
document.getElementById('exampleFlash').methodExposedForJavascript('value')

// ActionScript in Flash:
import flash.external.ExternalInterface;
ExternalInterface.addCallback( "methodExposedForJavascript", someInternalFunction );
function someInternalFunction( msg ) {
    // do something with msg - for example output it to existing txt field:
    _root.txtExampleTxt.text = msg;
}

最相关的示例是该手册页上的最后一个 http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/external/ExternalInterface.html

如何编译复杂示例的简短说明：http://help.adobe.com/en_US/as3/dev/WS9b644acd4ebe5999-2734bf3c124372a52ff-8000.html

它们其实很简单。最明显的复杂性来自于它们以编程方式生成 Flash 元素的事实 - 例如

// all that this code does - is creating simple TextField in your movie
import flash.text.TextField;
package  {
    public class ABC extends Sprite 
    {
        private var output:TextField;
        public function ABC() 
        {
            output = new TextField();
            output.y = 25;
            output.width = 450;
            addChild(output);
        }
    }
}

这样做是为了使示例更容易表达 - 但这基本上与“使用 GUI在第一帧中创建名为输出的文本字段”相同。

我将尝试从该示例中删除任何不需要的内容。 注意“receivedFromJavaScript” - 这是一个由Javascript触发的函数 - 你可以在里面添加反应。

闪光部分：

package  {

    import flash.display.Sprite;
    import flash.events.*;
    import flash.external.ExternalInterface;
    import flash.text.TextField;
    import flash.utils.Timer;
    import flash.text.TextFieldType;
    import flash.text.TextFieldAutoSize;
    import flash.system.Security;

    public class ExternalInterfaceExample extends Sprite 
    {
        private var output:TextField;

        public function ExternalInterfaceExample() 
        {
            // constructor code
            Security.allowDomain("*");


            output = new TextField();
            output.y = 25;
            output.width = 450;
            output.height = 325;
            output.multiline = true;
            output.wordWrap = true;
            output.border = true;
            output.text = "Initializing...\n";
            addChild(output);


            if (ExternalInterface.available) {
                try {
                    output.appendText("Adding callback...\n");
                    ExternalInterface.addCallback("sendToActionScript", receivedFromJavaScript);
                    if (checkJavaScriptReady()) {
                        output.appendText("JavaScript is ready.\n");
                    } else {
                        output.appendText("JavaScript is not ready, creating timer.\n");
                        var readyTimer:Timer = new Timer(100, 0);
                        readyTimer.addEventListener(TimerEvent.TIMER, timerHandler);
                        readyTimer.start();
                    }
                } catch (error:SecurityError) {
                    output.appendText("A SecurityError occurred: " + error.message + "\n");
                } catch (error:Error) {
                    output.appendText("An Error occurred: " + error.message + "\n");
                }
            } else {
                output.appendText("External interface is not available for this container.");
            }
        }
        private function receivedFromJavaScript(value:String):void {
            output.appendText("JavaScript says: " + value + "\n");
        }
        private function checkJavaScriptReady():Boolean {
            var isReady:Boolean = ExternalInterface.call("isReady");
            return isReady;
        }
        private function timerHandler(event:TimerEvent):void {
            output.appendText("Checking JavaScript status...\n");
            var isReady:Boolean = checkJavaScriptReady();
            if (isReady) {
                output.appendText("JavaScript is ready.\n");
                output.appendText("ExternalInterface.objectID = " + ExternalInterface.objectID + "\n");
                Timer(event.target).stop();
            }
        }
    }
}

HTML：

<!DOCTYPE html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>ExternalInterfaceExample</title>
<script>
    var jsReady = false;
    function isReady() {
        return jsReady;
    }
    function pageInit() {
        jsReady = true;
        document.forms["form1"].output.value += "\n" + "JavaScript is ready.\n";
    }
    function sendToActionScript(value) {
        document.getElementById("ExternalInterfaceExample").sendToActionScript(value);
    }
</script>
</head>
<body onload="pageInit();">

<object id="ExternalInterfaceExample"  name="ExternalInterfaceExample" 
type="application/x-shockwave-flash" data="ExternalInterfaceExample.swf" width="550" height="400">
<param name="movie" value="ExternalInterfaceExample.swf"/>
<param name="quality" value="high"/>
<param name="allowscriptaccess" value="always"/>
<a href="http://www.adobe.com/go/getflash">
    <img src="http://www.adobe.com/images/shared/download_buttons/get_flash_player.gif" alt="Get Adobe Flash player"/>
</a>
</object>

    <form name="form1" onsubmit="return false;">
        <input type="text" name="input" value="" />
        <input type="button" value="Send" onclick="sendToActionScript(this.form.input.value);" /><br />
        <textarea cols="60" rows="20" name="output" readonly="true">Initializing...</textarea>
    </form>

</body>
</html>