F#类型提供程序引用自定义类型

Question

我正在构建一个简单的类型提供程序,但在引用我创建的类型时,我似乎遇到了问题.例如,给定

namespace Adder

type Summation = Summation of int

module QuickAdd = 
  let add x y = x + y |> Summation

我想让以下测试用例通过:

module Adder.Tests

open Adder
open NUnit.Framework

type Simple = QuickAddProvider<1, 2>

[<Test>]
let ``Simple sample is 3`` () =
  let foo = Simple()
  Assert.AreEqual(foo.Sample, Summation 3)

使用以下类型提供程序:

namespace Adder

open Microsoft.FSharp.Core.CompilerServices
open ProviderImplementation.ProvidedTypes
open System.Reflection

[<TypeProvider>]
type public QuickAddProvider (config : TypeProviderConfig) as this =
  inherit TypeProviderForNamespaces ()

  let ns = "Adder"
  let asm = Assembly.GetExecutingAssembly()
  let paraProvTy = ProvidedTypeDefinition(asm, ns, "QuickAddProvider", Some typeof<obj>)

  let buildTypes (typeName:string) (args:obj[]) =
    let num1 = args.[0] :?> int
    let num2 = args.[1] :?> int
    let tpType = ProvidedTypeDefinition(asm, ns, typeName, Some typeof<obj>)
    let result = QuickAdd.add num1 num2
    let orig = ProvidedProperty("Sample", typeof<Summation>, GetterCode = (fun args -> <@@ result @@>))
    tpType.AddMember(orig)
    tpType.AddMember(ProvidedConstructor([], InvokeCode = (fun args -> <@@ () @@>)))
    tpType

  let parameters = 
    [ProvidedStaticParameter("Num1", typeof<int>)
     ProvidedStaticParameter("Num2", typeof<int>)]

  do paraProvTy.DefineStaticParameters(parameters, buildTypes)
  do this.AddNamespace(ns, [paraProvTy])

[<TypeProviderAssembly>]
do()

我在测试文件中遇到意外错误:

The type provider 'Adder.QuickAddProvider' reported an error in the context of provided type 'Adder.QuickAddProvider,Num1="1",Num2="2"', member 'get_Sample'. The error: Unsupported constant type 'Adder.Summation'

在生成的文件中出现以下错误:

The type "Summation" is not defined
The namespace or module "Adder" is not defined

更换Summation类型时int,测试用例会编译并传递,因此我知道我的类型提供程序并不是非常错误.我需要以某种方式"导入" Summation某处的类型吗？

Answer 1

此错误通常表示您正在创建包含自定义类型值的报价.类型提供程序中的引用只能包含基本类型的值 - 编译器知道如何序列化这些 - 但它无法处理自定义类型.

在代码段中,这发生在这里:

let result = QuickAdd.add num1 num2
let orig = ProvidedProperty("Sample", typeof<Summation>, GetterCode = (fun args -> 
  <@@ result @@>))

这里,GetterCode返回包含Summation不支持的类型值的报价.为了使这项工作,您可以做各种事情 - 通常,您需要提出一些产生您想要的值的其他引用表达式.

一种选择是做计算内报价,而不是外面:

<@@ QuickAdd.add num1 num2 @@>

另一种选择是Summation在报价中重新创建价值:

let (Summation n) = result
<@@ Summation n @@>

这是有效的,因为它只需要序列化一个原始int值,然后生成一个对Summationcase构造函数的调用.