如何在Cortex-M4 MCU上捕获和查看ITM跟踪信息？

Question

我想捕获,解码和查看Cortex-M4 MCU(在我的例子中是Atmel SAM4S)的ITM跟踪信息.特别是,我想捕获与我板上其他信号相关的异常和用户跟踪数据(即在同一时间线上显示所有信号和跟踪信息).

Answer 1

这可以使用以下步骤完成:

1. 将调试器置于SWD模式.如果在Linux上使用J-Link Segger,可以使用JLinkGDBServer -if swd
2. 将代码添加到MCU以启用跟踪.将比特率设置为适合您需要的值(我使用8 MHz).示例Ada代码如下.
3. 使用逻辑分析仪从SAM4S处理器捕获TRACESWO线上的跟踪数据.我使用了Saleae Logic Pro 16,采样率为100 MHz.

4. 将数据转换为sigrok可用的格式.使用Saleae捕获数据,包括以下步骤:

   • 仅使用前8个通道进行捕获(因此每个样本输出一个字节).
   • 将数据导出为二进制trace.bin,为每个样本写入一个字节.

   • 使用以下命令转换为trace.sr文件:

     sigrok-cli -i trace.bin -I binary:samplerate=100000000,numchannels=4 -o trace.sr

5. trace.sr在PulseView中打开文件.
6. 将UART解码器添加到TRACESWO通道,比特率8000000.
7. 堆栈ARM-ITM解码器.

有关更多信息,请参见http://www.sigrok.org/blog/new-protocol-decoders-arm-tpiu-itm-etmv3.

SAM4S跟踪的示例Ada代码:

sam4s-trace.ads:

with Interfaces;

package SAM4S.Trace is
   pragma Preelaborate;

   type Channel_Type is new Integer range 0 .. 31;
   type Value_Type is new Interfaces.Unsigned_32;

   procedure Initialize;

   procedure Put (Channel : Channel_Type;
                  Value   : Value_Type);

   procedure Put (Channel : Channel_Type;
                  Message : String);
end SAM4S.Trace;

SAM4S-trace.adb:

with System;
with System.Storage_Elements; use System.Storage_Elements;

package body SAM4S.Trace is
   procedure Initialize is
      ITM_LAR : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E000_0FB0#), Volatile;

      ITM_TCR : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E000_0E80#), Volatile;

      ITM_TER : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E000_0E00#), Volatile;

      ITM_TPR : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E000_0E40#), Volatile;

      DEMR : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E000_EDFC#), Volatile;

      TPIU_SPP : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E004_00F0#), Volatile;

      TPIU_FFCR : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E004_0304#), Volatile;

      TPIU_ACPR : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E004_0010#), Volatile;

      DWT_CTRL : Interfaces.Unsigned_32
        with Address => System'To_Address (16#E000_1000#), Volatile;

      use Interfaces;

   begin
      --  Enable write access via the Lock Access Register.
      ITM_LAR := 16#C5AC_CE55#;
      --  Enable the ITM, enable SWO mode behavior, enable synchronization
      --  packets, enable DWT event submission, enable timestamps.
      ITM_TCR := 16#0001_001F#;
      --  Enable access in user mode to all 32 channels.
      ITM_TPR := 16#0000_0000#;
      --  Enable all 32 trace channels.
      ITM_TER := 16#FFFF_FFFF#;

      --  Set TRCENA bit to 1 in Debug Exception and Monitor Register.
      DEMR := DEMR or 16#0100_0000#;

      --  Select NRZ serial wire output.
      TPIU_SPP := 16#0000_0002#;

      --  Deactivate formatter.
      TPIU_FFCR := 16#0000_0100#;

      --  Set prescalar (/10).
      --  TPIU_ACPR := 16#0000_0009#;

      --  Set prescalar (/15).
      TPIU_ACPR := 14;

      --  Enable exception trace and exception overhead.
      DWT_CTRL := DWT_CTRL or 16#0005_0000#;

   end Initialize;

   procedure Put (Channel : Channel_Type;
                  Value   : Value_Type) is
      Port_Reg : Value_Type with Address => System'To_Address (16#E000_0000#) +
        4 * Channel_Type'Pos (Channel), Volatile;
   begin
      --  Port register lsb is set when the the FIFO can accept at least one
      --  word.
      while Port_Reg = 0 loop
         null;
      end loop;
      Port_Reg := Value;
   end Put;

   procedure Put (Channel : Channel_Type;
                  Message : String) is
      Port_Reg : Value_Type with Address => System'To_Address (16#E000_0000#) +
        4 * Channel_Type'Pos (Channel), Volatile;
   begin
      --  Port register lsb is set when the the FIFO can accept at least one
      --  word.
      for Index in Message'Range loop
         while Port_Reg = 0 loop
            null;
         end loop;
         Port_Reg := Value_Type (Character'Pos (Message (Index)));
      end loop;
   end Put;

end SAM4S.Trace;

Answer 2

当你用"逻辑分析仪"标记它时,这可能是偏离主题的,但我发现以下内容非常有用.使用Keil uVision(以及可能还有其他IDE),您可以使用自定义.ini文件将ITM数据重新路由到文件.

在调试器中启用SWJ,使用SW端口.启用跟踪,启用您要使用的激励端口.

写一个.ini文件,其内容如下:

ITMLOG 0 > "debug.log"
ITMLOG 1 > "testlog.xml"

这将把ITM通道0重新路由到名为"debug.log"的文件,将通道1重新路由到"testlog.xml"(此处的文件语法).

要在c代码中使用fprinf轻松使用通道,我使用以下设置:

struct __FILE { int channel; };
#include <stdio.h>

#define ITM_Port8(n)    (*((volatile unsigned char *)(0xE0000000+4*n)))
#define ITM_Port16(n)   (*((volatile unsigned short*)(0xE0000000+4*n)))
#define ITM_Port32(n)   (*((volatile unsigned long *)(0xE0000000+4*n)))

#define DEMCR           (*((volatile unsigned long *)(0xE000EDFC)))
#define TRCENA          0x01000000

int fputc(int ch, FILE *f) {
  if (DEMCR & TRCENA) {
    while (ITM_Port32(f->channel) == 0);
    ITM_Port8(f->channel) = ch;
  }
  return(ch);
}

并在项目中使用:

FILE debug_stream = { .channel = 0 };
FILE test_stream = { .channel = 1 };

int main(void) {
    fprinf(&debug_stream, "this is a debug message, it will be rerouted to debug.log");
    fprinf(&test_stream, "this is a test message, it will be placed in testlog.xml");
}

参考:链接