如何使用CMake将子目录安装到不同位置？

Question

我有几个 CMake 项目，它们定义了自己的安装逻辑。现在，我想添加一个全局 CMakeLists.txt，它添加了这些项目，add_subdirectory()以便一次性构建和安装所有项目。我怎样才能${CMAKE_INSTALL_PREFIX}从外部为他们每个人提供不同的东西？

我尝试的是更改调用之间的安装前缀以添加子目录，但它们是在实际调用时安装的make install，当时安装前缀已设置为最后分配的值。

Answer 1

如果您的子项目需要相同的变量具有不同的值（在全局范围内），则您无法add_subdirectory在单个全局项目中使用它们来构建它们。

相反，全局项目可以使用cmake调用 viaexecute_process或 来安装它们ExternalProject_Add。有时，install(SCRIPT)可以使用命令来实现此目的。

安装使用execute_process使子项目在阶段立即可用configuration。

当子项目具有某种打包机制时可以使用它（请参阅有关打包的 CMake 教程），因此全局对象可以 find_package(<subproject-name>)以最简单的方式执行并与子项目中定义的库链接（使用变量，在外部填充）。

# Configure subproject into <subproject-build-dir>
execute_process(COMMAND ${CMAKE_COMMAND} -D<var>=<value> <subproject-source-dir> 
    WORKING_DIRECTORY <subproject-build-dir>)
# Build and install subproject
execute_process(COMMAND ${CMAKE_COMMAND} --build <subproject-build-dir> --target install)
# Extract variables, related to subproject for link with it.
find_package(<subproject-name>)

# Create target in global project and link with subproject
include_directories(${<subproject-name>_INCLUDE_DIRS})
link_directories(${<subproject-name>_LIBRARY_DIRS})
add_executable(global_program main.cpp)
target_link_libraries(global_program ${<subproject-name>_LIBRARIES})

安装使用将ExternalProject_add目标分配给子项目，该子项目将在build阶段安装。在这种情况下与子项目链接也是可能的，但需要手动填充变量。

# Configure, build and install subproject
ExternalProject_Add(<subproject_target>
    SOURCE_DIR <subproject-source-dir>
    CMAKE_CACHE_ARGS -D<var>=<value>
    BINARY_DIR <subproject-build-dir>
    INSTALL_DIR <CMAKE_INSTALL_PREFIX-for-subproject>
    )

# Create target in global project and link with subproject
include_directories(<subproject-include-files-location>)
link_directories(<subproject-libraries-location>)
add_executable(global_program main.cpp)
target_link_libraries(global_program <subproject-libraries-name>)
# Make sure that subproject will be built before executable.
add_dependencies(global_program <subproject_target>)

使用install(SCRIPT)在阶段执行脚本进行安装install。当全局项目和子项目之间不存在构建依赖关系时，可以使用此方法。

子项目_install.cmake：

# Configure subproject into <subproject-build-dir>
execute_process(COMMAND ${CMAKE_COMMAND} -D<var>=<value> <subproject-source-dir> 
    WORKING_DIRECTORY <subproject-build-dir>)
# Build and install subproject
execute_process(COMMAND ${CMAKE_COMMAND} --build <subproject-build-dir> --target install)

CMakeLists.txt：

install(SCRIPT subproject_install.cmake)