Grails - grails.config.locations 不适用于类路径和 .properties 文件

Question

我正在使用 Grails 2.5.3 版本做一个应用程序。我想外包数据库代码和Log4j的部分。

Log4j 的代码位于外部 .groovy 文件中。该文件不会被用户修改，因此不必是 /classes 目录中的属性文件。对于数据库代码来说，最好的方法是在外部属性文件中包含多个功能，因为将继续作为 /classes 目录中的属性文件。此外，DataSource.groovy 与其余配置一起存在。

然后，我只实现了使用 Log4j conf：

grails.config.locations = ["file:./grails-app/conf/LogConfig.groovy"]

尽管我将文件放在 /grails-app/conf 目录中，但使用类路径不起作用。这不起作用：

grails.config.locations = ["classpath:LogConfig.groovy"]

另外，我添加了两种情况（运行应用程序和战争模式）。但是，当我运行 grails prod war 并部署 Tomcat 时，Logconfig.groovy 无法识别。

grails.config.locations = ["file:./grails-app/conf/LogConfig.groovy",
"classpath:LogConfig.groovy"]

对于数据库代码，我没有实现使用 .properties 文件。我把这个文件放在 grails-app/conf 中，它的内容是：

# DB properties
dataSource.username = xxx
dataSource.password = xxx
dataSouce.driverClassName = xxx
environments.development.dataSource.url = jdbc:mysql://localhost/xxx
environments.test.dataSource.url = jdbc:mysql://localhost/xxx
environments.production.dataSource.url = jdbc:mysql://localhost/xxx

我读过很多教程和博客，但我不知道如何才能做到这一点。

谢谢您的帮助。

Answer 1

我们如何在开发和生产模式中做到这一点。

your-application/
    conf/
        dev/
        qa/
        prod/
    grails-app/
        conf/
          Config.groovy

grails-app 目录中的 Config.groovy：

environments {

    development {
        grails.logging.jul.usebridge = true

        grails.config.locations = [
          "file:conf/dev/XXXConfig.groovy",
          "file:conf/dev/XXXDataSource.groovy",
          "file:conf/dev/XXXLog4JConfig.groovy",
          "file:conf/dev/plugins/XXXSecurityConfig.groovy",
        ]        
    }
    production {
        grails.logging.jul.usebridge = false

        grails.config.locations = [
          "classpath:XXXConfig.groovy",
          "classpath:XXXDataSource.groovy",
          "classpath:XXXLog4JConfig.groovy",
          "classpath:plugins/XXXSecurityConfig.groovy",
        ]
    }
}

对于应用程序服务器（Tomcat、Websphere 等）中的部署，您只需将配置文件所在的目录添加到类路径中。当您的配置文件目录位于类路径中时，一切正常。

例如，我们运行 Tomcat 并具有将配置目录导出到类路径的启动脚本。

对于 Grails 3.x，我编写了对此 grails.config.locations 的支持，因为他们删除了该功能，并且我不想更改我们进行配置的方式。因此，将 grails.config.locations 配置放入 grails-app/conf 目录中的 application.groovy 中。

import org.grails.core.io.DefaultResourceLocator
import org.springframework.core.env.Environment
import grails.boot.config.GrailsAutoConfiguration
import org.springframework.core.env.MapPropertySource

class ApplicationConfigurationLoader {

    private ApplicationConfigurationLoader() {}

    public static load(GrailsAutoConfiguration application, Environment environment) {
        if (application && environment) {
            DefaultResourceLocator resourceLocator = new DefaultResourceLocator()
            def applicationGroovy = application.getClass().classLoader.getResource('application.groovy')
            if (applicationGroovy) {
                def applicationConfiguration = new ConfigSlurper(grails.util.Environment.current.name).parse(applicationGroovy)
                for (String configLocation in applicationConfiguration.grails.config.locations) {
                    def configurationResource = resourceLocator.findResourceForURI(configLocation)
                    if (configurationResource) {
                        def config = new ConfigSlurper(grails.util.Environment.current.name).parse(configurationResource.getURL())
                        environment.propertySources.addFirst(new MapPropertySource(configLocation, config))
                    }
                }
            }
        }
    }
}

在你的 grails-app/init 文件夹中你有你的 Application.groovy

import grails.boot.GrailsApp
import grails.boot.config.GrailsAutoConfiguration

import org.springframework.core.env.Environment
import org.springframework.context.EnvironmentAware

import com.bcbmedical.bfw.core.util.ApplicationConfigurationLoader

class Application extends GrailsAutoConfiguration implements EnvironmentAware {
    static void main(String[] args) {
        GrailsApp.run(Application, args)
    }

    @Override
    void setEnvironment(Environment environment) {
        ApplicationConfigurationLoader.load(this, environment)
    }

}