将用户名和密码存储在数据库中是否安全？

Question

我有人在一个部落中提交用户名和密码,我需要知道使用此代码将其提交到数据库中是否安全,或者它是否在数据库中是安全的.

MySQLCon.Open()
Dim SQLADD As String = "INSERT INTO members(username,password) VALUES(@memberToAdd, @memberPassword)"
COMMAND = New MySqlCommand(SQLADD, MySQLCon)
COMMAND.Parameters.AddWithValue("@memberToAdd", memberToAdd.Text)
COMMAND.Parameters.AddWithValue("@memberPassword", membersPassword.Text)
COMMAND.ExecuteNonQuery()
MySQLCon.Close()
MySQLCon.Dispose()

我使用参数来避免SQL注入攻击.

-------------------------------------------------- --------------------------------

这不是重复,因为它以不同的方式询问和存储密码.它使用MD5来散列密码.

Answer 1

使用基本安全措施存储密码的过程非常简单:

• 用盐哈希密码
• 为每个用户/密码使用不同的盐
• 将带有散列密码的salt存储在DB中
• 当他们尝试登录时,通过相同的方法运行尝试的PW; 比较结果.

如果输入正确的密码,则哈希的PW将匹配.Hashing可以保护用户免受攻击,以及看门人在屏幕上行走,同时members显示桌面.

创造盐和哈希PW

' salt size is 32 (0-31
Private Const SaltSize As Integer = 31
...

Dim dbPW As String = TextBox1.Text
Dim dbSalt = CreateNewSalt(SaltSize)
' eg: "dsEGWpJpwfAOvdRZyUo9rA=="

Dim SaltedPWHash As String = GetSaltedHash(dbPW, dbSalt)
' examples:
' using SHA256: bbKN8wYYgoZmNaG3IsQ2DPS2ZPIOnenl6i5NwUmrGmo=
' using SHA512: 
' 0vqZWBIbOlyzL25l9iWk51CxxJTiEM6QUZEH1ph+/aNp+lk4Yf8NYv8RLhYtbqCNpOqO3y8BmM+0YWtbAhE+RA=="

将PW哈希和salt存储为用户记录的一部分.盐并不是秘密,但如果用户更改密码,则更改它.

比较登录尝试

' check if PW entered equals DB
Dim pwTry = TextBox2.Text
' hash the login attempt using the salt stored in the DB
Dim pwLogin = GetSaltedHash(pwTry, dbSalt)

' compare the hash of what they entered to whats in the DB:
If String.Compare(SaltedPWHash, pwLogin, False) = 0 Then
    ' okay!
    Console.Beep()
End If

如果用户输入相同的PW,它应该产生相同的散列,就像那样简单.散列代码并不复杂:

哈希方法

Private Function GetSaltedHash(pw As String, salt As String) As String
    Dim tmp As String = pw & salt

    ' or SHA512Managed
    Using hash As HashAlgorithm = New SHA256Managed()
        ' convert pw+salt to bytes:
        Dim saltyPW = Encoding.UTF8.GetBytes(tmp)
        ' hash the pw+salt bytes:
        Dim hBytes = hash.ComputeHash(saltyPW)
        ' return a B64 string so it can be saved as text 
        Return Convert.ToBase64String(hBytes)
    End Using

End Function

Private Function CreateNewSalt(size As Integer) As String
    ' use the crypto random number generator to create
    ' a new random salt 
    Using rng As New RNGCryptoServiceProvider
        ' dont allow very small salt
        Dim data(If(size < 7, 7, size)) As Byte
        ' fill the array
        rng.GetBytes(data)
        ' convert to B64 for saving as text
        Return Convert.ToBase64String(data)
    End Using
End Function

• 使用像GUID(System.Guid.NewGuid.ToString)这样的东西很容易,但是使用加密随机数生成器并不是那么难.
• 与散列密码一样,由于编码,返回字符串更长.
• 每次用户更改密码时都要创建一个新的salt.不要使用全球盐,它会破坏目的.
• 您也可以多次散列PW.部分关键是如果/当受到攻击时,需要花费很长时间才能尝试所有各种组合.
• 这些功能是Shared/ static类成员的理想候选人.

另请注意,Kenneth链接的文章非常值得一读.

请注意,文章提到The salt should be stored in the user account table alongside the hash 这并不意味着您必须Salt在数据库中有一列.您可以在链接的文章中看到以下内容:

Dim dbPW As String = TextBox1.Text
Dim dbSalt = CreateNewSalt(SaltSize)

' get the salted PW hash
Dim SaltedPWHash As String = GetSaltedHash(dbPW, dbSalt)
' store salt with the hash:
SaltedPWHash = String.Format("{0}:{1}", dbSalt, dbPW)
' salt + ":" + hashed PW now ready to store in the db

要从散列密码中分割盐:

Dim SaltAndPWHash = rdr.Item("PWHash").ToString()

Dim split = SaltAndPWHash.Split(":"c)    ' split on ":"
Dim Salt = split(0)                      ' element(0) == salt
Dim StoredPWHash = split(1)              ' element(1) == hashed PW

您需要这两个部分:在对PW中尝试的日志进行散列后,将其与之进行比较split(1).