有monad更优雅代码的提示？

Question

我终于掌握了如何使用monads(不知道我是否理解它们......),但我的代码从来都不是很优雅.我想是因为缺乏对所有这些功能如何Control.Monad真正起作用的把握.所以我认为在使用状态monad的特定代码段中询问关于此的提示会很好.

代码的目标是计算多种随机游走,这是我在更复杂的事情之前尝试做的事情.问题是我同时有两个有状态计算,我想知道如何用优雅组合它们:

1. 更新随机数生成器的函数是类型的 Seed -> (DeltaPosition, Seed)
2. 更新随机游走者位置的功能属于某种类型DeltaPosition -> Position -> (Log, Position)(Log我只能通过某种方式报告随机游走者的当前位置).

我做的是这样的:

我有一个函数来组成这两个有状态的计算:

composing :: (g -> (b, g)) -> (b -> s -> (v,s)) -> (s,g) -> (v, (s, g))
composing generate update (st1, gen1) = let (rnd, gen2) = generate gen1
                                            (val, st2)  = update rnd st1
                                        in (val, (st2, gen2))

然后我把它变成一个组成状态的函数:

stateComposed :: State g b -> (b -> State s v) -> State (s,g) v
stateComposed rndmizer updater = let generate = runState rndmizer
                                     update x = runState $ updater x
                                 in  State $ composing generate update 

然后我有最简单的事情,例如,一个随机数,它只是将一个随机数加到当前位置:

update :: Double -> State Double Double
update x = State (\y -> let z = x+y
                        in  (z,z))

generate :: State StdGen Double
generate = State random

rolling1 = stateComposed generate update 

以及重复执行此操作的功能:

rollingN 1 = liftM (:[]) rolling1
rollingN n = liftM2 (:) rolling1 rollings
    where rollings = rollingN (n-1) 

然后,如果我加载ghci并运行:

*Main> evalState (rollingN 5) (0,mkStdGen 0)
[0.9872770354820595,0.9882724161698186,1.9620425108498993,2.0923229488759123,2.296045158010918]

我得到了我想要的东西,这是随机助行器占据的位置列表.但是......我觉得必须有更优雅的方式来做到这一点.我有两个问题:

1. 我可以使用聪明的函数以更"单一"的方式重写这些函数Control.Monad吗？

2. 是否有关于组合这样的状态的一般模式可以使用？这与monad变形金刚有什么关系吗？

Answer 1

更新:我应该已经提到,实际上有一个更好的方法可以完全不需要State或monad:

takeStep :: (Double, StdGen) -> (Double, StdGen)
takeStep (p, g) = let (d, g') = random g in (p + d, g')

takeSteps n = take n . tail . map fst $ iterate takeStep (0, mkStdGen 0)

它按预期工作:

*Main> takeSteps 5
[0.9872770354820595,0.9882724161698186,1.9620425108498993,2.0923229488759123,2.296045158010918]

如果你没有致力于"编写"两个独立的有状态计算,你可以更直接地完成同样的事情:

takeStep :: State (Double, StdGen) Double
takeStep = do
  (pos, gen) <- get
  let (delta, gen') = random gen
  let pos' = pos + delta
  put (pos', gen')
  return pos'

takeSteps n = evalState (replicateM n takeStep) (0, mkStdGen 0)

这会产生与您的示例相同的输出:

*Main> takeSteps 5
[0.9872770354820595,0.9882724161698186,1.9620425108498993,2.0923229488759123,2.296045158010918]

这种方法(做的所有国家操纵一个单子,而不是试图撰写State A和State B)我看来,像最优雅的解决方案.

更新:回答你关于使用monad变换器堆叠Statemonad的问题:这当然是可能的.我们可以写下面的内容,例如:

update' :: (Monad m) => Double -> StateT Double m Double
update' x = StateT $ \y -> let z = x + y in return (z, z)

generate' :: (Monad m) => StateT StdGen m Double
generate' = StateT $ return . random

takeStep' :: StateT Double (State StdGen) Double
takeStep' = update' =<< lift generate'

takeSteps' n = evalState (evalStateT (replicateM n takeStep') 0) $ mkStdGen 0

我们也可以按相反的顺序进行堆叠.

这个版本再次产生相同的输出,但在我看来,非StateT版本更清晰一点.