从 Excel 超链接公式中提取 URL

Question

我有一个 Excel 文件，其中包含数百个使用超链接公式的单元格=HYPERLINK( <targetURL>, <friendlyName> )。我需要从这些中提取纯文本 URL。我发现的大多数示例都依赖于使用不同超链接方法的单元格。

所以一个这样的函数：

Function HyperLinkText(pRange As Range) As String

   Dim ST1 As String
   Dim ST2 As String

   If pRange.Hyperlinks.Count = 0 Then
      HyperLinkText = "not found"
      Exit Function
   End If

   ST1 = pRange.Hyperlinks(1).Address
   ST2 = pRange.Hyperlinks(1).SubAddress

   If ST2 <> "" Then
      ST1 = "[" & ST1 & "]" & ST2
   End If

   HyperLinkText = ST1

End Function

导致单元格文本“未找到”。或者，有没有办法将这些单元格转换为其他超链接格式，以便我拥有的宏可以工作？

Answer 1

下面的方法将返回超链接文本，无论它是由公式还是由插入/超链接方法创建的。

如果是前者，我们只需要解析公式即可；如果是后者，我们需要迭代工作表上的超链接集合。

如果 cell_ref 中没有超链接，则该公式不会返回任何内容；改变以适应。

Option Explicit
Function HyperLinkText(rg As Range)
    Dim sFormula As String, S As String
    Dim L As Long
    Dim H As Hyperlink, HS As Hyperlinks

sFormula = rg.Formula
L = InStr(1, sFormula, "HYPERLINK(""", vbBinaryCompare)

If L > 0 Then
    S = Mid(sFormula, L + 11)
    S = Left(S, InStr(S, """") - 1)
Else
    Set HS = rg.Worksheet.Hyperlinks
    For Each H In HS
        If H.Range = rg Then
            S = H.Address
        End If
    Next H
End If

HyperLinkText = S

End Function