Clojure交换原子与地图值

Question

我想将assoc地图的值添加到atom.我可以这样做:

  (defonce config (atom {}))
  (swap! config assoc :a "Aaa")
  (swap! config assoc :b "Bbb")

但这是重复的,并拨打了几个电话swap!.我想做那样的事情:

(swap! config assoc  {:a "Aaa"
                      :b "Bbb"})
;; this doesn't work :
;; Exception in thread "main" clojure.lang.ArityException: Wrong number of args (2) passed to: core$assoc

我怎么做 ？

Answer 1

请参阅以下文档assoc:

=> (doc assoc)
-------------------------
clojure.core/assoc
([map key val] [map key val & kvs])
  assoc[iate]. When applied to a map, returns a new map of the
    same (hashed/sorted) type, that contains the mapping of key(s) to
    val(s). When applied to a vector, returns a new vector that
    contains val at index. Note - index must be <= (count vector).
nil

assoc不拿地图.它需要成对的键和值:

user=> (assoc {} :a 1 :b 2)
{:a 1, :b 2}
user=> (let [x (atom {})]
                    #_=> (swap! x assoc :a 1 :b 2)
                    #_=> x)
#object[clojure.lang.Atom 0x227513c5 {:status :ready, :val {:a 1, :b 2}}]

顺便说一句,您应该始终将您对原子的更新隔离为单个swap!.通过如上所述进行两次交换,您允许其他线程潜在地破坏引用的数据.单一swap!保持一切原子.

NB merge表现得像你想象的那样:

user=> (merge {} {:a 1 :b 1})
{:a 1, :b 1}
user=> (let [x (atom {})]
                    #_=> (swap! x merge {:a 1 :b 2})
                    #_=> x)
#object[clojure.lang.Atom 0x1be09e1b {:status :ready, :val {:a 1, :b 2}}]