使用Delphi RTTI获取接口的字符串名称

Question

我已经证明我可以使用Delphi 2010从其GUID获取接口的名称(例如,IMyInterface转换为字符串'IMyInterface'.我想在Delphi 7中实现这一点(兼容性).这可能吗？或者是有基本的编译限制.

Answer 1

是的,你可以得到它,以下显示使用IExample类型如何获得名称.旧的Delphi 7 RTTI是通过TypInfo Unit完成的.

program Project6;
{$APPTYPE CONSOLE}
uses
  SysUtils,TypInfo;

type
  IExample = interface
    ['{4902F666-F3FC-4999-BD8C-F226851201D6}']
    procedure blah;
  end;


begin
  Writeln(GetTypeName(TypeInfo(IExample)));
  readln
end.

刚刚注意到你说你想从GUID中获取它,而不仅仅是类型.这将需要GUID注册表到类型.Delphi 7中的RTTI可用于获取类型.

以下将采用IExample返回guid.

Writeln(GUIDToString(GetTypeData(TypeInfo(IExample)).Guid));

这是一个示例注册表,它将接口的TypeInfo()映射到它的GUID.它可以进行优化,但我这样做是为了说明这个概念.

unit Unit11;

interface
uses
  TypInfo,SysUtils, Contnrs;

type

  TGuidMap = class(TObject)
    Guid : TGUID;
    TypeInfo : PTypeInfo;
  end;

procedure RegisterInterface(InterfaceType : PTypeInfo);

function GetInterfaceType(Guid : TGUID) : PTypeInfo;

implementation
var
  GuidMapList : TObjectList;

procedure RegisterInterface(InterfaceType : PTypeInfo);
var
 Map : TGuidMap;
begin
  Map := TGuidMap.Create;
  Map.TypeInfo := InterfaceType;
  Map.Guid := GetTypeData(InterfaceType).Guid;
  GuidMapList.Add(Map);
end;

function GetInterfaceType(Guid : TGUID) : PTypeInfo;
var
 I : Integer;
begin
 result := nil;
 for I := 0 to GuidMapList.Count - 1 do
 begin
   if IsEqualGUID(TGuidMap(GuidMapList.Items[I]).Guid,Guid) then
   begin
     result := TGuidMap(GuidMapList.Items[I]).TypeInfo;
     break;
   end;
 end;
end;

Initialization
 GuidMapList := TObjectList.Create(true);
finalization
 GuidMapList.Free;
end.

要将项添加到注册表,您将调用

   RegisterInterface(TypeInfo(IExample));