在Haskell中解析化合物

Question

我试图自己做一个化学分析器，但是被卡住了。

这是我要使用的数据类型：

data Compound = Monoatomic String Int | Poliatomic [Compound] Int

给定像“ Ca（OH）2”这样的字符串，我想得到类似的东西；

Poliatomic [Monoatomic "Ca" 1, Poliatomic [Monoatomic "O" 1, Monoatomic "H" 1] 2 ] 1

单原子的单原子类型构造函数，多个原子的多原子构造函数。在此示例中，（OH）2表示内部政治结构，并表示为Poliatomic [(Monoatomic O 1), (Monoatomic H 1 )] 2。数字2代表我们有两个这样的政治结构。

我做了很多

import Data.Char (isUpper)
data Compound = Monoatomic String Int | Poliatomic [Compound] Int

instance Functor Compound where
        fmap f (Monoatomic s i) = Monoatomic (f s) i
        fmap f (Poliatomic xs i) = Poliatomic (fmap f xs) i

-- Change number of a compound
changeNumber :: Compound -> Int -> Compound
changeNumber (Monoatomic xs _) n = Monoatomic xs n
changeNumber (Poliatomic xs _) n = Poliatomic xs n

-- Take a partial compound and next chracter return partial compound
parseCompound :: Compound -> Char -> Compound
parseCompound (Poliatomic x:xs n) c
        | isUpper c = Poliatomic ((Monoatomic [c] 1):x:xs) n -- add new atom to compound
        | isLower c = Poliatomic 

-- I want to do foldl parseCompound (Poliatomic [] 1) inputstring

但是后来变得太复杂了，我无法继续。

看来这应该是一个相当简单的问题，但是我对Haskell还是陌生的，无法弄清楚如何完成此功能。

我有这个问题：

• 到目前为止，我的方法正确吗？
• 我该如何进行这项工作？

Answer 1

我用Parsec创建了您要查找的解析器，以使您对Parsec解析器的外观有所了解，因为您表示自己对此经验不足。

即使没有Haskell经验，它也应该相当可读。我对需要特别注意的部分提供了一些评论。

import Text.Read (readMaybe)
import Data.Maybe (fromMaybe)
import Text.Parsec (parse, many, many1, digit, char, string, (<|>), choice, try)
import Text.Parsec.String (Parser)


data Compound
  = Monoatomic String Int
  | Poliatomic [Compound] Int
  deriving Show


-- Run the substance parser on "Ca(OH)2" and print the result which is
-- Right (Poliatomic [Monoatomic "Ca" 1,Poliatomic [Monoatomic "O" 1,Monoatomic "H" 1] 2] 1)
main = print (parse substance "" "Ca(OH)2")


-- parse the many parts which make out the top-level polyatomic compound
--
-- "many1" means "at least one"
substance :: Parser Compound
substance = do
  topLevel <- many1 part
  return (Poliatomic topLevel 1)


-- a single part in a substance is either a poliatomic compound or a monoatomic compound
part :: Parser Compound
part = poliatomic <|> monoatomic


-- a poliatomic compound starts with a '(', then has many parts inside, then
-- ends with ')' and has a number after it which indicates how many of it there
-- are.
poliatomic :: Parser Compound
poliatomic = do
  char '('
  inner <- many1 part
  char ')'
  amount <- many1 digit
  return (Poliatomic inner (read amount))


-- a monoatomic compound is one of the many element names, followed by an
-- optional digit. if omitted, the amount defaults to 1.
--
-- "try" is a little special, and required in this case. it means "if a parser
-- fails, try the next one from where you started, not from where the last one
-- failed."
--
-- "choice" means "try all parsers in this list, stop when one matches"
--
-- "many" means "zero or more"
monoatomic :: Parser Compound
monoatomic = do
  name <- choice [try nameParser | nameParser <- atomstrings]
  amount <- many digit
  return (Monoatomic name (fromMaybe 1 (readMaybe amount)))


-- a list of parser for atom names. it is IMPORTANT that the longest names
-- come first. the reason for that is that it makes the parser much simpler to
-- write, and it can execute much faster. it's common when designing parsers to
-- consider things like that when creating them.
atomstrings :: [Parser String]
atomstrings = map string (words "He Li Be Ne Na Mg Al Ca H B C N O F")

我试图以一种对初学者来说至少应该合理访问的方式来编写此代码，但是它可能并不清楚，因此我很乐意回答有关此问题。

上面的解析器是您想要的解析器。但是，如果我有自由re绳，那不是我会写的。如果我愿意做，我会利用这样的事实：

Ca(OH)2

可以表示为

(Ca)1((O)1(H)1)2

这是一种更为统一的表示方式，进而可以简化数据结构，并简化解析器。我更喜欢写的代码看起来像 

import Text.Read (readMaybe)
import Data.Maybe (fromMaybe)
import Control.Applicative ((<$>), (<*>), pure)
import Text.Parsec (parse, many, many1, digit, char, string, (<|>), choice, try, between)
import Text.Parsec.String (Parser)


data Substance
  = Part [Substance] Int
  | Atom String
  deriving Show


main = print (parse substance "" "Ca(OH)2")
-- Right (Part [Part [Atom "Ca"] 1,Part [Part [Atom "O"] 1,Part [Atom "H"] 1] 2] 1)

substance :: Parser Substance
substance = Part <$> many1 part <*> pure 1

part :: Parser Substance
part = do
  inner <- polyatomic <|> monoatomic
  amount <- fromMaybe 1 . readMaybe <$> many digit
  return (Part inner amount)

polyatomic :: Parser [Substance]
polyatomic = between (char '(') (char ')') (many1 part)

monoatomic :: Parser [Substance]
monoatomic = (:[]) . Atom <$> choice (map (try . string) atomstrings)

atomstrings :: [String]
atomstrings = words "He Li Be Ne Na Mg Al Ca H B C N O F"

这在Haskell中使用了一些“高级”技巧（例如<$>和<*>运算符），所以OP可能对您不感兴趣，但是我将其引入了可能是更高级的Haskell用户并了解Parsec的其他人。

如您所见，该解析器仅占用大约一半的页面，这就是Parsec之类的库的强大功能–它们使编写解析器变得既轻松又有趣！