如何使用Gradle在AppEngine项目中使用Kotlin

Question

就像标题所说,在开发AppEngine项目时如何使用Kotlin？我正在使用带有Gradle的IntelliJ/Android Studio作为我的构建工具.

Answer 1

由于AppEngine执行编译的.class文件,因此它不关心JVM语言产生的内容.这意味着我们可以使用Kotlin.

一种方法是使用Gradle和Gradle App Engine插件.创建一个build.gradle看起来像这样的项目.然后添加Kotlin依赖项并应用插件.最终的构建文件看起来像这样:

buildscript {
    ext.kotlin_version = '1.0.6' //replace with latest Kotlin version
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.google.appengine:gradle-appengine-plugin:1.9.32' //Replace with latest GAE plugin version
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

repositories {
    mavenCentral();
}

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'war'
apply plugin: 'appengine'

sourceCompatibility = JavaVersion.VERSION_1_7
targetCompatibility = JavaVersion.VERSION_1_7

dependencies {
    appengineSdk 'com.google.appengine:appengine-java-sdk:1.9.32' //Replace with latest GAE SDK version
    compile 'javax.servlet:servlet-api:2.5'
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
}

appengine {
    downloadSdk = true
    appcfg {
        oauth2 = true
    }
}

从M11开始,您不需要为Kotlin文件创建单独的目录,因此您只需添加.kt文件即可src/main/java.