如何使用sqlcmd在批处理文件中显示进度？

Question

我正在使用sqlcmd(sqlcmd引用)在dos批处理文件(而不是PowerShell)中备份大型数据库.大约需要30分钟.

sqlcmd -S 127.0.0.1 -d DbNameHere -E -Q "BACKUP DATABASE [DbNameHere] TO DISK = N'c:\Temp\MyBackup.bak' WITH COPY_ONLY, NOFORMAT, INIT, NAME = N'My Full Database Backup', SKIP, NOREWIND, NOUNLOAD, STATS = 10"

如果在SQL Management Studio中运行BACKUP命令,则会获得输出:

10 percent processed.
20 percent processed.
...

在DOS批处理中,充其量,当备份完成时,我将所有10,20,30..100全部出现在屏幕上.

我试过玩这些参数,但我仍然没有在屏幕上获得所需的进度更新:

-m-1
-V 1
-r1

这些进度消息是缓冲的,这可能是问题的一部分.这里有例如:如何在TSQL中刷新PRINT缓冲区？ 但我有一个长时间运行的命令,而不是多个命令.

您可以在其他地方运行单独的SQL语句,它会告诉您进度甚至估计的完成时间:

SELECT session_id as SPID, command, a.text AS Query, start_time, percent_complete, dateadd(second,estimated_completion_time/1000, getdate()) as estimated_completion_time 
FROM sys.dm_exec_requests r CROSS APPLY sys.dm_exec_sql_text(r.sql_handle) a 
WHERE r.command in ('BACKUP DATABASE','RESTORE DATABASE')

但要使用它,我将不得不创建第二个批处理文件(sqlcmd执行此语句),在运行sqlcmd备份之前在新窗口中打开它,并在1分钟计时器上循环运行它,并且备份完成后结束它.所有这些都是批量的.理想情况下,我宁愿将它全部保存在一个批处理文件中!输出标准进度消息会简单得多!

有任何想法吗？

Answer 1

我想出了一种解决方案。缺点是它涉及第二个批处理文件。它基本上启动一个具有给定名称的进度窗口。该进度窗口会定期刷新。主进程完成后，它会taskkill使用给定的名称进行调用。进度批次依赖timeout. 两者都在我的 Windows 8 工作站以及 2008 R2 和 2012 服务器上。

主要备份批次：

@echo off
rem lots of other lines in my main batch file here

start "BACKUP_PROGRESS" /belownormal cmd /d /c "backup_progress2.cmd"

sqlcmd -S 127.0.0.1 -d DBNameHere-E -Q "BACKUP DATABASE [DBNameHere] TO DISK = N'c:\Temp\DBNameHere.bak' WITH COPY_ONLY, NOFORMAT, INIT, NAME = N'DBNameHere-Full Database Backup', SKIP, NOREWIND, NOUNLOAD, STATS = 10"

taskkill /FI "WINDOWTITLE eq BACKUP_PROGRESS" /F > nul

rem my main batch file continues here with lots of other lines

进度批处理文件（backup_progress2.cmd在主批处理中调用）。这setlocal enableextensions enabledelayedexpansion只是为了让我可以使用 以秒为单位显示时间!time!。

@echo off
rem http://stackoverflow.com/questions/21434982/windows-batch-scripting-catch-user-reaction-to-timeout-command
SET timeout=60

:loop
cls
setlocal enableextensions enabledelayedexpansion
echo.
echo Time now: !time!
echo.
endlocal
sqlcmd -S 127.0.0.1 -d DBNameHere -E -Q "SET NOCOUNT ON;SELECT start_time,cast(percent_complete as int) as progress,dateadd(second,estimated_completion_time/1000, getdate()) as estimated_completion_time, cast(estimated_completion_time/1000/60 as int) as minutes_left FROM sys.dm_exec_requests r WHERE r.command='BACKUP DATABASE'"
echo.
echo Refreshing every %timeout% seconds.
timeout %timeout% > nul
goto loop