在Phoenix Framework中渲染多对多关系JSON

Question

我有下一个型号

defmodule App.User do
  use App.Web, :model
  alias App.User

  schema "users" do  
    field :name, :string
    has_many :roles_users, App.RolesUser
    has_many :roles, through: [:roles_users, :role]
    timestamps
  end
end 

defmodule App.Role do
  use App.Web, :model

  schema "roles" do
    has_many :roles_users, App.RolesUser
    has_many :users, through: [:roles_users, :user]
    field :name, :string
    timestamps
  end

end

defmodule App.RolesUser do
  use App.Web, :model

  schema "roles_users" do
    belongs_to :role, App.Role
    belongs_to :user, App.User
    timestamps
  end
end

是为了多对多的关系.我要显示的控制器是

def index(conn, _params) do
  users = Repo.all(User)
        |> Repo.preload(:roles)

  render(conn, "index.json", users: users)
end

在我看来

def render("index.json", %{users: users}) do
  %{users: render_many(users, App.UserView, "user.json")}
end

def render("show.json", %{user: user}) do
  %{user: render_one(user, App.UserView, "user.json")}
end

def render("user.json", %{user: user}) do
  %{id: user.id,
    name: user.name,
    roles: user.roles
 }

当我发送GET请求时,我收到了此错误

unable to encode value: {nil, "roles"}

我知道这可能是因为user.roles需要以某种方式格式化解码JSON,但我对此没有任何线索.我在表格中尝试过

def render("user.json", %{user: user}) do
  %{id: user.id,
    name: user.name,
    roles: render_many(roles, App.UserView, "roles.json")
 }

但是没有用.

在视图中渲染多对多关系的最佳方法是什么？

Answer 1

使用render_many/4是正确的.

如果您希望在同一模块中定义"role.json"渲染功能,您可以执行以下操作:

def render("user.json", %{user: user}) do
  %{
    id: user.id,
    name: user.name,
    roles: render_many(user.roles, __MODULE__, "role.json", as: :role)
  }
end

def render("role.json", %{role: role}) do
  %{
    id: role.id
    ... 
  }
end

请注意,我们传递as: :role给render_many函数.这是因为%{role: role}从视图名称推断出分配(部分).在这种情况下,它是UserView那么这将是%{user: user}默认.

如果您定义了一个RoleView模块,那么您可以将该def render("role.json")功能移动到您的新模块RoleView并在render_many没有as选项的情况下调用:

...
roles: render_many(user.roles, MyApp.RoleView, "role.json")
...

您可能更喜欢的另一个选项是在模型中派生协议:

defmodule App.Role do
  use App.Web, :model
  @derive {Poison.Encoder, only: [:id, :name]}

  schema "roles" do
    has_many :roles_users, App.RolesUser
    has_many :users, through: [:roles_users, :user]
    field :name, :string
    timestamps
  end

就个人而言,我认为这会将您的模型与您的视图相结合,所以我更喜欢使用第一个选项.