F#计算表达式透明状态与Bind一起传递

Question

我有以下代码尝试使用通常的MaybeBuilder从网络流中读取可能不完整的数据(例如图像数据):

let image = maybe {
    let pos = 2 //Initial position skips 2 bytes of packet ID
    let! width, pos = readStreamAsInt 2 pos
    let! height, pos = readStreamAsInt 2 pos
    let! data, pos = readStream (width*height) pos
    advanceInStream pos
    return {width = width; height = height; pixels = data}
}

因此,如果数据尚未到达NetworkStream,则readStream [asInt] [numBytes] [offset]函数返回一些[data]或None.读取整个网络数据包时执行advanceInStream函数.

我想知道是否有一些方法可以编写一些自定义计算表达式构建器来隐藏来自其用户的pos,因为它始终是相同的 - 我读取了一些数据并在流中定位并将其作为最后一个参数传递给下一个读取函数.

PS MaybeBuilder使用:

type MaybeBuilder() =    
    member x.Bind(d,f) = Option.bind f d
    member x.Return d = Some d
    member x.ReturnFrom d = d
    member x.Zero() = None
let maybe = new MaybeBuilder()

PPS

第二个想法似乎我必须使pos可变,因为在阅读中可能有"for"或"while"循环.简单吧!使用pos Bind阴影可以正常工作,但是如果你在循环中添加读数就无法保持不变性,对吧？那么任务就变得微不足道了.

Answer 1

@bytebuster 很好地阐述了自定义计算表达式的可维护性，但我仍然认为我演示了如何将 和Statemonad组合Maybe成一个。

在“传统”语言中，我们对组合诸如整数之类的值有很好的支持，但是在开发解析器时我们遇到了问题（从二进制流生成值本质上是解析）。对于解析器，我们希望将简单的解析器函数组合成更复杂的解析器函数，但这里“传统”语言通常缺乏良好的支持。

在函数式语言中，函数与值一样普通，并且由于值可以组合，显然函数也可以组合。

首先我们定义一个StreamReader函数。AStreamReader采用StreamPosition（流 + 位置）并生成更新的StreamPosition和 a StreamReaderResult（读取值或失败）。

type StreamReader<'T> = 
  StreamReader of (StreamPosition -> StreamPosition*StreamReaderResult<'T>)

（这是最重要的一步。）

我们希望能够将简单的StreamReader函数组合成更复杂的函数。我们想要维护的一个非常重要的属性是，组合操作是“封闭的”，StreamReader这意味着组合的结果是一个新的StreamReader，并且可以无限地组合。

为了读取图像，我们需要读取宽度和高度，计算乘积并读取字节。像这样的东西：

let readImage = 
  reader {
    let! width  = readInt32 
    let! height = readInt32 
    let! bytes  = readBytes (width*height)

    return width, height, bytes
  }

因为组合被关闭readImage是一个StreamReader<int*int*byte[]>.

为了能够StreamReader像上面那样进行组合，我们需要定义一个计算表达式，但在此之前我们需要定义操作Return和Bindfor StreamReader。事实证明，Yield拥有它也很好。

module StreamReader =
  let Return v : StreamReader<'T> =
    StreamReader <| fun sp -> 
      sp, (Success v)

  let Bind (StreamReader t) (fu : 'T -> StreamReader<'U>) : StreamReader<'U> =
    StreamReader <| fun sp -> 
      let tsp, tr = t sp
      match tr with
      | Success tv ->
        let (StreamReader u) = fu tv
        u tsp
      | Failure tfs -> tsp, Failure tfs

  let Yield (ft : unit -> StreamReader<'T>) : StreamReader<'T> =
    StreamReader <| fun sp -> 
      let (StreamReader t) = ft ()
      t sp

Return很简单，因为StreamReader应该返回给定值并且不更新StreamPosition.

Bind更具挑战性，但描述了如何将两个StreamReader函数组合成一个新函数。Bind运行第一个StreamReader函数并检查结果，如果失败则返回失败，否则使用StreamReader结果计算第二个函数StreamReader并在更新流位置上运行。

Yield只需创建StreamReader函数并运行它。Yield由 F# 在构建计算表达式时使用。

最后让我们创建计算表达式生成器

type StreamReaderBuilder() =
  member x.Return v   = StreamReader.Return v
  member x.Bind(t,fu) = StreamReader.Bind t fu
  member x.Yield(ft)  = StreamReader.Yield ft

let reader = StreamReaderBuilder ()

现在我们构建了功能组合的基本框架StreamReader。此外，我们需要定义原始StreamReader函数。

完整示例：

open System
open System.IO

// The result of a stream reader operation is either
//  Success of value
//  Failure of list of failures
type StreamReaderResult<'T> =
  | Success of 'T
  | Failure of (string*StreamPosition) list

and StreamPosition =
  {
    Stream    : byte[]
    Position  : int
  }

  member x.Remaining = max 0 (x.Stream.Length - x.Position)

  member x.ReadBytes (size : int) : StreamPosition*StreamReaderResult<byte[]> =
    if x.Remaining < size then
      x, Failure ["EOS", x]
    else
      let nsp = StreamPosition.New x.Stream (x.Position + size)
      nsp, Success (x.Stream.[x.Position..(x.Position + size - 1)])

  member x.Read (converter : byte[]*int -> 'T) : StreamPosition*StreamReaderResult<'T> =
    let size = sizeof<'T>
    if x.Remaining < size then
      x, Failure ["EOS", x]
    else
      let nsp = StreamPosition.New x.Stream (x.Position + size)
      nsp, Success (converter (x.Stream, x.Position))

  static member New s p = {Stream = s; Position = p;}

// Defining the StreamReader<'T> function is the most important decision
//   In this case a stream reader is a function that takes a StreamPosition 
//   and produces a (potentially) new StreamPosition and a StreamReadeResult
type StreamReader<'T> = StreamReader of (StreamPosition -> StreamPosition*StreamReaderResult<'T>)

// Defining the StreamReader CE
module StreamReader =
  let Return v : StreamReader<'T> =
    StreamReader <| fun sp -> 
      sp, (Success v)

  let Bind (StreamReader t) (fu : 'T -> StreamReader<'U>) : StreamReader<'U> =
    StreamReader <| fun sp -> 
      let tsp, tr = t sp
      match tr with
      | Success tv ->
        let (StreamReader u) = fu tv
        u tsp
      | Failure tfs -> tsp, Failure tfs

  let Yield (ft : unit -> StreamReader<'T>) : StreamReader<'T> =
    StreamReader <| fun sp -> 
      let (StreamReader t) = ft ()
      t sp

type StreamReaderBuilder() =
  member x.Return v   = StreamReader.Return v
  member x.Bind(t,fu) = StreamReader.Bind t fu
  member x.Yield(ft)  = StreamReader.Yield ft

let reader = StreamReaderBuilder ()

let read (StreamReader sr) (bytes : byte[]) (pos : int) : StreamReaderResult<'T> =
  let sp    = StreamPosition.New bytes pos
  let _, sr = sr sp
  sr

// Defining various stream reader functions
let readValue (converter : byte[]*int -> 'T) : StreamReader<'T> =
  StreamReader <| fun sp -> sp.Read converter

let readInt32 = readValue BitConverter.ToInt32
let readInt16 = readValue BitConverter.ToInt16
let readBytes size : StreamReader<byte[]> = 
  StreamReader <| fun sp -> 
    sp.ReadBytes size

let readImage = 
  reader {
    let! width  = readInt32 
    let! height = readInt32 
    let! bytes  = readBytes (width*height)

    return width, height, bytes
  }

[<EntryPoint>]
let main argv = 
  // Sample byte stream
  let bytes   = [|2;0;0;0;3;0;0;0;1;2;3;4;5;6|] |> Array.map byte
  let result  = read readImage bytes 0

  printfn "%A" result

  0