如何在汇编中迭代所有磁盘扇区？

Question

在学习装配的过程中,我正在编写一个操作系统.我已成功编写了将第二个512字节扇区附加到初始512字节引导加载程序所需的代码:

%define KBDINT  0x16
%define VIDINT  0x10
%define DISKINT 0x13
%define TTYOUT  0x0E
%define VIDMODE 0x0000
%define NUL 0x00
%define CR  0x0D
%define LF  0x0A
%define START   0x7C00

%macro  PRINT   1
    mov si, %1
    call    print
%endmacro

    bits    16          ; 16 bit real mode
    org START           ; loader start in memory
start:  jmp main

print:  jmp .init
.loop:  mov bx, VIDMODE
    mov ah, TTYOUT
    int VIDINT
    inc si
.init:  mov al, [si]
    cmp al, NUL
    jne .loop
    ret

main:   cli
    xor ax, ax
    mov ds, ax
    mov es, ax
    sti
    PRINT   welcome

    mov ah, NUL
    int DISKINT
    mov al, 0x01        ; sector count
    mov ah, 0x02        ; read function
    mov bx, kernel
    mov cl, 0x02
    mov ch, 0x00        ; cylinder number
    mov dh, 0x00        ; head number
    int DISKINT
    jc  fail
    jmp kernel

fail:   PRINT   failure
;   jmp halt

halt:   PRINT   halting
    cli
    hlt
    PRINT   imprbbl
    jmp halt

    welcome db "moose os", CR, LF, NUL
    failure db "failed disk load", CR, LF, NUL
    halting db "halting", CR, LF, NUL
    imprbbl db "but that's impossible!", CR, LF, NUL

times 0x0200 - ($ - $$) - 2 db 0x00
    end dw 0xAA55

kernel: PRINT   yay
    yay db "kernel", CR, LF, NUL
    jmp halt

times 0xFFFF db 0x00

我用以下代码编译文件nasm -f bin -o boot.bin boot.asm && qemu boot.bin:

我很好奇头部和圆柱体是如何使用的:

• 这些部门是如何重复的？
• 迭代在仿真和直接执行之间有何不同？

Answer 1

•各部门如何重复？

要使用CHS CylinderHeadSector表示法迭代多个扇区,我们首先必须检索这些参数的实际限制.BIOS具有功能08h,int 13h它为我们提供了最大值以及一些我们现在不需要的额外信息.

CL中的扇区号范围从1到63.DH中
的头号范围从0到255,尽管很少使用255.
CL中的柱面编号范围为0到1023.由于这不能保存在单个字节中,因此该10位编号的2个最高位存储在CL寄存器的第6位和第7位!

迭代如何工作

可以把CHS符号想象成某种数字,其中C是最重要的部分而S是最不重要的部分.
为了进入磁盘上的下一个扇区,我们在最不重要的一端开始增加这个数字.
如果通过递增S部分我们溢出其范围,我们将其重置为其最小值(1)并开始递增下一个更重要的部分,在这种情况下是H.
如果通过递增H部分我们溢出其范围,我们将其重置为其最小值(0)并开始递增最重要的部分,在这种情况下为C.
如果通过递增C部分我们溢出其范围,我们将其重置为其最小值(0).这将使磁盘上的环绕.如果在输入时给出了正确的SectorCount,则通常此时读数将停止.

; INPUT:  DL=Drive
;         CH=Cylinder
;         DH=Head
;         CL=Sector
;         AX=SectorCount
;         ES:BX=Buffer
; OUTPUT: CF=0 AH       = 0
;              CH,DH,CL = CHS of following sector
;         CF=1 AH       = Error status
;              CH,DH,CL = CHS of problem sector
ReadDiskSectors:
  push    es
  push    di
  push    bp
  mov     bp,sp           ;Local variables:
  push    ax              ;[bp-2]=SectorCount
  push    cx              ;[bp-4]=MaxSector
  push    dx              ;[bp-6]=MaxHead
  push    bx              ;[bp-8]=MaxCylinder

  push    es
  mov     ah,08h
  int     13h             ;ReturnDiskDriveParameters
  pop     es
  jc      NOK
  mov     bx,cx           ;10-bit cylinder info -> BX
  xchg    bl,bh
  shr     bh,6
  xchg    [bp-8],bx       ;Store MaxCylinder and get input BX back
  movzx   dx,dh           ;8-bit head info -> DX
  xchg    [bp-6],dx       ;Store MaxHead and get input DX back
  and     cx,003Fh        ;6-bit sector info -> CX
  xchg    [bp-4],cx       ;Store MaxSector and get input CX back

ReadNext:
  mov     di,5            ;Max 5 tries per sector
ReadAgain:
  mov     ax,0201h        ;Read 1 sector
  int     13h             ;ReadDiskSectors
  jnc     OK
  push    ax              ;Save error status byte in AH
  mov     ah,00h
  int     13h             ;ResetDiskSystem
  pop     ax
  dec     di
  jnz     ReadAgain
  stc
  jmp     NOK
OK:
  dec     word ptr [bp-2] ;SectorCount
  jz      Ready
  call    NextCHS
  mov     ax,es           ;Move buffer 512 bytes up
  add     ax,512/16
  mov     es,ax
  jmp     ReadNext

Ready:
  call    NextCHS         ;Return useful CHS values to support reads
  xor     ah,ah           ; -> CF=0 ... that are longer than memory
NOK:
  mov     sp,bp
  pop     bp
  pop     di
  pop     es
  ret

NextCHS:
  mov     al,cl            ;Calculate the 6-bit sector number
  and     al,00111111b
  cmp     al,[bp-4]        ;MaxSector
  jb      NextSector
  cmp     dh,[bp-6]        ;MaxHead
  jb      NextHead
  mov     ax,cx            ;Calculate the 10-bit cylinder number
  xchg    al,ah
  shr     ah,6
  cmp     ax,[bp-8]        ;MaxCylinder
  jb      NextCylinder
DiskWrap:
  mov     cx,1             ;Wraparound to very first sector on disk
  mov     dh,0
  ret
NextCylinder:
  inc     ax
  shl     ah,6             ;Split 10-bit cylinder number over CL and CH
  xchg    al,ah
  mov     cx,ax
  mov     dh,0
  inc     cl
  ret
NextHead:
  inc     dh
  and     cl,11000000b
NextSector:
  inc     cl
  ret

关于行业规模的说明

虽然拥有长度不是512字节的扇区是完全没问题的,但可以假设它们是那么大的. 经过几十年的编程,我从未见过任何没有512字节扇区的磁盘.
如果您坚持支持不同的大小,您可以查看DisketteParameterTable的第4个字节,您从BIOS函数ReturnDiskDriveParameters中收到ES:DI中的指针.

•迭代在仿真和直接执行之间有何不同？

我想通过直接执行你可以理解真正的硬件.
对于真正的硬件BIOS,将返回CHS表示法中的几何体,并且扇区存在......好吧,因为它们是真实的!
在仿真下,仿真器将尽力为您提供这些几何值,但是您需要确保相关驱动器上存在足够的扇区.这正是@Jester在问你时所说的:"你甚至在图像文件中有这个扇区吗？" 您通过使用放大图像文件解决了此问题times 0xFFFF db 0x00

一些额外的建议

你没有设置堆栈.由于您将内核加载到7C00h的bootsector之上,我建议您将SS:SP初始化为0000h:7C00h,以便在bootsector下面进行堆栈.

main:
  cli
  xor ax, ax
  mov ds, ax
  mov es, ax
  mov ss, ax
  mov sp, 7C00h
  sti
  PRINT   welcome

正如@Fifoernik评论你最好放在jmp halt之前,yay db "kernel", CR, LF, NUL以防止这些数据的执行!

kernel:
  PRINT   yay
  jmp halt
  yay db "kernel", CR, LF, NUL