在一个机器人文件中混合关键字驱动的测试和数据驱动的测试

Question

是否可以在一个机器人文件中混合关键字驱动的测试和数据驱动的测试？我不知道如何把这两件放在一起.我只在一个机器人文件中需要它.

数据驱动测试的一个例子:

*** Settings ***
Test Template       Invalid Login

*** Test Cases ***  USERNAME            PASSWORD
Invalid Username    invalid             ${VALID PASSWORD}
Invalid Password    ${VALID USERNAME}   invalid
Invalid Both        invalid             invalid
Empty Username      ${EMPTY}            ${VALID PASSWORD}
Empty Password      ${VALID USERNAME}   ${EMPTY}
Empty Both          ${EMPTY}            ${EMPTY}

*** Keywords ***
Invalid Login
  [Arguments]   ${username}   ${password}
  Input Username    ${username}
  Input Password    ${password}
  Submit Credentials
  Error Page Should Be Open

如何使用我的关键字驱动测试的关键字？

Answer 1

从"设置"部分删除测试模板.

使用[Template]指令添加测试用例:

*** Test Cases ***
Invalid Password
    [Template]    Invalid Login
    invalid          ${VALID PASSWORD}
    ${VALID USER}    invalid
    invalid          whatever
    ${EMPTY}         ${VALID PASSWORD}
    ${VALID USER}    ${EMPTY}
    ${EMPTY}         ${EMPTY}

*** Keywords ***
Invalid Login
  [Arguments]   ${username}   ${password}
  Input Username    ${username}
  Input Password    ${password}
  Submit Credentials
  Error Page Should Be Open

有关更多信息,请参阅文档:http://robotframework.org/robotframework/latest/RobotFrameworkUserGuide.html#test-templates