enumFromTo如何工作？

Question

我无法添加一个数字Char; 以下将无法编译'a' + 1.但是,['a'..'z']成功创建了一个字符串,其中每个字符值都会递增.有一个特殊的功能,可以增加一个Char？

我知道我能做到chr (ord c + 1).

['a'..'z']或者底层enumFromTo函数如何增加结果中的字符String？

Answer 1

是的,有一个特殊的函数可以添加到Char来自同一个Enum类的enumFromTo名称succ.请注意它是部分的:succ maxBound未定义,因此在应用之前请注意检查字符的值succ.succ确实是相同的\c -> chr (ord c + 1),因为您可以使用universe包验证:

> let avoidMaxBound f x = if x == maxBound then Nothing else Just (f x)
> avoidMaxBound succ == avoidMaxBound (\c -> chr (ord c + 1))
True

实际上GHC的实现与succ你建议的功能非常接近:

instance  Enum Char  where
    succ (C# c#)
       | isTrue# (ord# c# /=# 0x10FFFF#) = C# (chr# (ord# c# +# 1#))
       | otherwise             = error ("Prelude.Enum.Char.succ: bad argument")

但是,在GHC succ的实施中没有使用enumFromTo:

instance  Enum Char  where
    {-# INLINE enumFromTo #-}
    enumFromTo (C# x) (C# y) = eftChar (ord# x) (ord# y)
{-# RULES
"eftChar"       [~1] forall x y.        eftChar x y       = build (\c n -> eftCharFB c n x y)
#-}

-- We can do better than for Ints because we don't
-- have hassles about arithmetic overflow at maxBound
{-# INLINE [0] eftCharFB #-}
eftCharFB :: (Char -> a -> a) -> a -> Int# -> Int# -> a
eftCharFB c n x0 y = go x0
                 where
                    go x | isTrue# (x ># y) = n
                         | otherwise        = C# (chr# x) `c` go (x +# 1#)

{-# NOINLINE [1] eftChar #-}
eftChar :: Int# -> Int# -> String
eftChar x y | isTrue# (x ># y ) = []
            | otherwise         = C# (chr# x) : eftChar (x +# 1#) y

如果你可以忽略主要出于效率原因存在的肮脏,你可以看到它eftChar本质上是使用succ,但它的内联版本而不是实际调用succ(这里,以避免拳击和重新装箱Char被操纵).