Shadertoy的音频着色器如何工作？

Question

首先,我找不到任何适当的社区来发布这个问题所以我选择了这个.我想知道流行的基于webGL的着色器工具的音频着色器是如何工作的,因为即使我明显听说过"普通"GLSL着色器,我第一次听说过用于程序生成音频的着色器,我很惊讶.有线索吗？

Answer 1

它们基本上是一个函数,它time为音频单(左右声道)返回2个值.值从-1到1.

粘贴在这个着色器中,也许你会得到它

vec2 mainSound( float time )
{
    return vec2( sin(time * 1000.0), sin(time * 1000.0) );
}

你可以在这里看到更类似的制作声音风格的实例.

你可以这样想象它

function generateAudioSignal(time) {
   return Math.sin(time * 4000); // generate a 4khz sign wave.
}

var audioData = new Float32Array(44100 * 4); // 4 seconds of audio at 44.1khz
for (var sample = 0; sample < audioData.length; ++sample) {
  var time = sample / 44100;
  audioData[sample] = generateAudioSignal(time);
}

现在将audioData传递给Web Audio API

对于立体声,它可能是

function generateStereoAudioSignal(time) {
   return [Math.sin(time * 4000), Math.sin(time * 4000)]; // generate a 4khz stereo sign wave.
}

var audioData = new Float32Array(44100 * 4 * 2); // 4 seconds of stereo audio at 44.1khz
for (var sample = 0; sample < audioData.length; sample += 2) {
  var time = sample / 44100 / 2;
  var stereoData = generateAudioSignal(time);
  audioData[sample + 0] = stereoData[0];
  audioData[sample + 1] = stereoData[1];
}

他们真的没有理由在WebGL中(假设他们是).在WebGL中,您可以使用它们将数据生成到附加到帧缓冲区的纹理中.然后,他们生成的数据必须从GPU复制回主内存gl.readPixels,然后传递到Web Audio API,这将很慢,至少在WebGL中它会阻止处理,因为没有办法异步读取数据WebGL的.最重要的是,您无法轻松读回WebGL中的浮点数据.当然,如果shadertoy真正使用WebGL,那么它可以重新编写音频着色器以将数据编码为8位RGBA纹理,然后将其转换回JavaScript中的浮点数.更有理由不使用WebGL.使用WebGL的主要原因是它只是使它对称.所有着色器使用相同的语言.

上面链接的bytebeat示例完全在JavaScript中运行.它默认为bytebeat,意味着函数预期返回的值是0到255 unsigned int但是有一个floatbeat的设置,在这种情况下,它需要一个从-1到1的值,就像shadertoy的着色器一样.

更新

所以我检查了Shadertoy它正在使用WebGL着色器,它将值编码为8位纹理

这是一个实际的着色器(我使用chrome着色器编辑器轻松查看着色器).

precision highp float;

uniform float     iChannelTime[4];
uniform float     iBlockOffset; 
uniform vec4      iDate;
uniform float     iSampleRate;
uniform vec3      iChannelResolution[4];
uniform sampler2D iChannel0;
uniform sampler2D iChannel1;
uniform sampler2D iChannel2;
uniform sampler2D iChannel3;

vec2 mainSound( float time )
{
    return vec2( sin(time * 1000.0), sin(time * 1000.0) );
}

void main() {
   // compute time `t` based on the pixel we're about to write
   // the 512.0 means the texture is 512 pixels across so it's
   // using a 2 dimensional texture, 512 samples per row
   float t = iBlockOffset + ((gl_FragCoord.x-0.5) + (gl_FragCoord.y-0.5)*512.0)/iSampleRate;

   // Get the 2 values for left and right channels
   vec2 y = mainSound( t );

   // convert them from -1 to 1 to 0 to 65536
   vec2 v  = floor((0.5+0.5*y)*65536.0);

   // separate them into low and high bytes
   vec2 vl = mod(v,256.0)/255.0;
   vec2 vh = floor(v/256.0)/255.0;

   // write them out where 
   // RED   = channel 0 low byte
   // GREEN = channel 0 high byte
   // BLUE  = channel 1 low byte
   // ALPHA = channel 2 high byte
   gl_FragColor = vec4(vl.x,vh.x,vl.y,vh.y);
}

这指出在这种特殊情况下使用WebGL的一个优点是,您可以获得与片段着色器相同的音频着色器输入(因为它是片段着色器).这意味着例如音频着色器最多可以引用4个纹理

在JavaScript中,然后您将读取纹理,gl.readPixels然后将样本转换回浮点数

   var pixels = new Uint8Array(width * height * 4);
   gl.readPixels(0, 0, width, height, gl.RGBA, gl.UNSIGNED_BYTE, pixels);
   for (var sample = 0; sample < numSamples; ++sample) {
     var offset = sample * 4;  // RGBA
     audioData[sample * 2    ] = backToFloat(pixels[offset + 0], pixels[offset + 1]);
     audioData[sample * 2 + 1] = backToFloat(pixels[offset + 2], pixels[offset + 3]);
   }

   float backToFloat(low, high) {
     // convert back to 0 to 65536
     var value = low + high * 256;

     // convert from 0 to 65536 to -1 to 1
     return value / 32768 - 1;
   } 

此外,虽然我上面说过,但我认为这是一个好主意我认为shadertoy一直在调用音频着色器,因此我提出的关于阻塞处理的问题是正确的,但是......显然,只是预先生成了一个当您按下播放时,使用着色器的N秒音频,其中N显然为60秒.所以,没有阻挡,但声音只持续60秒.