如何在不扫描整个表的情况下检索ets键列表？

Question

我使用ets通过elixir作为一个简单的内存持久层来存储和检索键,也用于偶尔的foldl,它涉及减少许多具有不同值的重复键.我正在使用行李选项.

是否有一种简单的O(1)方法来检索当前密钥的列表而无需进行更多涉及的表遍历或匹配或折叠？

Erlang或Elixir语法响应欢迎.

:ets.new(:cache, [:bag, :named_table, :protected])

我有一个原子键的静态映射,由我用来帮助插入的整数索引.但并非所有的钥匙都被使用..

chunk_key_map = %{2 => :chunk_key_2, ..... 28 => :chunk_key_28}

如果没有快速的方法,我知道我可以做一个ets:查找我的每个静态原子键值并测试!= []并生成我自己的列表,但想看看ets是否支持这样的功能.

谢谢

Answer 1

谢谢,这让我走上了正确的轨道:)

同样的事情,但将前一个键作为累加器传递:

def key_stream(table_name) do
  Stream.resource(
    fn -> :ets.first(table_name) end,
    fn :"$end_of_table" -> {:halt, nil}
       previous_key -> {[previous_key], :ets.next(table_name, previous_key)} end,
    fn _ -> :ok end)
end

Answer 2

所以我没有找到 ets 技术，而是在 Elixir 中以恒定的时间实现了键列表检索代码，因为我的键映射是静态的。

    list = Enum.reduce(2..28, [], fn head, acc -> 
            case :ets.lookup(:cache, Map.get(chunk_key_map, head)) do
                [] -> acc
                _ -> [acc, head]
            end
        end)

    List.flatten(list)

更新：根据回复，我采用了 Hamidreza 的ets 遍历逻辑，并Stream使用Stream.resource/3.

defp get_ets_keys_lazy(table_name) when is_atom(table_name) do
    eot = :"$end_of_table"

    Stream.resource(
        fn -> [] end,

        fn acc ->
            case acc do
                [] -> 
                    case :ets.first(table_name) do
                        ^eot -> {:halt, acc}
                        first_key -> {[first_key], first_key}                       
                    end

                acc -> 
                    case :ets.next(table_name, acc) do  
                        ^eot -> {:halt, acc}
                        next_key -> {[next_key], next_key}
                    end
            end
        end,

        fn _acc -> :ok end
    )
end

然后我通过管道运行流

get_ets_keys_lazy(table_name) 
    |> Stream.map(lambda1) 
    |> Stream.each(lambda2)
    |> Stream.run