Delphi/Firemonkey在运行时更改iOS屏幕旋转

Question

基本上我想要实现的是当用户在应用程序的某个部分根据需要更改屏幕旋转时,我有这个为Andriod工作,我不明白为什么它不应该适用于iOS

procedure TForm1.Button1Click(Sender: TObject);
var
  ScreenService: IFMXScreenService;
  OrientSet: TScreenOrientations;
begin
    if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 
    then
    begin
        OrientSet := [TScreenOrientation.soLandscape];//<- Break point set here and line is executed
        ScreenService.SetScreenOrientation(OrientSet);
    end;
end;

从这里采取:如何在delphi xe5 Firemonkey中使用android开发防止屏幕旋转

ScreenService.SetScreenOrientation已执行且不会引发异常,但方向未更改,我还在Project> Options> Application> Orientation中设置了Enable custom orientation,但这也没有任何效果.

对我来说奇怪的是,如果不支持,那么不应该这样

if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 

回报错误？甚至没有进入开始

我添加了一个测试按钮来检查屏幕方向后,我将其设置为横向

if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 
then
begin
    case ScreenService.GetScreenOrientation of
        TScreenOrientation.Portrait: ShowMessage('Portrait');
        TScreenOrientation.Landscape: ShowMessage('landscape');
        TScreenOrientation.InvertedPortrait: ShowMessage('Inverted-Portrait');
        TScreenOrientation.InvertedLandscape: ShowMessage('Inverted-Landscape');
        else ShowMessage('not set');
    end;
end;

如果在将它设置为横向之后它在纵向中,它仍然会说肖像

更新1:我也试过改变

OrientSet := [TScreenOrientation.soLandscape] // <- Deprecated

至

OrientSet := [TScreenOrientation.Landscape]

但行为仍然是一样的

Answer 1

好的,这次轮换让我深入研究iOS API,以了解iOS如何管理方向.

因为您无法在iOS中的iOS中伪造旋转或强制设备某些设备方向,所以您需要考虑很多方向

• 设备方向
• 状态栏方向
• UIViewcontroller方向

无法强制或更改设备方向,这将始终显示设备现在的方向.

然而,状态栏方向始终具有setStatusBarOrientation您可以调用的程序并且指定您想要的方向,但是这被标记为已弃用,因此无效,但是当我调用该函数时,我没有得到外部异常,它还在那里,它只是没有用.

然后我读到了这个:

setStatusBarOrientation:animated:方法不会被完全弃用.现在,只有当最顶层的全屏视图控制器的supportedInterfaceOrientations方法返回0时,它才有效

然后我决定尝试这个

Application.FormFactor.Orientations := []; //the supportedInterfaceOrientations returns 0
App := TUIApplication.Wrap(TUIApplication.OCClass.sharedApplication);
win := TUIWindow.Wrap(App.windows.objectAtIndex(0));
App.setStatusBarOrientation(UIInterfaceOrientationLandscapeLeft);

并且它适用于状态栏方向更改,但如上所述,此协议已弃用,因此在某个阶段它可能/将会消失,这将不再起作用.

但是这只改变了状态栏和所有警报视图等的旋转,但是在我想要更改为横向的情况下,rootviewcontroller中的实际内容仍然在肖像中.

然后,如果我想在Delphi中转到Application-> Orientation->启用自定义旋转并说景观,那么App只会以横向显示,并且它完美地完成,因为在创建表单然后rootViewcontroller成为supportedInterface返回的方向只是横向,Viewcontroller转到Landscape.

因为当您的设备更改设备方向时,将根据Viewcontroller支持的接口方向评估方向,如果不支持方向,则不会旋转方向.

但是当分配新的rootviewcontroller时,必须更新GUI以在Viewcontrollers支持的方向中显示,考虑到这一点,这是我的修复/黑客将应用程序的方向更改为您想要的方向.

TL; DR

Uses: iOSapi.UIKit; 

procedure ChangeiOSorientation(toOrientation: UIInterfaceOrientation;
possibleOrientations: TScreenOrientations);
var
    win : UIWindow;
    App : UIApplication;
    viewController : UIViewController;
    oucon: UIViewController;
begin
    Application.FormFactor.Orientations := []; //Change supported orientations
    App := TUIApplication.Wrap(TUIApplication.OCClass.sharedApplication);
    win := TUIWindow.Wrap(App.windows.objectAtIndex(0)); //The first Windows is always the main Window

    App.setStatusBarOrientation(toOrientation);
    {After you have changed your statusbar orientation set the
    Supported orientation/orientations to whatever you need}
    Application.FormFactor.Orientations := possibleOrientations;
    viewController := TUIViewController.Wrap(TUIViewController.alloc.init);//dummy ViewController
    oucon := TUIViewController.Wrap(TUIViewController.alloc.init);
    {Now we are creating a new Viewcontroller now when it is created
     it will have to check what is the supported orientations}
    oucon := win.rootViewController;//we store all our current content to the new ViewController
    Win.setRootViewController(viewController);
    Win.makeKeyAndVisible;// We display the Dummy viewcontroller

    win.setRootViewController(oucon);
    win.makeKeyAndVisible; 
    {And now we Display our original Content in a new Viewcontroller 
     with our new Supported orientations} 
end;

你现在所要​​做的就是打电话 ChangeiOSorientation(toOrientation,possibleOrientations)

如果您想要它去Portrait,但可以选择横向

 ChangeiOSorientation(UIInterfaceOrientationPortrait,[TScreenOrientation.Portrait,TScreenOrientation.Landscape,TScreenOrientation.InvertedLandscape]);    

这是在努力

• 德尔福10西雅图
• iPhone 5运行iOS 9.0
• PA服务器17.0
• Xcode 7.1
• iPhoneOS 9.1 SDK