Oracle:有没有办法获得最近的SQL语法错误？

Question

我们在应用程序日志中看到很多"ORA-00936:缺少表达式"错误.Oracle是否有办法确定哪些语句失败？

我尝试查询v $ sql,但这些语句没有插入到该视图中,因为它们没有通过语法检查.

我们的C#应用​​程序使用Linq生成对Oracle数据库的查询.这使得从应用程序获取sql查询有点困难.我希望我能更容易地从Oracle获得它.

Answer 1

您可以在Oracle中创建一个将记录所有错误的触发器(或几乎所有错误 - NO_DATA_FOUND不被视为错误).在下面的示例中,架构中的任何错误都记录在TRACK_DETAIL表中(一行错误,下一行失败的SQL).您可以使用序列号,日期/时间等使其更复杂.

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

完成后,请记住丢弃(或禁用)触发器.