为什么这个汇编代码没有将指针指向的值加倍

Question

我正在尝试将 c 代码与 asm 接口。但它无法正常工作，我无法找到问题。

程序.c

#include<stdio.h>
int *asm_multi(int *ptr);

int main()
{
  int i=10;
  int *p=&i;
  asm_multi(p);
  printf("%d\n",*p);
  return 0;
}

代码.asm

.section .text
.global asm_multi
.type asm_multi,@function
asm_multi:
    pushl %ebp
    movl %esp,%ebp
    movl 8(%ebp),%eax
    movl %eax,%edx
    leal (%edx,%edx,1),%edx
    movl %edx,%eax
    movl %ebp,%esp
    popl %ebp
    ret

我正在创建最终的可执行文件

as code.asm -o code.o
gcc program.c code.o -o  output
./output

它打印的输出是：10 而我期待的是：20

代码中有什么问题？不要考虑程序的效率。我刚刚开始 asm 编程。

在阅读了保存在此链接中的更复杂示例后，我创建了上述代码。这完美地工作。

Answer 1

您应该尽快学会使用调试器。它不仅可以帮助您查找错误，还可以让您准确地查看 CPU 在每条指令上的操作，并将其与您的意图进行比较。

另外，注释您的代码，尤其是在寻求帮助时，这样我们就可以告诉您说明在哪些地方与您的意图不符，如果您自己无法做到的话。

然后让我们评论您的代码：

asm_multi:
    pushl %ebp
    movl %esp,%ebp
    movl 8(%ebp),%eax        # fetch first argument, that is p into eax
    movl %eax,%edx           # edx = p too
    leal (%edx,%edx,1),%edx  # edx = eax + edx = 2 * p
    movl %edx,%eax           # eax = edx = 2 * p
    movl %ebp,%esp
    popl %ebp
    ret

如您所见，有两个问题：

1. 您将指针加倍而不是它指向的值
2. 你没有把它写回内存，只是在 eax 中返回它然后被 C 代码忽略

一个可能的修复：

asm_multi:
    pushl %ebp
    movl %esp,%ebp
    movl 8(%ebp),%eax       # fetch p
    shll $1, (%eax)         # double *p by shifting 1 bit to the left
# alternatively
#   movl (%eax), %edx       # fetch *p
#   addl %edx, (%eax)       # add *p to *p, doubling it
    movl %ebp,%esp
    popl %ebp
    ret