如何用逗号代替小数点来解析浮点数？

Question

我想Float从使用逗号作为小数分隔符存储它们的文件中解析值.因此,我需要一个功能myParse :: String -> Float,例如,myParse "23,46" == 23.46.

我有一些关于如何做到这一点的想法,但它们似乎都过于复杂,例如:

• 用字符串中的,a 替换.并使用read; 要么
• 按照这个FP完整博客文章(名为Parsing Floats With Parsec),挑战单态限制的诅咒.

有更简单的方法,还是我真的需要使用解析库？在第二种情况下,你可以粘贴一些建议,以便让我开始吗？单态限制让我感到害怕,我相信必须有一种方法可以在不使用语言扩展的情况下完成此操作.

Answer 1

更换,由.然后调用read足够简单; 你只需要记住使用你自己的专用函数而不是普通的旧函数read:

readFloatWithComma :: String -> Float
readFloatWithComma = read . sanitize
  where
    sanitize = map (\c -> if c == ',' then '.' else c)

在GHCi中:

?> readFloatWithComma "23,46"
23.46

关于这种parsec方法,尽管您链接的文章提出了建议,但只要您拥有所有顶级绑定的类型签名,单一性限制就不必担心了.特别是,以下代码不需要任何语言扩展来正确编译(至少在GHC 7.10.1中):

import Text.Parsec
import Text.Parsec.String         ( Parser )
import Control.Applicative hiding ( (<|>) )

infixr 5 <++>
(<++>) :: Applicative f => f [a] -> f [a] -> f [a]
a <++> b = (++) <$> a <*> b

infixr 5 <:>
(<:>) :: Applicative f => f a -> f [a] -> f [a]
a <:>  b = (:) <$> a <*> b

number :: Parser String
number = many1 digit

plus :: Parser String
plus = char '+' *> number

minus :: Parser String
minus = char '-' <:> number

integer :: Parser String
integer = plus <|> minus <|> number

float :: Parser Float
float = fmap rd $ integer <++> decimal <++> exponent
    where rd       = read :: String -> Float
          decimal  = option "" $ ('.' <$ char ',') <:> number
          exponent = option "" $ oneOf "eE" <:> integer

在GHCi中:

?> parseTest float "23,46"
23.46