那些遇到过的问题

如何在CONSTRUCT的图形上创建聚合

Ani*_*vid 2 rdf semantic-web owl ontology sparql

这是我的查询:

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rs: <http://www.welovethesemanticweb.com/rs#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    construct {
  ?subject0 rs:similarityValue ?similairty0.
    ?subject1 rs:similarityValue ?similairty1
}
WHERE {

  {
  ?subject0 ?predicate0 ?object0.
  rs:Impromptu_No._1 ?predicate0 ?object0.
    ?predicate0 rs:hasSimilarityValue ?similairty0Helper.
    BIND(?similairty0Helper * (4/9) AS ?similairty0)
    FILTER (?subject0 != rs:Impromptu_No)  
  }
  union {
    ?subject1 ?predicate ?object.
    ?object ?predicate1 ?object1.
    ?predicate1 rs:hasSimilarityValue ?similairty1Helper.
    rs:Impromptu_No._1 ?predicateHelper ?objectHelper.
    ?objectHelper ?predicate1 ?object1
      BIND(?similairty1Helper * (1/9) AS ?similairty1)
    FILTER (?subject1 != rs:Impromptu_No._1)
  }
}
Run Code Online (Sandbox Code Playgroud)

结果是:

rs:5th_Symphony
      rs:similarityValue
            0.011111111111111112e0 .

rs:Polonaise_heroique
      rs:similarityValue
            0.011111111111111112e0 , 0.17777777777777778e0 , 0.26666666666666666e0 .

rs:Preludes
      rs:similarityValue
            0.011111111111111112e0 , 0.26666666666666666e0 , 0.17777777777777778e0 .

rs:Requiem_Sequentia
      rs:similarityValue
            0.011111111111111112e0 .

rs:Le_nozze_di_Figaro
      rs:similarityValue
            0.011111111111111112e0 .

rs:Symphony_No._29_in_A_major
      rs:similarityValue
            0.011111111111111112e0 .

rs:Piano_Concerto_No._24
      rs:similarityValue
            0.011111111111111112e0 .

rs:Impromptu_No._1
      rs:similarityValue
            0.26666666666666666e0 , 0.17777777777777778e0 .

rs:Sonata_Pathetique
      rs:similarityValue
            0.011111111111111112e0 .

rs:Dies_Irae
      rs:similarityValue
            0.011111111111111112e0 .

rs:Piano_Sonata_No._31
      rs:similarityValue
            0.011111111111111112e0 , 0.26666666666666666e0 .

rs:Violin_Concerto_No._5_in_A_major
      rs:similarityValue
            0.011111111111111112e0 .
Run Code Online (Sandbox Code Playgroud)

如您所见,对于每个实例,有许多值,我想聚合它们并SUM为每个实例创建它们.我会这样做SELECT,但是CONSTRUCT,我不知道如何应用聚合.

看完后,我发现,我们不能直接从使用聚合CONSTRUCT,但我需要使用SELECT和CONSTRUCT在一起,看来我必须使用一个名为"命名图"的东西,但我不知道该怎么做,即使我试过.

非常感谢您的帮助.

非常感谢,最好的问候,

更新1

我试过的方法之一是:

construct {
  ?subject0 rs:similarityValue ?similairty0.
    ?subject1 rs:similarityValue ?similairty1
}
WHERE {
  GRAPH ?g  {?subject0 rs:similarityValue ?similairty0}.
  {
  ?subject0 ?predicate0 ?object0.
....
Run Code Online (Sandbox Code Playgroud)

但我得到了空洞的结果

Jos*_*lor 5

首先,最好确保您可以选择要检索的所有信息.看起来你的目标是这样:

prefix rs: <http://www.welovethesemanticweb.com/rs#>

select distinct ?s ?weight ?factor where {
  #-- ?x is the special value of interest.  This
  #-- is pulled out into a VALUES block just for
  #-- convenience; there's just one place to change
  #-- rs:Impromptu_No._1, now.
  values ?x { rs:Impromptu_No._1 }

  #-- find ?s which are "one step" away from
  #-- a common property/value with ?x, and
  #-- take 4/9 as ?weight.
  {
    ?s ?p ?o .
    ?x ?p ?o .
    bind(4/9 as ?weight)
  }
  union
  #-- find ?s which are are "two steps" away from
  #-- a common property/value with ?x, and take
  #-- 1/9 as ?weight
  {
    ?s ?a ?b . ?b ?p ?o .
    ?x ?c ?d . ?d ?p ?o .
    bind(1/9 as ?weight)
  }

  #-- get the similarity factor of the property
  #-- and make sure that ?s is different from ?x.
  ?p rs:hasSimilarityValue ?factor .
  filter(?s != ?x)
}
Run Code Online (Sandbox Code Playgroud) 
-----------------------------------------------------------------------------------------------------------------------
| s                                   | weight                     | factor                                           |
=======================================================================================================================
| rs:5th_Symphony                     | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Dies_Irae                        | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Le_nozze_di_Figaro               | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Piano_Concerto_No._24            | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Piano_Sonata_No._31              | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Piano_Sonata_No._31              | 0.444444444444444444444444 | "0.6"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Polonaise_heroique               | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Polonaise_heroique               | 0.444444444444444444444444 | "0.4"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Polonaise_heroique               | 0.444444444444444444444444 | "0.6"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Preludes                         | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Preludes                         | 0.444444444444444444444444 | "0.4"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Preludes                         | 0.444444444444444444444444 | "0.6"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Requiem_Sequentia                | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Sonata_Pathetique                | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Symphony_No._29_in_A_major       | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
| rs:Violin_Concerto_No._5_in_A_major | 0.111111111111111111111111 | "0.1"^^<http://www.w3.org/2001/XMLSchema#double> |
-----------------------------------------------------------------------------------------------------------------------
Run Code Online (Sandbox Code Playgroud)

现在,似乎在此之后,您希望按？s的值进行分组并将加权相似度相加:

select distinct ?s (sum(?weight * ?factor) as ?similarity) where {
  values ?x { rs:Impromptu_No._1 }
  {
    ?s ?p ?o .
    ?x ?p ?o .
    bind(4/9 as ?weight)
  }
  union
  {
    ?s ?a ?b . ?b ?p ?o .
    ?x ?c ?d . ?d ?p ?o .
    bind(1/9 as ?weight)
  }

  ?p rs:hasSimilarityValue ?factor .
  filter(?s != ?x)
}
group by ?s
Run Code Online (Sandbox Code Playgroud) 
----------------------------------------------------------------
| s                                   | similarity             |
================================================================
| rs:5th_Symphony                     | 0.044444444444444446e0 |
| rs:Piano_Concerto_No._24            | 0.044444444444444446e0 |
| rs:Requiem_Sequentia                | 0.044444444444444446e0 |
| rs:Dies_Irae                        | 0.044444444444444446e0 |
| rs:Piano_Sonata_No._31              | 0.31111111111111117e0  |
| rs:Symphony_No._29_in_A_major       | 0.044444444444444446e0 |
| rs:Le_nozze_di_Figaro               | 0.044444444444444446e0 |
| rs:Violin_Concerto_No._5_in_A_major | 0.044444444444444446e0 |
| rs:Sonata_Pathetique                | 0.044444444444444446e0 |
| rs:Preludes                         | 0.48888888888888893e0  |
| rs:Polonaise_heroique               | 0.48888888888888893e0  |
----------------------------------------------------------------
Run Code Online (Sandbox Code Playgroud)

最后,由于您已经获得了所需的值,因此您现在可以构建所需的三元组:

construct {
  ?s rs:similarityValue ?similarity
}
where {{
  select distinct ?s (sum(?weight * ?factor) as ?similarity) where {
    values ?x { rs:Impromptu_No._1 }
    {
      ?s ?p ?o .
      ?x ?p ?o .
      bind(4/9 as ?weight)
    }
    union
    {
      ?s ?a ?b . ?b ?p ?o .
      ?x ?c ?d . ?d ?p ?o .
      bind(1/9 as ?weight)
    }
    ?p rs:hasSimilarityValue ?factor .
    filter(?s != ?x)
  }
  group by ?s
}}
Run Code Online (Sandbox Code Playgroud) 
@prefix :      <http://www.semanticweb.org/rs#> .
@prefix rs:    <http://www.welovethesemanticweb.com/rs#> .
@prefix rdf:   <http://www.w3.org/1999/02/22-rdf-syntax-ns#> .
@prefix owl:   <http://www.w3.org/2002/07/owl#> .
@prefix xsd:   <http://www.w3.org/2001/XMLSchema#> .
@prefix rdfs:  <http://www.w3.org/2000/01/rdf-schema#> .

rs:5th_Symphony  rs:similarityValue  0.044444444444444446e0 .

rs:Polonaise_heroique
        rs:similarityValue  0.48888888888888893e0 .

rs:Preludes  rs:similarityValue  0.48888888888888893e0 .

rs:Requiem_Sequentia  rs:similarityValue
                0.044444444444444446e0 .

rs:Le_nozze_di_Figaro
        rs:similarityValue  0.044444444444444446e0 .

rs:Symphony_No._29_in_A_major
        rs:similarityValue  0.044444444444444446e0 .

rs:Piano_Concerto_No._24
        rs:similarityValue  0.044444444444444446e0 .

rs:Sonata_Pathetique  rs:similarityValue
                0.044444444444444446e0 .

rs:Dies_Irae  rs:similarityValue  0.044444444444444446e0 .

rs:Piano_Sonata_No._31
        rs:similarityValue  0.31111111111111117e0 .

rs:Violin_Concerto_No._5_in_A_major
        rs:similarityValue  0.044444444444444446e0 .
Run Code Online (Sandbox Code Playgroud)

归档时间：

查看次数：

174 次

最近记录：

9 年，9 月 前
相关归档
什么是Ontology(数据库？)？ 20
"reify"和"具体化"对RDF有何意义？ 9
为什么clojure.data.xml在解析RDF文件时不返回xml命名空间？ 7
了解SPARQL是什么 6
Marklogic 7:语义搜索 6
可靠地查询SPARQL端点并在本地缓存结果 5
为什么使用owl:Restriction as own:EquivalenceClass的属性？ 4
OWL:非负整数和正整数之间有什么区别？ 3
文字是RDF资源吗？ 2
owl的含义:hasValue？ 1
难疑归档
是什么 !!(不是)JavaScript中的运算符？ 2906
确定已安装的PowerShell版本 2543
如何将package.json中的每个依赖项更新为最新版本？ 1871
如何使用Bash将stdout和stderr重定向并附加到文件中？ 1440
安全地将JSON字符串转换为对象 1298
使用react路由器以编程方式导航 1251
在HTML中显示哪些字符可用于上/下三角(没有词干的箭头)？ 1212
检查jQuery中是否存在元素 1209
angular.service vs angular.factory 1061
jQuery的jquery-1.10.2.min.map触发了404(未找到) 1051