添加新的网络位置，而不是映射网络驱动器

Question

假设我有 100 个用户，我需要为每个用户添加多个网络位置。它们不能是网络驱动器（例如 Q:），因为某些用户已经映射了超过 26 个驱动器。

我希望使用批处理文件或 VB 脚本来完成此操作。我已经设法通过添加网络快捷方式使用 VB 脚本使其工作，但这不是用户需要的解决方案。

我一直在搜索，但找不到任何与网络位置相关的内容。

我愿意尝试其他方法。

Answer 1

已编辑以正确回答问题；原始答案（在Network Locations中创建快捷方式）保留在最后。

经过一些测试，网络位置是位于该文件夹中的一个只读文件夹%AppData%\Microsoft\Windows\Network Shortcuts，里面有两个文件：desktop.ini具有精确内容（请参阅代码）和target.lnk目标的快捷方式。

Option Explicit

Function CreateNetworkLocation( networkLocationName, networkLocationTarget )
    Const ssfNETHOOD  = &H13&
    Const fsATTRIBUTES_READONLY = 1
    Const fsATTRIBUTES_HIDDEN = 2
    Const fsATTRIBUTES_SYSTEM = 4

    CreateNetworkLocation = False 

    ' Instantiate needed components
    Dim fso, shell, shellApplication
        Set fso =               WScript.CreateObject("Scripting.FileSystemObject")
        Set shell =             WScript.CreateObject("WScript.Shell")
        Set shellApplication =  WScript.CreateObject("Shell.Application")

    ' Locate where NetworkLocations are stored
    Dim nethoodFolderPath, networkLocationFolder, networkLocationFolderPath
        nethoodFolderPath = shellApplication.Namespace( ssfNETHOOD ).Self.Path

    ' Create the folder for our NetworkLocation and set its attributes
        networkLocationFolderPath = fso.BuildPath( nethoodFolderPath, networkLocationName )
        If fso.FolderExists( networkLocationFolderPath ) Then 
            Exit Function 
        End If 
        Set networkLocationFolder = fso.CreateFolder( networkLocationFolderPath )
        networkLocationFolder.Attributes = fsATTRIBUTES_READONLY

    ' Write the desktop.ini inside our NetworkLocation folder and change its attributes    
    Dim desktopINIFilePath
        desktopINIFilePath = fso.BuildPath( networkLocationFolderPath, "desktop.ini" )
        With fso.CreateTextFile(desktopINIFilePath)
            .Write  "[.ShellClassInfo]" & vbCrlf & _ 
                    "CLSID2={0AFACED1-E828-11D1-9187-B532F1E9575D}" & vbCrlf & _ 
                    "Flags=2" & vbCrlf
            .Close
        End With 
        With fso.GetFile( desktopINIFilePath )
            .Attributes = fsATTRIBUTES_HIDDEN + fsATTRIBUTES_SYSTEM
        End With 

    ' Create the shortcut to the target of our NetworkLocation
    Dim targetLink
        targetLink = fso.BuildPath( networkLocationFolderPath, "target.lnk" )
        With shell.CreateShortcut( targetLink )
            .TargetPath = networkLocationTarget
            .Save
        End With        

    ' Done
        CreateNetworkLocation = True 

End Function

CreateNetworkLocation "Tests", "\\192.168.1.2\c$"

在 Windows 7 中测试。

原始答案-以防万一有人发现它有用。

您需要做的就是在文件夹中创建一个快捷方式：

%AppData%\Microsoft\Windows\Network Shortcuts

只是一个 VBScript 示例（如问题中所示，不确定标签是否指向其他需求）：

Option Explicit

Const ssfNETHOOD  = &H13&

Dim fso, shell, shellApplication

    Set fso =               WScript.CreateObject("Scripting.FileSystemObject")
    Set shell =             WScript.CreateObject("WSCript.Shell")
    Set shellApplication =  WScript.CreateObject("Shell.Application")

Dim networkLocationsFolder
    networkLocationsFolder = shellApplication.Namespace( ssfNETHOOD ).Self.Path

    With shell.CreateShortcut(fso.BuildPath( networkLocationsFolder, "Test PC.lnk" ))
        .TargetPath = "\\192.168.1.10\c$"
        .WindowStyle = 1
        .IconLocation = "shell32.dll, 9"
        .Description = "Access to Test computer drive"
        .WorkingDirectory = "\\192.168.1.10\c$"
        .Save
    End With