Delphi Rest.JSON JsonToObject仅适用于f变量

Question

我正在使用Delphi XE8.

我只是看REST.Json ObjectToJsonString()和JsonToObject()电话.

主要是尝试做这样的事情:

如何将对象转换为JSON并返回一行代码

我注意到,当他们开始使用F角色时,我只能让变量工作.我找不到任何关于此的文件.这是预期的行为吗？我应该F在开始时使用a命名我的类中的所有变量吗？如果是,有人可以解释原因吗？

我创建了一个类TTestJSON并定义了两个成员变量并将它们设置为'WORKS'和'FAILS'.

然后我从对象创建了一个JSON字符串值:

{
  "varThatWorksBeacuseItStartsWithF":"WORKS",
  "sVarThatFailsBecauseItStartsWithS":"FAILS"
} 

从JSON字符串返回到对象时,只有fVarThatWorksBeacuseItStartsWithF正确地重置变量.在下面的代码中,test := TJson.JsonToObject<TTestJSON>(JsonStr);使用上面的JSON,注意sVarThatFailsBecauseItStartsWithS是""和否"FAILS".

procedure TForm3.btn1Click(Sender: TObject);
var
  test : TTestJSON;
  JsonStr : String;
begin
  m1.Clear;
  test := TTestJSON.Create;
  try
    test.fVarThatWorksBeacuseItStartsWithF := 'WORKS';
    test.sVarThatFailsBecauseItStartsWithS := 'FAILS';
    JsonStr := TJson.ObjectToJsonString( test );
  finally
    test.Free;
  end;
  m1.Lines.Add(  '** JSONStr Value START **' + #13#10 + JsonStr + '** JSONStr Value END **' + #13#10 );

  test := TJson.JsonToObject<TTestJSON>(JsonStr);
  try
    m1.Lines.Add('** Obj loaded from JSON String Start **' + #13#10 + TJson.ObjectToJsonString( test ) + #13#10 + '** Obj loaded from JSON String End **');
  finally
    test.Free;
  end;
end;

从结果开始,var开头的var f已经f从JSON字符串中删除了,而那个以jSON字符串开头的那个字符串s仍然存在.我原以为第二个结果会是这样的:

{
  "varThatWorksBeacuseItStartsWithF":"WORKS",
  "sVarThatFailsBecauseItStartsWithS":"FAILS"
}

以下是重现的完整代码 - 只需在vcl表单上有一个按钮和一个备忘录 - 也使用REST.Json:

unit Main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, rest.Json;

type
  TTestJSON = class
    fVarThatWorksBeacuseItStartsWithF : String;
    sVarThatFailsBecauseItStartsWithS : String;
  end;

  TForm3 = class(TForm)
    btn1: TButton;
    m1: TMemo;
    procedure btn1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form3: TForm3;

implementation

{$R *.dfm}

procedure TForm3.btn1Click(Sender: TObject);
var
  test : TTestJSON;
  JsonStr : String;
begin
  m1.Clear;
  test := TTestJSON.Create;
  try
    test.fVarThatWorksBeacuseItStartsWithF := 'WORKS';
    test.sVarThatFailsBecauseItStartsWithS := 'FAILS';
    JsonStr := TJson.ObjectToJsonString( test );
  finally
    test.Free;
  end;
  m1.Lines.Add(  '** JSONStr Value START **' + #13#10 + JsonStr + '** JSONStr Value END **' + #13#10 );

  test := TJson.JsonToObject<TTestJSON>(JsonStr);
  try
    m1.Lines.Add('** Obj loaded from JSON String Start **' + #13#10 + TJson.ObjectToJsonString( test ) + #13#10 + '** Obj loaded from JSON String End **');
  finally
    test.Free;
  end;
end;

end.

Answer 1

该库序列化字段。由于通常的做法是用字母F前缀字段，因此设计人员希望从JSON中使用的名称中删除该字母。因此，他们决定采用默认行为，即删除名称以F开头的字段中的第一个字母。坦白说，这对我来说似乎很奇怪。

可以使用属性来自定义此行为。例如：

[JSONMarshalled(False)]
FFoo: Integer; 

[JSONMarshalled(True)]
[JSONName('Blah')]
Bar: Integer;

据我所知，这些都没有正确记录。

Answer 2

Delphi中的JSON序列化基于字段,而不是属性.但是大多数Delphi类都有友好属性和F前缀字段.同时,Emb似乎试图避免生成的JSON中的F前缀名称.在序列化字段时,它们从名称中删除了第一个"F",并在从JSON读取时将其添加回(以查找正确的字段).似乎在Delphi中使用JSON序列化的唯一(安全)方法是保留所有字段名称前缀为"F"(对于要序列化的字段):

TTestJSON = class
protected
  FName: String;
public
  property Name: String read FName write FName;
end;

更新2:正如大卫提到的,我们可以使用属性,然后我们可以更好地控制:

uses
  REST.Json.Types, // without this unit we get warning: W1025 Unsupported language feature: 'custom attribute'
  REST.Json;

type
  // All fields of records are serialized, no control here.
  TRec = record
    RecStr: String;
  end;

  // By default all fields of class are serialized, but only F-prefixed serialized correctly.
  // We can use JSONMarshalled attribute to enable/disable serialization.
  // We can use JSonName attribute to serialize field with specific name in JSON.
  TTestJSON = class
    [JSONMarshalled(True)] [JSonName('RecField')]
    R: TRec;
  end;

procedure TForm28.FormCreate(Sender: TObject);
var
  Test: TTestJSON;
  JsonStr: string;
begin
  Test := TTestJSON.Create;
  try
    Test.R.RecStr := 'Some str';
    JsonStr := TJson.ObjectToJsonString( Test );
  finally
    FreeAndNil(Test);
  end;

  // JsonStr: {"RecField":["Some str"]}

  Test := TJson.JsonToObject<TTestJSON>(JsonStr);
  FreeAndNil(Test);
end;