如何在Clojure中为函数参数创建默认值

Question

我来这个:

(defn string->integer [str & [base]]
  (Integer/parseInt str (if (nil? base) 10 base)))

(string->integer "10")
(string->integer "FF" 16)

但它必须是一个更好的方法来做到这一点.

Answer 1

如果签名在arity中不同,则函数可以具有多个签名.您可以使用它来提供默认值.

(defn string->integer 
  ([s] (string->integer s 10))
  ([s base] (Integer/parseInt s base)))

请注意,假设false和nil都被视为非值,(if (nil? base) 10 base)可以缩短为(if base base 10)或进一步缩短(or base 10).

Answer 2

rest从Clojure 1.2 [ ref ] 开始,您还可以将参数解构为地图.这允许您为函数参数命名并提供默认值:

(defn string->integer [s & {:keys [base] :or {base 10}}]
    (Integer/parseInt s base))

现在你可以打电话了

(string->integer "11")
=> 11

要么

(string->integer "11" :base 8)
=> 9

你可以在这里看到这个:https://github.com/Raynes/clavatar/blob/master/src/clavatar/core.clj(例如)

Answer 3

这种解决方案更接近原始解决方案的精神,但略微清洁

(defn string->integer [str & [base]]
  (Integer/parseInt str (or base 10)))

甲类似的模式,其可以方便的使用or与结合let

(defn string->integer [str & [base]]
  (let [base (or base 10)]
    (Integer/parseInt str base)))

虽然在这种情况下更详细,但如果您希望默认值依赖于其他输入值,则可能很有用.例如,请考虑以下功能:

(defn exemplar [a & [b c]]
  (let [b (or b 5)
        c (or c (* 7 b))]
    ;; or whatever yer actual code might be...
    (println a b c)))

(exemplar 3) => 3 5 35

这种方法可以很容易地扩展到使用命名参数(如在M. Gilliar的解决方案中):

(defn exemplar [a & {:keys [b c]}]
  (let [b (or b 5)
        c (or c (* 7 b))]
    (println a b c)))

或者使用更多的融合:

(defn exemplar [a & {:keys [b c] :or {b 5}}]
  (let [c (or c (* 7 b))]
    (println a b c)))

Answer 4

您可能还需要考虑另一种方法:部分功能.这些可以说是一种更"功能",更灵活的方式来指定函数的默认值.

首先创建(如果需要)一个函数,该函数具有您要提供的参数作为默认值作为前导参数:

(defn string->integer [base str]
  (Integer/parseInt str base))

这样做是因为Clojure的版本partial允许您仅按照它们在函数定义中出现的顺序提供"默认"值.根据需要对参数进行排序后,您可以使用以下partial函数创建函数的"默认"版本:

(partial string->integer 10)

为了使这个函数可以多次调用,你可以使用以下函数将它放在var中def:

(def decimal (partial string->integer 10))
(decimal "10")
;10

您还可以使用let以下方法创建"本地默认值" :

(let [hex (partial string->integer 16)]
  (* (hex "FF") (hex "AA")))
;43350

部分函数方法比其他方法具有一个关键优势:函数的使用者仍然可以决定默认值而不是函数的生成者,而无需修改函数定义.在示例中说明了这一点hex,我已经确定默认函数decimal不是我想要的.

此方法的另一个优点是您可以为默认函数指定一个不同的名称(十进制,十六进制等),这可能更具描述性和/或不同的范围(var,local).如果需要,部分函数也可以与上面的一些方法混合使用:

(defn string->integer 
  ([s] (string->integer s 10))
  ([base s] (Integer/parseInt s base)))

(def hex (partial string->integer 16))

(请注意,这与Brian的答案略有不同,因为参数的顺序已被颠倒,原因在此响应的顶部给出)

Answer 5

您也可以查看(fnil) https://clojuredocs.org/clojure.core/fnil